Version bump

Package-Manager: portage-2.2.20/cvs/Linux x86_64
Manifest-Sign-Key: 0xA188FBD4

1 files changed, 56 insertions, 0 deletions

diff --git a/gnome-extra/seahorse-nautilus/seahorse-nautilus-3.11.92.ebuild b/gnome-extra/seahorse-nautilus/seahorse-nautilus-3.11.92.ebuild
new file mode 100644
index 000000000000..56fb0cbe37b4
--- /dev/null
+++ b/gnome-extra/seahorse-nautilus/seahorse-nautilus-3.11.92.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/seahorse-nautilus/seahorse-nautilus-3.11.92.ebuild,v 1.1 2015/06/07 11:26:51 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="Nautilus extension for encrypting and decrypting files with GnuPG"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/Seahorse"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="
+	>=app-crypt/gpgme-1.0.0
+	>=app-crypt/gcr-3.4
+	>=dev-libs/dbus-glib-0.35
+	>=dev-libs/glib-2.28:2
+	gnome-base/gnome-keyring
+	>=gnome-base/nautilus-3
+	x11-libs/gtk+:3
+	>=x11-libs/libcryptui-3.9.90
+	>=x11-libs/libnotify-0.3:=
+	>=app-crypt/gnupg-1.4
+"
+# seahorse-nautilus was formerly part of seahorse-plugins
+RDEPEND="${COMMON_DEPEND}
+	!app-crypt/seahorse-plugins[nautilus]
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Do not let configure mangle CFLAGS
+	sed -e '/^[ \t]*CFLAGS="$CFLAGS \(-g\|-O0\)/d' -i configure.ac configure ||
+		die "sed failed"
+
+	# Fix icon location, upstream bug #719763
+	sed -i 's/pixmaps\/seahorse-plugins\/48x48/pixmaps\/cryptui\/48x48/' \
+		tool/seahorse-notification.c || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-gpg-check \
+		--enable-libnotify
+}