migrate to multilib, bug #479282

Package-Manager: portage-2.2.0_alpha196/cvs/Linux x86_64
Manifest-Sign-Key: 0x160F534A

3 files changed, 251 insertions, 5 deletions

diff --git a/dev-libs/glib/ChangeLog b/dev-libs/glib/ChangeLog
index d32bdc0f6cba..b6c97f825bda 100644
--- a/dev-libs/glib/ChangeLog
+++ b/dev-libs/glib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.565 2013/07/26 20:39:10 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.566 2013/08/10 14:24:32 aballier Exp $
+
+*glib-2.36.3-r2 (10 Aug 2013)
+
+  10 Aug 2013; Alexis Ballier <aballier@gentoo.org> +glib-2.36.3-r2.ebuild:
+  migrate to multilib, bug #479282
 
 *glib-2.36.3-r1 (26 Jul 2013)
 
diff --git a/dev-libs/glib/Manifest b/dev-libs/glib/Manifest
index b2d3e45b2beb..c6b7930810f9 100644
--- a/dev-libs/glib/Manifest
+++ b/dev-libs/glib/Manifest
@@ -26,13 +26,14 @@ EBUILD glib-1.2.10-r5.ebuild 1802 SHA256 b8561be2cdbe967604c39b6316bee46016e6213
 EBUILD glib-2.32.4-r1.ebuild 8283 SHA256 dd2679288fa2fc9ac701c7e28802ea9cd651e0ecfeb21aba77408fd7f3cad044 SHA512 84dff6719a77eb70d2b80473750521518b49cd353927034192f83e58e5ce81ff7a4333545a300f0ad71e4eb1a4d6b69fa0cf55c1cd85ce603fd47ccdb170373d WHIRLPOOL 8e06ee1377e42d79ab138e5775b6ba86bad3183213a3b6053e8f841019b53c23f3907a1a34a7f2b57e9f83e804c06868d39493ca8bc7abb719cf7190af824e65
 EBUILD glib-2.34.3.ebuild 8559 SHA256 f1af100fd9f3ee7723687b8cb62ba4c31c1460f745bf4fd0ab5a61546ca72841 SHA512 b0fde730dab39339c838474b28097a73d7300f4b50dae36544a1dde6b57a22fbdb02e21df2c087f44e14de8d272fdcb77b2fe91b5ea28a4aa922aba860dca00d WHIRLPOOL a3422c3a2c9068fcd45cfd0a1d428ec19760620fe10030f1de4ca19b348f19d4a0eab97dee982f04986d3038413b3fcb980b6846d38d32dec1fd67590d21f0b4
 EBUILD glib-2.36.3-r1.ebuild 8459 SHA256 5f6c191593d6cc0a44442c9cec540b48b4791416fdf22010acd9ad858b735c55 SHA512 1c56ce38aa7333e39fbbda431f212bfac83b70975ae49de55a11bb700e17771310b16237ff5673f61c370ced886cbeb72e4c898cf79749bf55744cea699fd76a WHIRLPOOL 826c64dfcc60b293d659c45e1ece35ac60e758a6b7a0d6a71e4ce00a87bc30c881decf1dd2f18410f156383dbf5bc062397ae74e53321cc7654ec452edd17d4c
+EBUILD glib-2.36.3-r2.ebuild 8726 SHA256 decb1b98b30db6a0ced4a53b68a91455df3822661a97ba74514a41b964a479b1 SHA512 38cfc1ffd924aa966f5d044f743197df453a7db8b5fd47ceee4deec8d10ff08e92ae254ebbcde89346b5dada280e32e3bc091fe22c07a270ae3859de1e0cb66d WHIRLPOOL f234c22495014ed985f2177c274327cafa09fb0bae84abcd342dee8eb6141ea2e7cd8dd35f15f4cbfc1ae1f05096f038de3e14bbe40afcb1125cac00b2530c9a
 EBUILD glib-2.36.3.ebuild 9202 SHA256 c806edb96874dd4d9e3a8fff70f8091723b0cd884bff0032e2c78b98db57da21 SHA512 7ebfcc9df549e1ed1cff863fd3d6c2458609e44f58698d2f37262950de552e9985e3d33a07917268054f9a8dfef0f179e6c77ef5c01b7d47b7941e1e9cd4df8b WHIRLPOOL 024a575e623d2710752afa2eea1ae6a38ec35e2dcf795854172dbb06e6bc1c8760b90c5e43883d1833481fdf77cce03c16d0e80f47692b987658b89efed23558
-MISC ChangeLog 78592 SHA256 76999f9d04ec1b3ef6e09ae77cc4b14bffd2bb9010d6476040720520e721d91a SHA512 49cc9de4ff0b65c3a2dc5d861de01036903fbaa5f43691f64724d106504183ac247b94b9444e805d83b4e3a8a71247024e5e1dfc179245e5a06d5b7167223090 WHIRLPOOL 3caeb3e3df3e5632e31cce355793a3e667cfb7522a2ae8a675e60b307450a0bdc53d0356b8fba2d0643a74a19621c09727d8f9387368ae35d716d8a02974b2c9
+MISC ChangeLog 78738 SHA256 943788520dfa3ffebade76b9aea1cd5e71bd3521db750889bf6efe3517bfccdf SHA512 7bdbd9c3bf95d72e103a303f0a4e8420503a71cdcf1d7c92111ab4b1d00c37cab52ea7dc826f7684f030ed1161ac05e2e9d265dcb6cdc505d55f2a54801de85b WHIRLPOOL e19bd2e77a43ae1ce00e398575e4aa3dbec32816867b7cf9a33840f3b9372a5343dfb4636429150eb6a3500330cdf126a5e9e68c66187d8cb5c36b499b089884
 MISC metadata.xml 479 SHA256 1a41cb4f56511674a423efd444f7c6999b5d316f9058d2eb67a032a522738ffb SHA512 f30f9e937d43dd4fb148dc7ab1554b5c58ddf4211bc06cfc65e92ff9843a84f0b05fa130fcd130744ad6e3579fb5b82a7f31950dd8ccc317f58388023cb6fe50 WHIRLPOOL 92888cd8e3a839860cb20c60ad1ee2871ea9efdf54d5751d6b5f677faf10e721333c3d68b1b5c4af212854f9ecd9e31970832eaa05f30276987bcadacaf5f637
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.20 (GNU/Linux)
 
-iEYEAREIAAYFAlHy3m8ACgkQCaWpQKGI+9QPTACcCR1+GtPg1rql+uc7fUwwPxMG
-7RYAn1GpxlVm5x99ducTBXE6L7b0USKq
-=iFV8
+iEYEAREIAAYFAlIGTSIACgkQvFcC4BYPU0ryawCgpdStAq0Tl+DAslBCDZyrEYgi
+tPoAn3nMbJbw1tUDlse1pQa2XNMxXCmN
+=Dxfo
 -----END PGP SIGNATURE-----
diff --git a/dev-libs/glib/glib-2.36.3-r2.ebuild b/dev-libs/glib/glib-2.36.3-r2.ebuild
new file mode 100644
index 000000000000..004ad8b48a3c
--- /dev/null
+++ b/dev-libs/glib/glib-2.36.3-r2.ebuild
@@ -0,0 +1,240 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.36.3-r2.ebuild,v 1.1 2013/08/10 14:24:32 aballier Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python2_{5,6,7} )
+# Avoid runtime dependency on python when USE=test
+
+inherit autotools bash-completion-r1 gnome.org libtool eutils flag-o-matic gnome2-utils multilib pax-utils python-r1 toolchain-funcs versionator virtualx linux-info multilib-minimal
+
+DESCRIPTION="The GLib library of C routines"
+HOMEPAGE="http://www.gtk.org/"
+
+LICENSE="LGPL-2+"
+SLOT="2"
+IUSE="debug fam kernel_linux selinux static-libs systemtap test utils xattr"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+
+RDEPEND="
+	virtual/libiconv[${MULTILIB_USEDEP}]
+	virtual/libffi[${MULTILIB_USEDEP}]
+	sys-libs/zlib[${MULTILIB_USEDEP}]
+	|| (
+		>=dev-libs/elfutils-0.142
+		>=dev-libs/libelf-0.8.12 )
+	xattr? ( sys-apps/attr[${MULTILIB_USEDEP}] )
+	fam? ( virtual/fam[${MULTILIB_USEDEP}] )
+	utils? (
+		${PYTHON_DEPS}
+		>=dev-util/gdbus-codegen-${PV}[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	>=dev-libs/libxslt-1.0
+	>=sys-devel/gettext-0.11
+	>=dev-util/gtk-doc-am-1.15
+	systemtap? ( >=dev-util/systemtap-1.3 )
+	test? (
+		sys-devel/gdb
+		${PYTHON_DEPS}
+		>=dev-util/gdbus-codegen-${PV}[${PYTHON_USEDEP}]
+		>=sys-apps/dbus-1.2.14 )
+	!<dev-libs/gobject-introspection-1.$(get_version_component_range 2)
+	!<dev-util/gtk-doc-1.15-r2
+"
+# gobject-introspection blocker to ensure people don't mix
+# different g-i and glib major versions
+
+PDEPEND="x11-misc/shared-mime-info
+	!<gnome-base/gvfs-1.6.4-r990"
+# shared-mime-info needed for gio/xdgmime, bug #409481
+# Earlier versions of gvfs do not work with glib
+
+DOCS="AUTHORS ChangeLog* NEWS* README"
+
+pkg_setup() {
+	if use kernel_linux ; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		if use test; then
+			CONFIG_CHECK="~IPV6"
+			WARNING_IPV6="Your kernel needs IPV6 support for running some tests, skipping them."
+			export IPV6_DISABLED="yes"
+		fi
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	# Fix gmodule issues on fbsd; bug #184301, upstream bug #107626
+	epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch
+
+	if use test; then
+		# Do not try to remove files on live filesystem, upstream bug #619274
+		sed 's:^\(.*"/desktop-app-info/delete".*\):/*\1*/:' \
+			-i "${S}"/gio/tests/desktop-app-info.c || die "sed failed"
+
+		# Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629, upstream bug #629163
+		if ! has_version dev-util/desktop-file-utils ; then
+			ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
+			ewarn "think on installing it to get these tests run."
+			sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
+			sed -i -e "/desktop-app-info\/default/d" gio/tests/desktop-app-info.c || die
+			sed -i -e "/desktop-app-info\/fallback/d" gio/tests/desktop-app-info.c || die
+			sed -i -e "/desktop-app-info\/lastused/d" gio/tests/desktop-app-info.c || die
+		fi
+
+		# gdesktopappinfo requires existing terminal (gnome-terminal or any
+		# other), falling back to xterm if one doesn't exist
+		if ! has_version x11-terms/xterm && ! has_version x11-terms/gnome-terminal ; then
+			ewarn "Some tests will be skipped due to missing terminal program"
+			sed -i -e "/appinfo\/launch/d" gio/tests/appinfo.c || die
+		fi
+
+		# Disable tests requiring dbus-python and pygobject; bugs #349236, #377549, #384853
+		if ! has_version dev-python/dbus-python || ! has_version 'dev-python/pygobject:3' ; then
+			ewarn "Some tests will be skipped due to dev-python/dbus-python or dev-python/pygobject:3"
+			ewarn "not being present on your system, think on installing them to get these tests run."
+			sed -i -e "/connection\/filter/d" gio/tests/gdbus-connection.c || die
+			sed -i -e "/connection\/large_message/d" gio/tests/gdbus-connection-slow.c || die
+			sed -i -e "/gdbus\/proxy/d" gio/tests/gdbus-proxy.c || die
+			sed -i -e "/gdbus\/proxy-well-known-name/d" gio/tests/gdbus-proxy-well-known-name.c || die
+			sed -i -e "/gdbus\/introspection-parser/d" gio/tests/gdbus-introspection.c || die
+			sed -i -e "/g_test_add_func/d" gio/tests/gdbus-threading.c || die
+			sed -i -e "/gdbus\/method-calls-in-thread/d" gio/tests/gdbus-threading.c || die
+			# needed to prevent gdbus-threading from asserting
+			ln -sfn $(type -P true) gio/tests/gdbus-testserver.py
+		fi
+
+		# Some tests need ipv6, upstream bug #667468
+		if [[ -n "${IPV6_DISABLED}" ]]; then
+			sed -i -e "/socket\/ipv6_sync/d" gio/tests/socket.c || die
+			sed -i -e "/socket\/ipv6_async/d" gio/tests/socket.c || die
+			sed -i -e "/socket\/ipv6_v4mapped/d" gio/tests/socket.c || die
+		fi
+
+		# Test relies on /usr/bin/true, but we have /bin/true, upstream bug #698655
+		sed -i -e "s:/usr/bin/true:/bin/true:" gio/tests/desktop-app-info.c || die
+
+		# thread test fails, upstream bug #679306
+		epatch "${FILESDIR}/${PN}-2.34.0-testsuite-skip-thread4.patch"
+	fi
+
+	# gdbus-codegen is a separate package
+	epatch "${FILESDIR}/${PN}-2.35.x-external-gdbus-codegen.patch"
+
+	# leave python shebang alone
+	sed -e '/${PYTHON}/d' \
+		-i glib/Makefile.{am,in} || die
+
+	# Gentoo handles completions in a different directory
+	sed -i "s|^completiondir =.*|completiondir = $(get_bashcompdir)|" \
+		gio/Makefile.am || die
+
+	# Revert "g_file_set_contents(): don't fsync on ext3/4" (from 2.36 branch)
+	epatch "${FILESDIR}/${P}-revert-ext34.patch"
+
+	epatch_user
+
+	# Needed for the punt-python-check patch, disabling timeout test
+	# Also needed to prevent croscompile failures, see bug #267603
+	# Also needed for the no-gdbus-codegen patch
+	eautoreconf
+
+	# FIXME: Really needed when running eautoreconf before? bug#????
+	#[[ ${CHOST} == *-freebsd* ]] && elibtoolize
+
+	epunt_cxx
+}
+
+multilib_src_configure() {
+	# Avoid circular depend with dev-util/pkgconfig and
+	# native builds (cross-compiles won't need pkg-config
+	# in the target ROOT to work here)
+	if ! tc-is-cross-compiler && ! $(tc-getPKG_CONFIG) --version >& /dev/null; then
+		if has_version sys-apps/dbus; then
+			export DBUS1_CFLAGS="-I/usr/include/dbus-1.0 -I/usr/$(get_libdir)/dbus-1.0/include"
+			export DBUS1_LIBS="-ldbus-1"
+		fi
+		export LIBFFI_CFLAGS="-I$(echo /usr/$(get_libdir)/libffi-*/include)"
+		export LIBFFI_LIBS="-lffi"
+	fi
+
+	local myconf
+
+	# Building with --disable-debug highly unrecommended.  It will build glib in
+	# an unusable form as it disables some commonly used API.  Please do not
+	# convert this to the use_enable form, as it results in a broken build.
+	use debug && myconf="--enable-debug"
+
+	# Only used by the gresource bin
+	multilib_is_native_abi || myconf="${myconf} --disable-libelf"
+
+	# Always use internal libpcre, bug #254659
+	ECONF_SOURCE="${S}" econf ${myconf} \
+		$(use_enable xattr) \
+		$(use_enable fam) \
+		$(use_enable selinux) \
+		$(use_enable static-libs static) \
+		$(use_enable systemtap dtrace) \
+		$(use_enable systemtap systemtap) \
+		$(use_enable test modular-tests) \
+		--enable-man \
+		--with-pcre=internal \
+		--with-threads=posix \
+		--with-xml-catalog="${EPREFIX}/etc/xml/catalog"
+}
+
+multilib_src_install_all() {
+	if use utils ; then
+		python_replicate_script "${ED}"/usr/bin/gtester-report
+	else
+		rm "${ED}usr/bin/gtester-report"
+		rm "${ED}usr/share/man/man1/gtester-report.1"
+	fi
+
+	# Do not install charset.alias even if generated, leave it to libiconv
+	rm -f "${ED}/usr/lib/charset.alias"
+
+	# Don't install gdb python macros, bug 291328
+	rm -rf "${ED}/usr/share/gdb/" "${ED}/usr/share/glib-2.0/gdb/"
+
+	# Completely useless with or without USE static-libs, people need to use
+	# pkg-config
+	prune_libtool_files --modules
+}
+
+multilib_src_test() {
+	gnome2_environment_reset
+
+	unset DBUS_SESSION_BUS_ADDRESS
+	export XDG_CONFIG_DIRS=/etc/xdg
+	export XDG_DATA_DIRS=/usr/local/share:/usr/share
+	export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
+	unset GSETTINGS_BACKEND # bug 352451
+	export LC_TIME=C # bug #411967
+	python_export_best
+
+	# Related test is a bit nitpicking
+	mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+	chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+
+	# Hardened: gdb needs this, bug #338891
+	if host-is-pax ; then
+		pax-mark -mr "${BUILD_DIR}"/tests/.libs/assert-msg-test \
+			|| die "Hardened adjustment failed"
+	fi
+
+	# Need X for dbus-launch session X11 initialization
+	Xemake check
+}
+
+pkg_postinst() {
+	if has_version '<x11-libs/gtk+-3.0.12:3'; then
+		# To have a clear upgrade path for gtk+-3.0.x users, have to resort to
+		# a warning instead of a blocker
+		ewarn
+		ewarn "Using <gtk+-3.0.12:3 with ${P} results in frequent crashes."
+		ewarn "You should upgrade to a newer version of gtk+:3 immediately."
+	fi
+}