Add ruby20 target.

Package-Manager: portage-2.2.7/cvs/Linux x86_64

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-ruby/fakefs/fakefs-0.4.3-r1.ebuild b/dev-ruby/fakefs/fakefs-0.4.3-r1.ebuild
new file mode 100644
index 000000000000..739087c70886
--- /dev/null
+++ b/dev-ruby/fakefs/fakefs-0.4.3-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/fakefs/fakefs-0.4.3-r1.ebuild,v 1.1 2013/10/06 12:07:31 mrueg Exp $
+
+EAPI=5
+
+USE_RUBY="ruby18 ruby19 ruby20 jruby"
+
+RUBY_FAKEGEM_RECIPE_TEST="none"
+
+# requires sdoc
+RUBY_FAKEGEM_TASK_DOC=""
+
+RUBY_FAKEGEM_EXTRADOC="CONTRIBUTORS README.markdown"
+
+inherit ruby-fakegem eutils
+
+DESCRIPTION="A fake filesystem. Use it in your tests."
+HOMEPAGE="http://github.com/defunkt/fakefs"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/rspec:2
+		>=dev-ruby/test-unit-2.5.1-r1
+	)"
+
+all_ruby_prepare() {
+	# Remove bundler
+	rm Gemfile || die
+}
+
+each_ruby_prepare() {
+	case ${RUBY} in
+		*jruby)
+			# Ignore failing tests: upstream is aware and doing the same
+			# on Travis.
+			rm test/fakefs_test.rb test/file/stat_test.rb || die
+			;;
+		*)
+			;;
+	esac
+}
+
+each_ruby_test() {
+	ruby-ng_rspec
+	ruby-ng_testrb-2 -Ilib:test test/**/*_test.rb
+}