the new pam config needs a patch to avoid 100% cpu usage by lxdm-binary. See: https://bugs.launchpad.net/ubuntu/+source/lxdm/+bug/922363

Package-Manager: portage-2.2.0_alpha166/cvs/Linux x86_64
Manifest-Sign-Key: 0xADC916E5

1 files changed, 81 insertions, 0 deletions

diff --git a/lxde-base/lxdm/lxdm-0.4.1-r7.ebuild b/lxde-base/lxdm/lxdm-0.4.1-r7.ebuild
new file mode 100644
index 000000000000..ef382dccdd6d
--- /dev/null
+++ b/lxde-base/lxdm/lxdm-0.4.1-r7.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxdm/lxdm-0.4.1-r7.ebuild,v 1.1 2013/05/05 20:14:22 lxnay Exp $
+
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="LXDE Display Manager"
+HOMEPAGE="http://lxde.org"
+SRC_URI="mirror://sourceforge/lxde/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+IUSE="debug gtk3 nls pam"
+
+RDEPEND="sys-auth/consolekit
+	x11-libs/libxcb
+	gtk3? ( x11-libs/gtk+:3 )
+	!gtk3? ( x11-libs/gtk+:2 )
+	nls? ( sys-devel/gettext )
+	pam? ( virtual/pam )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig"
+
+src_prepare() {
+	# Upstream bug, tarball contains pre-made lxdm.conf
+	rm "${S}"/data/lxdm.conf || die
+
+	# There is consolekit
+	epatch "${FILESDIR}/${P}-pam_console-disable.patch"
+	# Fix null pointer dereference, backported from git
+	epatch "${FILESDIR}/${P}-git-fix-null-pointer-deref.patch"
+
+	epatch "${FILESDIR}"/${P}-configure-add-pam.patch
+
+	# 403999
+	epatch "${FILESDIR}"/${P}-missing-pam-defines.patch
+
+	# 412025
+	epatch "${FILESDIR}"/${P}-event-check.patch
+
+	# 393329 Selinux support
+	epatch "${FILESDIR}"/${P}-selinux-support.patch
+
+	# See https://bugs.launchpad.net/ubuntu/+source/lxdm/+bug/922363
+	epatch "${FILESDIR}/${P}-fix-pam-100-cpu.patch"
+
+	# this replaces the bootstrap/autogen script in most packages
+	eautoreconf
+
+	# process LINGUAS
+	if use nls; then
+		einfo "Running intltoolize ..."
+		intltoolize --force --copy --automake || die
+		strip-linguas -i "${S}/po" || die
+	fi
+}
+src_configure() {
+	econf	--enable-password \
+		--with-x \
+		--with-xconn=xcb \
+		$(use_enable gtk3) \
+		$(use_enable nls) \
+		$(use_enable debug) \
+		$(use_with pam)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS README TODO || die
+}
+
+pkg_postinst() {
+	echo
+	elog "LXDM in the early stages of development!"
+	echo
+}