Version bump KDE 4.4.2

Package-Manager: portage-2.2_rc67/cvs/Linux x86_64
RepoMan-Options: --force

1 files changed, 47 insertions, 0 deletions

diff --git a/kde-base/dolphin/dolphin-4.4.2.ebuild b/kde-base/dolphin/dolphin-4.4.2.ebuild
new file mode 100644
index 000000000000..673adc689bd5
--- /dev/null
+++ b/kde-base/dolphin/dolphin-4.4.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/dolphin/dolphin-4.4.2.ebuild,v 1.1 2010/03/30 19:24:05 spatz Exp $
+
+EAPI="3"
+
+KMNAME="kdebase-apps"
+inherit kde4-meta
+
+DESCRIPTION="A KDE filemanager focusing on usability"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug +handbook semantic-desktop subversion thumbnail"
+
+DEPEND="
+	$(add_kdebase_dep kdelibs 'semantic-desktop?')
+	$(add_kdebase_dep libkonq)
+	semantic-desktop? ( >=dev-libs/shared-desktop-ontologies-0.2 )
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep kfind)
+	subversion? (
+		dev-util/subversion
+		$(add_kdebase_dep kompare)
+	)
+"
+PDEPEND="
+	thumbnail? ( $(add_kdebase_dep mplayerthumbs) )
+"
+
+KMLOADLIBS="libkonq"
+
+src_prepare() {
+	kde4-meta_src_prepare
+
+	if ! use subversion; then
+		sed -e '/install(.*fileviewsvnplugin.*)/s/^/#DONOTINSTALL /g' \
+			-i dolphin/src/CMakeLists.txt || die 'failed to disable subversion plugin'
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+	)
+
+	kde4-meta_src_configure
+}