blob: b9c53e0910bdb013d6a5a47656fe4795e2adf4bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit vala xdg-utils
DESCRIPTION="Panel for the Xfce desktop environment"
HOMEPAGE="
https://docs.xfce.org/xfce/xfce4-panel/start
https://gitlab.xfce.org/xfce/xfce4-panel/
"
SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="+dbusmenu introspection vala wayland X"
REQUIRED_USE="
|| ( wayland X )
vala? ( introspection )
"
DEPEND="
>=dev-libs/glib-2.72.0
>=x11-libs/cairo-1.16.0
>=x11-libs/gtk+-3.24.0:3[X?,introspection?,wayland?]
>=xfce-base/exo-0.11.2:=
>=xfce-base/garcon-4.17.0:=
>=xfce-base/libxfce4ui-4.17.1:=
>=xfce-base/libxfce4util-4.17.2:=[introspection?,vala?]
>=xfce-base/libxfce4windowing-4.19.3:=[X?]
>=xfce-base/xfconf-4.13.2:=
dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
introspection? ( >=dev-libs/gobject-introspection-1.66:= )
wayland? (
>=dev-libs/wayland-1.15
>=gui-libs/gtk-layer-shell-0.7.0
)
X? (
>=x11-libs/libX11-1.6.7
x11-libs/libwnck:3
)
"
RDEPEND="
${DEPEND}
"
BDEPEND="
vala? ( $(vala_depend) )
dev-lang/perl
dev-util/gdbus-codegen
dev-util/intltool
sys-devel/gettext
virtual/pkgconfig
"
PATCHES=(
# fix build with USE=-wayland
# https://gitlab.xfce.org/xfce/xfce4-panel/-/issues/833
"${FILESDIR}/${P}-build.patch"
)
src_configure() {
local myconf=(
$(use_enable introspection)
$(use_enable dbusmenu dbusmenu-gtk3)
$(use_enable vala)
$(use_enable wayland)
$(use_enable wayland gtk-layer-shell)
$(use_enable X x11)
)
use vala && vala_setup
econf "${myconf[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
}
pkg_postinst() {
xdg_icon_cache_update
xdg_desktop_database_update
}
pkg_postrm() {
xdg_icon_cache_update
xdg_desktop_database_update
}
|
GitWeb