Migrate to distutils-r1. Switch examples to USE=examples (rather than USE=doc).

Package-Manager: portage-2.2.0_alpha169/cvs/Linux x86_64
Manifest-Sign-Key: 0x9627F456F9DA7643!

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-python/celementtree/celementtree-1.0.5-r2.ebuild b/dev-python/celementtree/celementtree-1.0.5-r2.ebuild
new file mode 100644
index 000000000000..ef63d10d4f87
--- /dev/null
+++ b/dev-python/celementtree/celementtree-1.0.5-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/celementtree/celementtree-1.0.5-r2.ebuild,v 1.1 2013/03/26 19:01:51 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+
+inherit distutils-r1
+
+MY_P="cElementTree-${PV}-20051216"
+
+DESCRIPTION="The cElementTree module is a C implementation of the ElementTree API"
+HOMEPAGE="http://effbot.org/zone/celementtree.htm http://pypi.python.org/pypi/cElementTree"
+SRC_URI="http://effbot.org/downloads/${MY_P}.tar.gz"
+
+LICENSE="ElementTree"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris"
+IUSE="examples"
+
+RDEPEND=">=dev-python/elementtree-1.2[${PYTHON_USEDEP}]
+	>=dev-libs/expat-1.95.8"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}/${P}-use_system_expat.patch"
+		"${FILESDIR}/${P}-setuptools.patch"
+	)
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" selftest.py || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( samples/. selftest.py )
+
+	distutils-r1_python_install_all
+}