Bug #267886.

Package-Manager: portage-2.1.9.24/cvs/Linux i686

1 files changed, 70 insertions, 0 deletions

diff --git a/app-office/openerp-server/openerp-server-5.0.6.ebuild b/app-office/openerp-server/openerp-server-5.0.6.ebuild
new file mode 100644
index 000000000000..71d034f9f1a5
--- /dev/null
+++ b/app-office/openerp-server/openerp-server-5.0.6.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/openerp-server/openerp-server-5.0.6.ebuild,v 1.1 2010/12/13 11:02:20 elvanor Exp $
+
+EAPI="2"
+
+inherit eutils distutils
+
+DESCRIPTION="Open Source ERP & CRM"
+HOMEPAGE="http://www.openerp.com/"
+SRC_URI="http://www.openerp.com/download/stable/source/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+CDEPEND="dev-db/postgresql-server
+	dev-python/lxml
+	dev-python/psycopg
+	dev-python/pychart
+	dev-python/pytz
+	dev-python/pyxml
+	dev-python/pyopenssl
+	dev-python/reportlab
+	media-gfx/pydot"
+
+RDEPEND="${CDEPEND}"
+DEPEND="${CDEPEND}"
+
+OPENERP_USER="openerp"
+OPENERP_GROUP="openerp"
+
+src_install() {
+	distutils_src_install
+
+	doinitd "${FILESDIR}/${PN}"
+	newconfd "${FILESDIR}/openerp-server-confd" "${PN}"
+	keepdir /var/run/openerp
+	keepdir /var/log/openerp
+
+	rm "${D}/usr/bin/openerp-server"
+}
+
+pkg_preinst() {
+	enewgroup ${OPENERP_GROUP}
+	enewuser ${OPENERP_USER} -1 -1 -1 ${OPENERP_GROUP}
+
+	fowners ${OPENERP_USER}:${OPENERP_GROUP} /var/run/openerp
+	fowners ${OPENERP_USER}:${OPENERP_GROUP} /var/log/openerp
+}
+
+pkg_postinst() {
+	elog "In order to setup the initial database, run:"
+	elog "  emerge --config =${CATEGORY}/${PF}"
+	elog "Be sure the database is started before"
+}
+
+pquery() {
+	psql -q -At -U postgres -d template1 -c "$@"
+}
+
+pkg_config() {
+	einfo "In the following, the 'postgres' user will be used."
+	if ! pquery "SELECT usename FROM pg_user WHERE usename = '${OPENERP_USER}'" | grep -q ${OPENERP_USER}; then
+		ebegin "Creating database user ${OPENERP_USER}"
+		createuser --quiet --username=postgres --createdb --no-adduser ${OPENERP_USER}
+		eend $? || die "Failed to create database user"
+	fi
+}