Add vde flag to expose new VDE support

Package-Manager: portage-2.2_rc6/cvs/Linux 2.6.26-gentoo x86_64

4 files changed, 213 insertions, 8 deletions

diff --git a/app-emulation/kvm/ChangeLog b/app-emulation/kvm/ChangeLog
index 74ebb101e3a4..e35d70bfe71c 100644
--- a/app-emulation/kvm/ChangeLog
+++ b/app-emulation/kvm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/kvm
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/kvm/ChangeLog,v 1.10 2008/08/04 21:08:00 dang Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/kvm/ChangeLog,v 1.11 2008/08/07 14:37:12 dang Exp $
+
+*kvm-72-r1 (07 Aug 2008)
+
+  07 Aug 2008; Daniel Gryniewicz <dang@gentoo.org> metadata.xml,
+  +kvm-72-r1.ebuild:
+  Add vde flag to expose new VDE support
 
   04 Aug 2008; Daniel Gryniewicz <dang@gentoo.org> metadata.xml,
   +kvm-72.ebuild:
diff --git a/app-emulation/kvm/Manifest b/app-emulation/kvm/Manifest
index af8292f8eaef..e0a66f14ec79 100644
--- a/app-emulation/kvm/Manifest
+++ b/app-emulation/kvm/Manifest
@@ -8,13 +8,14 @@ DIST kvm-patches-20080716.tar.gz 31882 RMD160 ebe8151d661095e667d1b36b85217ace89
 EBUILD kvm-70-r1.ebuild 5565 RMD160 fbfd0b38ac7eb23980a9f3b6af167bed1ba2166b SHA1 1a0b79d4bd9ea288fda6cd1538b4b8792ee930a2 SHA256 5cc07e032e168347348cfbdebaceb88e074de0c6f0d05e0b2971848d17d2e51d
 EBUILD kvm-70.ebuild 5518 RMD160 951c9c6cfb2290115a544011bd6bce9614e2fa5a SHA1 dbdc0b2419323b7c803838ef621f00ba165f3b68 SHA256 800cc398871a05919871c32a8fcfe1011245e6781b50cc8ce75a849f6c15f585
 EBUILD kvm-71-r2.ebuild 6233 RMD160 b45fe4f99911c479900ba9d457f823e30e28551f SHA1 f84942e2e937ececc4410eab1345952f2081bb74 SHA256 ea33cccd78455dbe9f797d1570e0b18a087349d1a2e867702807fc9b7161e834
+EBUILD kvm-72-r1.ebuild 6308 RMD160 2d2a58c823f5789b2c0c158ce46f8728193e88d9 SHA1 2138a395443155690810fd04cf2646863fd90970 SHA256 9a0e03bb60deca3810356616c9d1c474202afba9db15c117fb80b6f0ed9a53bd
 EBUILD kvm-72.ebuild 6230 RMD160 81bcdbe7ebef70301c4ad782d4c5279e6f7b9ae0 SHA1 7629aa4bca2834261f887d565740b314b736b027 SHA256 e58644c6ae6d668cce279b1ddf191444663de90a4c00f78e54f5a799f991f09b
-MISC ChangeLog 2873 RMD160 3a7645c310131048de3b19abdd5e0f835574a541 SHA1 67644cdcc3ad0fd8ddd06822ac1fca990cfa72d2 SHA256 078fdcba5093353322bd2a505cbdaaf09c7f31ee70f5247ab3c0bd6d559889cc
-MISC metadata.xml 815 RMD160 9fc08b542397aaed365d366d0fb9f9186790e31d SHA1 90cbe495ea9f78daeb93487500774e2ce4c15750 SHA256 d0202c04d56b8e5b0e88f7372b181bdbca99e9de07ef2186e3e3924dbdf9321b
+MISC ChangeLog 3027 RMD160 a604892ac46bad169868e099756ab4292ecde02b SHA1 f56a62331e118bb8d8ee5da5fb30d6f8ba2df6b5 SHA256 9c1c8e89e08ec7acc16d8c907dd1d58622fc7a83faabcdae86be76e83ff6a730
+MISC metadata.xml 1206 RMD160 7eccc3315c6280b8f843477707ef8218f20f807e SHA1 2959c23142dafa1c9de0ed1703c22f44222afb81 SHA256 495de6cfd4670ab4bfb6557c9249a184b55921f0f4eb8206dca247fa4ce4a991
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.9 (GNU/Linux)
 
-iD8DBQFIl2++omPajV0RnrERAotzAJ4nlWVZb76nNXcCSAKry5EIvZ+wtwCdF/5X
-H5W8OmrqbbXJkz/TFqr0yT4=
-=xAu8
+iD8DBQFImwimomPajV0RnrERAh6SAJ4pdqY6as7VaQGvEOOUo8T9XFymcgCeNNtj
+77GL+nrzUbv2e25eEPONta8=
+=IbTT
 -----END PGP SIGNATURE-----
diff --git a/app-emulation/kvm/kvm-72-r1.ebuild b/app-emulation/kvm/kvm-72-r1.ebuild
new file mode 100644
index 000000000000..231eb138017f
--- /dev/null
+++ b/app-emulation/kvm/kvm-72-r1.ebuild
@@ -0,0 +1,192 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/kvm/kvm-72-r1.ebuild,v 1.1 2008/08/07 14:37:12 dang Exp $
+
+inherit eutils flag-o-matic toolchain-funcs linux-mod
+
+# Patchset git repo is at http://github.com/dang/kvm-patches/tree/master
+PATCHSET="kvm-patches-20080716"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	mirror://gentoo/${PATCHSET}.tar.gz"
+
+DESCRIPTION="Kernel-based Virtual Machine userland tools"
+HOMEPAGE="http://kvm.qumranet.com/kvmwiki"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+# Add bios back when it builds again
+IUSE="alsa esd gnutls havekernel ncurses pulseaudio sdl test vde"
+RESTRICT="test"
+
+RDEPEND="sys-libs/zlib
+	alsa? ( >=media-libs/alsa-lib-1.0.13 )
+	esd? ( media-sound/esound )
+	pulseaudio? ( media-sound/pulseaudio )
+	gnutls? ( net-libs/gnutls )
+	ncurses? ( sys-libs/ncurses )
+	sdl? ( >=media-libs/libsdl-1.2.11 )
+	vde? ( net-misc/vde )"
+
+#    bios? (
+#        sys-devel/dev86
+#        dev-lang/perl
+#        sys-power/iasl
+#    )
+DEPEND="${RDEPEND}
+	gnutls? ( dev-util/pkgconfig )
+	app-text/texi2html"
+
+QA_TEXTRELS="usr/bin/kvm"
+
+pkg_setup() {
+	# check kernel version
+	if use havekernel ; then
+		ewarn "You have the 'havekernel' use flag set.  This means you"
+		ewarn "must ensure you have a compatible kernel on your own."
+	elif kernel_is lt 2 6 22; then
+		eerror "the kvm in your kernel requires an older version of"
+		eerror "kvm as shown in :"
+		eerror "  http://kvm.qumranet.com/kvmwiki/Downloads"
+		die "kvm version not compatible"
+	fi
+
+	# check for kvm support
+	if use havekernel ; then
+		ewarn "You have the 'havekernel' use flag set.  This means you"
+		ewarn "must ensure your kernel has KVM support enable on your own"
+	elif ! linux_chkconfig_present KVM; then
+		eerror "Please enable KVM support in your kernel, found at:"
+		eerror
+		eerror "  Virtualization"
+		eerror "    Kernel-based Virtual Machine (KVM) support"
+		die "KVM support not detected!"
+	fi
+
+	enewgroup kvm
+}
+
+src_unpack() {
+	unpack ${A}
+
+	cd "${S}"
+	# prevent docs to get automatically installed
+	sed -i '/$(DESTDIR)$(docdir)/d' qemu/Makefile
+	# Alter target makefiles to accept CFLAGS set via flag-o
+	sed -i 's/^\(C\|OP_C\|HELPER_C\)FLAGS=/\1FLAGS+=/' \
+		qemu/Makefile qemu/Makefile.target
+	[[ -x /sbin/paxctl ]] && \
+		sed -i 's/^VL_LDFLAGS=$/VL_LDFLAGS=-Wl,-z,execheap/' \
+			qemu/Makefile.target
+	# avoid strip
+	sed -i 's/$(INSTALL) -m 755 -s/$(INSTALL) -m 755/' qemu/Makefile
+
+	epatch \
+		"${WORKDIR}/${PATCHSET}"/kvm-45-qemu-configure.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-61-qemu-kvm.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-57-qemu-kvm-cmdline.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-57-kernel-longmode.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-68-libkvm-no-kernel.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-69-qemu-no-blobs.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-69-qemu-ifup_ifdown.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-70-block-rw-range-check.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-71-qemu-kvm-doc.patch \
+		"${WORKDIR}/${PATCHSET}"/kvm-71-qemu-configure.patch
+}
+
+src_compile() {
+	local mycc conf_opts audio_opts
+
+	audio_opts="oss"
+	use gnutls || conf_opts="$conf_opts --disable-vnc-tls"
+	use ncurses || conf_opts="$conf_opts --disable-curses"
+	use sdl || conf_opts="$conf_opts --disable-gfx-check --disable-sdl"
+	use vde && conf_opts="$conf_opts --enable-vde"
+	use alsa && audio_opts="alsa $audio_opts"
+	use esd && audio_opts="esd $audio_opts"
+	use pulseaudio && audio_opts="pa $audio_opts"
+	use sdl && audio_opts="sdl $audio_opts"
+	conf_opts="$conf_opts --disable-gcc-check"
+	conf_opts="$conf_opts --prefix=/usr"
+	#conf_opts="$conf_opts --audio-drv-list=\"$audio_opts\""
+
+	./configure ${conf_opts} --audio-drv-list="$audio_opts" || die "econf failed"
+
+	emake libkvm || die "emake libkvm failed"
+
+	if use test; then
+		emake user || die "emake user failed"
+	fi
+
+	mycc=$(cat qemu/config-host.mak | egrep "^CC=" | cut -d "=" -f 2)
+
+	filter-flags -fpie -fstack-protector
+
+	# If using gentoo's compiler set the SPEC to non-hardened
+	if [ ! -z ${GCC_SPECS} -a -f ${GCC_SPECS} ]; then
+		local myccver=$(${mycc} -dumpversion)
+		local gccver=$($(tc-getBUILD_CC) -dumpversion)
+
+		#Is this a SPEC for the right compiler version?
+		myspec="${GCC_SPECS/${gccver}/${myccver}}"
+		if [ "${myspec}" == "${GCC_SPECS}" ]; then
+			shopt -s extglob
+			GCC_SPECS="${GCC_SPECS/%hardened*specs/vanilla.specs}"
+			shopt -u extglob
+		else
+			unset GCC_SPECS
+		fi
+	fi
+
+#    if use bios; then
+#        emake bios || die "emake bios failed"
+#        emake vgabios || die "emake vgabios failed"
+#    fi
+
+	emake qemu || die "emake qemu failed"
+}
+
+src_install() {
+	# kcmd so we don't install kernel modules which weren't build
+	emake DESTDIR="${D}" kcmd='#' install || die "make install failed"
+
+	exeinto /usr/bin/
+	doexe "${S}/kvm_stat"
+
+	mv "${D}"/usr/share/man/man1/qemu.1 "${D}"/usr/share/man/man1/kvm.1
+	mv "${D}"/usr/share/man/man1/qemu-img.1 "${D}"/usr/share/man/man1/kvm-img.1
+	mv "${D}"/usr/share/man/man8/qemu-nbd.8 "${D}"/usr/share/man/man8/kvm-nbd.8
+	mv "${D}"/usr/bin/qemu-img "${D}"/usr/bin/kvm-img
+	mv "${D}"/usr/bin/qemu-nbd "${D}"/usr/bin/kvm-nbd
+
+	insinto /etc/udev/rules.d/
+	doins scripts/65-kvm.rules
+
+	insinto /etc/kvm/
+	insopts -m0755
+	newins scripts/qemu-ifup kvm-ifup
+	newins scripts/qemu-ifdown kvm-ifdown
+
+	dodoc qemu/pc-bios/README
+	newdoc qemu/qemu-doc.html kvm-doc.html
+	newdoc qemu/qemu-tech.html kvm-tech.html
+}
+
+pkg_postinst() {
+	elog "If you don't have kvm compiled into the kernel, make sure you have"
+	elog "the kernel module loaded before running kvm. The easiest way to"
+	elog "ensure that the kernel module is loaded is to load it on boot."
+	elog "For AMD CPUs the module is called 'kvm-amd'"
+	elog "For Intel CPUs the module is called 'kvm-intel'"
+	elog "Please review /etc/conf.d/modules for how to load these"
+	elog
+	elog "Make sure your user is in the 'kvm' group"
+	elog "Just run 'gpasswd -a <USER> kvm', then have <USER> re-login."
+	elog
+	elog "You will need the Universal TUN/TAP driver compiled into your"
+	elog "kernel or loaded as a module to use the virtual network device"
+	elog "if using -net tap.  You will also need support for 802.1d"
+	elog "Ethernet Bridging and a configured bridge if using the provided"
+	elog "kvm-ifup script from /etc/kvm."
+	echo
+}
diff --git a/app-emulation/kvm/metadata.xml b/app-emulation/kvm/metadata.xml
index cac634592f93..c837b0689f1d 100644
--- a/app-emulation/kvm/metadata.xml
+++ b/app-emulation/kvm/metadata.xml
@@ -16,10 +16,16 @@
 		or AMD-V)
 	</longdescription>
 	<use>
-		<flag name='bios'>Compile BIOS from source (not necessary to run
-			<pkg>app-emulation/kvm</pkg></flag>
+		<flag name='alsa'>Enable alsa output for sound emulation</flag>
+		<flag name='esd'>Enable esound output for sound emulation</flag>
+		<flag name='gnutls'>Enable TLS support for the VNC console server</flag>
 		<flag name='havekernel'>Don't require a kernel build tree (useful if
 			using a binary distrbuted kernel aka binary packages)</flag>
+		<flag name='ncurses'>Enable the ncurses-based console</flag>
+		<flag name='pulseaudio'>Enable pulseaudio output for sound emulation</flag>
+		<flag name='sdl'>Enable the SDL-based console</flag>
+		<flag name='test'>Build tests</flag>
+		<flag name='vde'>Enable VDE-based networking</flag>
 	</use>
 </pkgmetadata>