Version bump.

Package-Manager: portage-2.1.4.4

4 files changed, 233 insertions, 2 deletions

diff --git a/mail-client/claws-mail-gtkhtml/ChangeLog b/mail-client/claws-mail-gtkhtml/ChangeLog
index 7a2322e132f3..4d9dec577ad0 100644
--- a/mail-client/claws-mail-gtkhtml/ChangeLog
+++ b/mail-client/claws-mail-gtkhtml/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for mail-client/claws-mail-gtkhtml
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail-gtkhtml/ChangeLog,v 1.22 2008/02/13 20:48:56 ticho Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail-gtkhtml/ChangeLog,v 1.23 2008/02/23 12:57:45 ticho Exp $
+
+*claws-mail-gtkhtml-0.17.2 (23 Feb 2008)
+
+  23 Feb 2008; Andrej Kacian <ticho@gentoo.org>
+  +claws-mail-gtkhtml-0.17.2.ebuild:
+  Version bump.
 
 *claws-mail-gtkhtml-0.17.1 (13 Feb 2008)
 
diff --git a/mail-client/claws-mail-gtkhtml/claws-mail-gtkhtml-0.17.2.ebuild b/mail-client/claws-mail-gtkhtml/claws-mail-gtkhtml-0.17.2.ebuild
new file mode 100644
index 000000000000..414094affa74
--- /dev/null
+++ b/mail-client/claws-mail-gtkhtml/claws-mail-gtkhtml-0.17.2.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail-gtkhtml/claws-mail-gtkhtml-0.17.2.ebuild,v 1.1 2008/02/23 12:57:45 ticho Exp $
+
+inherit eutils
+
+MY_P="${PN#claws-mail-}2_viewer-${PV}"
+
+DESCRIPTION="Renders HTML mail using the gtkhtml2 rendering widget."
+HOMEPAGE="http://claws.sylpheed.org"
+SRC_URI="http://www.claws-mail.org/downloads/plugins/${MY_P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+DEPEND=">=mail-client/claws-mail-3.3.1
+		=gnome-extra/gtkhtml-2*
+		net-misc/curl
+		dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_install() {
+	make DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog NEWS README
+
+	# kill useless files
+	rm -f "${D}"/usr/lib*/claws-mail/plugins/*.{a,la}
+}
diff --git a/mail-client/claws-mail/ChangeLog b/mail-client/claws-mail/ChangeLog
index d229c815afff..e57d4764b88a 100644
--- a/mail-client/claws-mail/ChangeLog
+++ b/mail-client/claws-mail/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for mail-client/claws-mail
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v 1.65 2008/02/16 10:30:02 ticho Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v 1.66 2008/02/23 12:57:01 ticho Exp $
+
+*claws-mail-3.3.1 (23 Feb 2008)
+
+  23 Feb 2008; Andrej Kacian <ticho@gentoo.org> +claws-mail-3.3.1.ebuild:
+  Version bump.
 
   16 Feb 2008; Andrej Kacian <ticho@gentoo.org> claws-mail-3.3.0.ebuild:
   Removed clamav from list of external plugins, due to licensing constraints.
diff --git a/mail-client/claws-mail/claws-mail-3.3.1.ebuild b/mail-client/claws-mail/claws-mail-3.3.1.ebuild
new file mode 100644
index 000000000000..0a10c0c5a916
--- /dev/null
+++ b/mail-client/claws-mail/claws-mail-3.3.1.ebuild
@@ -0,0 +1,191 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/claws-mail-3.3.1.ebuild,v 1.1 2008/02/23 12:57:01 ticho Exp $
+
+IUSE="bogofilter crypt dillo doc gnome gnutls imap ipv6 kde ldap nntp pda session spamassassin spell ssl startup-notification xface"
+
+inherit eutils multilib
+
+DESCRIPTION="Claws-Mail is an email client (and news reader) based on GTK+"
+HOMEPAGE="http://www.claws-mail.org"
+
+if [ -n "${P/*_rc*/}" ]; then
+	SRC_URI="mirror://sourceforge/sylpheed-claws/${P}.tar.bz2"
+else
+	MY_P="${P/_/-}"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="http://www.claws-mail.org/snapshots/${MY_P}.tar.bz2"
+fi
+
+SLOT="0"
+LICENSE="GPL-3"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+COMMONDEPEND=">=x11-libs/gtk+-2.6
+	pda? ( >=app-pda/jpilot-0.99 )
+	ssl? ( >=dev-libs/openssl-0.9.7 )
+	ldap? ( >=net-nds/openldap-2.0.7 )
+	crypt? ( >=app-crypt/gpgme-1.1.1 )
+	dillo? ( www-client/dillo )
+	spell? ( virtual/aspell-dict )
+	kde? ( kde-base/kdelibs )
+	imap? ( >=net-libs/libetpan-0.49 )
+	nntp? ( >=net-libs/libetpan-0.49 )
+	gnome? ( >=gnome-base/libgnomeprintui-2.2 )
+	gnutls? ( net-libs/gnutls )
+	startup-notification? ( x11-libs/startup-notification )
+	bogofilter? ( mail-filter/bogofilter )
+	session? ( x11-libs/libSM
+			x11-libs/libICE )"
+
+DEPEND="${COMMONDEPEND}
+	xface? ( >=media-libs/compface-1.4 )
+	>=sys-apps/sed-4
+	dev-util/pkgconfig"
+
+RDEPEND="${COMMONDEPEND}
+	app-misc/mime-types
+	x11-misc/shared-mime-info"
+
+PLUGIN_NAMES="acpi-notifier att-remover attachwarner cachesaver etpan-privacy fetchinfo gtkhtml maildir mailmbox newmail notification pdf-viewer perl rssyl smime synce vcalendar"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+}
+
+src_compile() {
+	local myconf="--disable-libetpan"
+
+	# libetpan is needed if user wants nntp or imap functionality
+	# TODO: Perhaps change it into a single "libetpan" USE flag?
+	use imap && myconf="--enable-libetpan"
+	use nntp && myconf="--enable-libetpan"
+
+	# Optional features
+	myconf="${myconf} `use_enable gnome gnomeprint`"
+	myconf="${myconf} `use_enable ipv6`"
+	myconf="${myconf} `use_enable ldap`"
+	myconf="${myconf} `use_enable pda jpilot`"
+	myconf="${myconf} `use_enable spell aspell`"
+	myconf="${myconf} `use_enable gnutls`"
+	myconf="${myconf} `use_enable ssl openssl`"
+	myconf="${myconf} `use_enable xface compface`"
+	myconf="${myconf} `use_enable doc manual`"
+	myconf="${myconf} `use_enable startup-notification`"
+	myconf="${myconf} `use_enable session libsm`"
+
+	# Optional plugins
+	myconf="${myconf} `use_enable crypt pgpmime-plugin`"
+	myconf="${myconf} `use_enable crypt pgpinline-plugin`"
+	myconf="${myconf} `use_enable crypt pgpcore-plugin`"
+	myconf="${myconf} `use_enable dillo dillo-viewer-plugin`"
+	myconf="${myconf} `use_enable spamassassin spamassassin-plugin`"
+	myconf="${myconf} `use_enable bogofilter bogofilter-plugin`"
+
+	econf \
+		--enable-trayicon-plugin \
+		--disable-maemo \
+		${myconf} || die "./configure failed"
+
+	emake || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	# Makefile install claws-mail.png in /usr/share/icons/hicolor/48x48/apps
+	# => also install it in /usr/share/pixmaps for other desktop envs
+	# => also install higher resolution icons in /usr/share/icons/hicolor/...
+	insinto /usr/share/pixmaps
+	doins ${PN}.png || die
+	local res resdir
+	for res in 64x64 128x128 ; do
+		resdir="/usr/share/icons/hicolor/${res}/apps"
+		insinto ${resdir}
+		newins ${PN}-${res}.png ${PN}.png || die
+	done
+
+	dodoc AUTHORS ChangeLog* INSTALL* NEWS README* TODO*
+	docinto tools
+	dodoc tools/README*
+
+	insinto /usr/share/applications
+	doins ${PN}.desktop
+
+	einfo "Installing extra tools"
+	cd "${S}"/tools
+	exeinto /usr/$(get_libdir)/${PN}/tools
+	doexe *.pl *.py *.conf *.sh || die
+	doexe tb2claws-mail update-po uudec uuooffice || die
+
+	if use kde; then
+		einfo "Installing kde service scripts"
+		local kdeprefix="$(kde-config --prefix)"
+		local servicescript="${PN}-kdeservicemenu.pl"
+		local desktopfile="${PN}-attach-files.desktop"
+		cd "${S}"/tools/kdeservicemenu
+		sed -i -e "s:SCRIPT_PATH:${kdeprefix}/bin/${servicescript}:g" \
+			${desktopfile}.template
+		dodir /usr/share/apps/konqueror/servicemenus
+		insopts -m 0644
+		insinto /usr/share/apps/konqueror/servicemenus
+		newins ${desktopfile}.template ${desktopfile} || die
+		dodir ${kdeprefix}/bin
+		insopts -m 755
+		exeinto ${kdeprefix}/bin
+		doexe ${servicescript} || die
+	fi
+
+	# kill useless plugin files
+	rm -f "${D}"/usr/lib*/${PN}/plugins/*.{la,a}
+}
+
+pkg_postinst() {
+	gtk-update-icon-cache -f -t "${ROOT}"/usr/share/icons/hicolor
+
+	UPDATE_PLUGINS=""
+	RENAME_PLUGINS=""
+	for x in ${PLUGIN_NAMES}; do
+		has_version mail-client/${PN}-$x && UPDATE_PLUGINS="${UPDATE_PLUGINS} $x"
+		has_version mail-client/sylpheed-claws-$x && RENAME_PLUGINS="${RENAME_PLUGINS} $x"
+	done
+	if [ -n "${RENAME_PLUGINS}" ]; then
+		elog
+		elog "The following sylpheed-claws plugins were found on your system:"
+		elog
+		for x in ${RENAME_PLUGINS}; do
+			elog "    mail-client/sylpheed-claws-$x"
+		done
+		elog
+		elog "If you want to continue using those you need to merge their "
+		elog "renamed counterparts:"
+		elog
+		for x in ${RENAME_PLUGINS}; do
+			elog "    mail-client/${PN}-$x"
+		done
+		elog
+	fi
+	if [ -n "${UPDATE_PLUGINS}" ]; then
+		elog
+		elog "You have to re-emerge or update the following plugins:"
+		elog
+		for x in ${UPDATE_PLUGINS}; do
+			elog "    mail-client/${PN}-$x"
+		done
+		elog
+	fi
+	if [ -n "${RENAME_PLUGINS}${UPDATE_PLUGINS}" ]; then
+		elog
+		elog "You can use"
+		elog "    /bin/bash ${FILESDIR}/plugins-rebuild.sh"
+		elog "to automatically handle this."
+		elog
+		epause 5
+		ebeep 3
+	fi
+}
+
+pkg_postrm() {
+	gtk-update-icon-cache -f -t "${ROOT}"/usr/share/icons/hicolor
+}