Version bump on 3.2 and 3.3 branches.

Package-Manager: portage-2.2.0_alpha115/cvs/Linux i686

1 files changed, 58 insertions, 0 deletions

diff --git a/media-sound/audacious/audacious-3.3_beta1.ebuild b/media-sound/audacious/audacious-3.3_beta1.ebuild
new file mode 100644
index 000000000000..dbfd6b257fd3
--- /dev/null
+++ b/media-sound/audacious/audacious-3.3_beta1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/audacious-3.3_beta1.ebuild,v 1.1 2012/07/05 01:00:52 jdhore Exp $
+
+EAPI=4
+inherit eutils
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="http://distfiles.audacious-media-player.org/${MY_P}.tar.bz2
+	 mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS=""
+
+IUSE="chardet nls session"
+
+RDEPEND=">=dev-libs/dbus-glib-0.60
+	>=dev-libs/glib-2.16
+	dev-libs/libxml2
+	>=x11-libs/cairo-1.2.6
+	>=x11-libs/pango-1.8.0
+	x11-libs/gtk+:3
+	session? ( x11-libs/libSM )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	chardet? ( >=app-i18n/libguess-1.1 )
+	nls? ( dev-util/intltool )"
+
+PDEPEND=">=media-plugins/audacious-plugins-3.3_beta1"
+
+src_configure() {
+	# D-Bus is a mandatory dependency, remote control,
+	# session management and some plugins depend on this.
+	# Building without D-Bus is *unsupported* and a USE-flag
+	# will not be added due to the bug reports that will result.
+	# Bugs #197894, #199069, #207330, #208606
+	econf \
+		--enable-dbus \
+		$(use_enable chardet) \
+		$(use_enable nls) \
+		$(use_enable session sm)
+}
+
+src_install() {
+	default
+	dodoc AUTHORS
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins "${WORKDIR}"/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}