In a revbump, add subunit useflag to fix bug 354091 by flameeyes, bump to EAPI=4, and move to using autotools-utils eclass (adding static-libs useflag).

Package-Manager: portage-2.2.0_alpha55-r1/cvs/Linux x86_64

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-libs/check/check-0.9.8-r1.ebuild b/dev-libs/check/check-0.9.8-r1.ebuild
new file mode 100644
index 000000000000..78c94662c61a
--- /dev/null
+++ b/dev-libs/check/check-0.9.8-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/check/check-0.9.8-r1.ebuild,v 1.1 2011/09/29 12:39:53 binki Exp $
+
+EAPI=4
+inherit autotools autotools-utils eutils
+
+DESCRIPTION="A unit test framework for C"
+HOMEPAGE="http://sourceforge.net/projects/check/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="static-libs subunit"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-0.9.6-AM_PATH_CHECK.patch \
+		"${FILESDIR}"/${PN}-0.9.6-64bitsafe.patch
+
+	sed -i -e '/^docdir =/d' {.,doc}/Makefile.am || die
+
+	# fix out-of-sourcedir build having inconsistent check.h files, for
+	# example breaks USE=subunit.
+	rm src/check.h || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-dependency-tracking
+		$(use_enable subunit)
+		--docdir=/usr/share/doc/${PF}
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+	dodoc AUTHORS *ChangeLog* NEWS README THANKS TODO
+
+	rm -f "${D}"/usr/share/doc/${PF}/COPYING* || die
+	find "${D}" -name '*.la' -exec rm -f {} + || die
+}