KDE SC 4.5.3 Version bump

Package-Manager: portage-2.2.0_alpha3/cvs/Linux x86_64
RepoMan-Options: --force

2 files changed, 55 insertions, 1 deletions

diff --git a/kde-base/kget/ChangeLog b/kde-base/kget/ChangeLog
index eafbda3a2bf2..a82b265344ac 100644
--- a/kde-base/kget/ChangeLog
+++ b/kde-base/kget/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kget
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kget/ChangeLog,v 1.176 2010/10/06 09:17:16 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kget/ChangeLog,v 1.177 2010/11/03 16:30:30 scarabeus Exp $
+
+*kget-4.5.3 (03 Nov 2010)
+
+  03 Nov 2010; Tomáš Chvátal <scarabeus@gentoo.org> +kget-4.5.3.ebuild:
+  Version bump
 
 *kget-4.5.2 (05 Oct 2010)
 
diff --git a/kde-base/kget/kget-4.5.3.ebuild b/kde-base/kget/kget-4.5.3.ebuild
new file mode 100644
index 000000000000..70a97d2a37e1
--- /dev/null
+++ b/kde-base/kget/kget-4.5.3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kget/kget-4.5.3.ebuild,v 1.1 2010/11/03 16:30:30 scarabeus Exp $
+
+EAPI="3"
+
+KDE_HANDBOOK="optional"
+KMNAME="kdenetwork"
+WEBKIT_REQUIRED="optional"
+inherit kde4-meta
+
+DESCRIPTION="An advanced download manager for KDE"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug bittorrent semantic-desktop sqlite"
+
+RDEPEND="
+	app-crypt/qca:2
+	$(add_kdebase_dep kdelibs 'semantic-desktop?')
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep libkonq)
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep solid)
+	bittorrent? ( >=net-libs/libktorrent-1.0.3 )
+	sqlite? ( dev-db/sqlite:3 )
+	webkit? ( >=kde-misc/kwebkitpart-0.9.6 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+
+src_prepare() {
+	kde4-meta_src_prepare
+	# Disable bittorrent as supported mimetype
+	if ! use bittorrent; then
+		sed -e '/MimeType=/s|application/x-bittorrent;||' \
+			-i kget/desktop/kget.desktop || die
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with bittorrent KTorrent)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with sqlite)
+		$(cmake-utils_use_with webkit KWebKitPart)
+	)
+	kde4-meta_src_configure
+}