Really fix bug 239583, fix linking against optional deps, fix compiler usage for cross compile

Package-Manager: portage-2.2_rc26/cvs/Linux x86_64

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-libs/libtomcrypt/libtomcrypt-1.17-r3.ebuild b/dev-libs/libtomcrypt/libtomcrypt-1.17-r3.ebuild
new file mode 100644
index 000000000000..14f2d6f9fc91
--- /dev/null
+++ b/dev-libs/libtomcrypt/libtomcrypt-1.17-r3.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libtomcrypt/libtomcrypt-1.17-r3.ebuild,v 1.1 2009/03/18 20:35:01 tommy Exp $
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="modular and portable cryptographic toolkit"
+HOMEPAGE="http://libtom.org/?page=features&whatfile=crypt"
+SRC_URI="http://libtom.org/files/crypt-${PV}.tar.bz2"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc libtommath tomsfastmath"
+
+RDEPEND="libtommath? ( dev-libs/libtommath )
+	tomsfastmath? ( dev-libs/tomsfastmath )
+	!libtommath? ( !tomsfastmath? ( dev-libs/libtommath ) )"
+DEPEND="${RDEPEND}
+	doc? ( virtual/latex-base virtual/ghostscript )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	use doc || sed -i '/^install:/s:docs::' makefile
+	epatch "${FILESDIR}"/libtomcrypt-1.17-r2-libtool-tag-and-make-fix.patch
+}
+
+src_compile() {
+	local extraflags=""
+	use libtommath && append-flags -DLTM_DESC && extraflags="-ltommath"
+	use tomsfastmath && append-flags -DTFM_DESC && extraflags="${extraflags} -ltfm"
+	sed -i -e "s:gcc:$(tc-getCC):g" \
+		-e "s:--mode=link gcc:--mode=link $(tc-getCC) --tag CC $(tc-getCC):g" \
+		{,testprof/}makefile.shared
+	EXTRALIBS="${extraflags}" emake -f makefile.shared IGNORE_SPEED=1 || die "emake failed"
+}
+
+src_install() {
+	emake -f makefile.shared DESTDIR="${D}" install ||\
+		die "emake install failed"
+	dodoc TODO changes || die "dodoc failed"
+	if use doc ; then
+		dodoc doc/* || die "dodoc failed"
+		docinto notes ; dodoc notes/* || die "dodoc failed"
+		docinto demos ; dodoc demos/* || die "dodoc failed"
+	fi
+}