Version bump. Fixes bug #227043. Thanks to chutzpah for the help.

Package-Manager: portage-2.2_rc4/cvs/Linux 2.6.26-gentoo i686

9 files changed, 429 insertions, 8 deletions

diff --git a/media-sound/alsa-firmware/ChangeLog b/media-sound/alsa-firmware/ChangeLog
index f9c10b95719d..6bc02cb2f379 100644
--- a/media-sound/alsa-firmware/ChangeLog
+++ b/media-sound/alsa-firmware/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/alsa-firmware
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-firmware/ChangeLog,v 1.83 2008/06/09 14:06:01 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-firmware/ChangeLog,v 1.84 2008/08/02 21:00:13 betelgeuse Exp $
+
+*alsa-firmware-1.0.17 (02 Aug 2008)
+
+  02 Aug 2008; Petteri Räty <betelgeuse@gentoo.org>
+  +alsa-firmware-1.0.17.ebuild:
+  Version bump. Fixes bug #227043. Thanks to chutzpah for the help.
 
   09 Jun 2008; Raúl Porcel <armin76@gentoo.org>
   alsa-firmware-1.0.14.ebuild, alsa-firmware-1.0.15.ebuild,
diff --git a/media-sound/alsa-firmware/alsa-firmware-1.0.17.ebuild b/media-sound/alsa-firmware/alsa-firmware-1.0.17.ebuild
new file mode 100644
index 000000000000..9c61a0c5e3ec
--- /dev/null
+++ b/media-sound/alsa-firmware/alsa-firmware-1.0.17.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-firmware/alsa-firmware-1.0.17.ebuild,v 1.1 2008/08/02 21:00:13 betelgeuse Exp $
+
+MY_P="${P/_rc/rc}"
+
+DESCRIPTION="Advanced Linux Sound Architecture firmware"
+HOMEPAGE="http://www.alsa-project.org/"
+SRC_URI="mirror://alsaproject/firmware/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+ECHOAUDIO_CARDS="alsa_cards_darla20 alsa_cards_gina20
+alsa_cards_layla20 alsa_cards_darla24 alsa_cards_gina24
+alsa_cards_layla24 alsa_cards_mona alsa_cards_mia alsa_cards_indigo
+alsa_cards_indigoio alsa_cards_echo3g"
+
+EMU_CARDS="alsa_cards_emu1212 alsa_cards_emu1616 alsa_cards_emu1820"
+
+IUSE="alsa_cards_pcxhr alsa_cards_vx222 alsa_cards_usb-usx2y
+alsa_cards_hdsp alsa_cards_hdspm alsa_cards_mixart alsa_cards_asihpi
+alsa_cards_sb16 alsa_cards_korg1212 alsa_cards_maestro3 alsa_cards_emi26
+alsa_cards_ymfpci alsa_cards_wavefront alsa_cards_msnd-pinnacle
+alsa_cards_aica ${ECHOAUDIO_CARDS} ${EMU_CARDS}"
+
+S="${WORKDIR}/${MY_P}"
+
+DEPEND=""
+RDEPEND="alsa_cards_usb-usx2y? ( sys-apps/fxload )
+	alsa_cards_hdsp? ( media-sound/alsa-tools )
+	alsa_cards_hdspm? ( media-sound/alsa-tools )
+	alsa_cards_mixart? ( || ( >=sys-fs/udev-096 media-sound/alsa-tools ) )
+	alsa_cards_vx222? ( || ( >=sys-fs/udev-096 media-sound/alsa-tools ) )
+	alsa_cards_pcxhr? ( || ( >=sys-fs/udev-096 >=media-sound/alsa-tools-1.0.14_rc1-r1 ) )"
+
+src_compile() {
+	econf \
+		--with-hotplug-dir=/lib/firmware \
+		|| die "configure failed"
+
+	emake || die "make failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	use alsa_cards_pcxhr || rm -rf "${D}/usr/share/alsa/firmware/pcxhrloader" "${D}/lib/firmware/pcxhr"
+	use alsa_cards_vx222 || rm -rf "${D}/usr/share/alsa/firmware/vxloader" "${D}/lib/firmware/vx"
+	use alsa_cards_usb-usx2y || rm -rf "${D}/usr/share/alsa/firmware/usx2yloader" "${D}/lib/firmware/vx"
+	use alsa_cards_mixart || rm -rf "${D}/usr/share/alsa/firmware/mixartloader" "${D}/lib/firmware/mixart"
+	use alsa_cards_hdsp || use alsa_cards_hdspm || rm -rf "${D}/usr/share/alsa/firmware/hdsploader"
+	use alsa_cards_asihpi || rm -rf "${D}/lib/firmware/asihpi"
+	use alsa_cards_sb16 || rm -rf "${D}/lib/firmware/sb16"
+	use alsa_cards_korg1212 || rm -rf "${D}/lib/firmware/korg"
+	use alsa_cards_maestro3 || rm -rf "${D}/lib/firmware/ess"
+	use alsa_cards_emi26 || rm -rf "${D}lib/firmware/emagic"
+	use alsa_cards_ymfpci || rm -rf "${D}lib/firmware/yamaha"
+	use alsa_cards_wavefront || rm -rf "${D}/lib/firmware/wavefront"
+	use alsa_cards_msnd-pinnacle || rm -rf "${D}/lib/firmware/turtlebeach"
+	use alsa_cards_aica || rm -rf "${D}/lib/firmware/aica_firmware.bin"
+
+	local ea="no"
+	for card in ${ECHOAUDIO_CARDS}; do
+		use ${card} && ea="yes" && break
+	done
+
+	local emu="no"
+	for card in ${EMU_CARDS}; do
+		use ${card} && emu="yes" && break
+	done
+
+	[[ ${ea} == "no" ]] && rm -rf "${D}/lib/firmware/ea"
+	[[ ${emu} == "no" ]] && rm -rf "${D}/lib/firmware/emu"
+
+	insinto /etc/udev/rules.d
+	use alsa_cards_usb-usx2y && doins "${FILESDIR}/52-usx2yaudio.rules"
+
+	dodoc README || die
+}
diff --git a/media-sound/alsa-headers/ChangeLog b/media-sound/alsa-headers/ChangeLog
index 424aec687f32..f445031a7b90 100644
--- a/media-sound/alsa-headers/ChangeLog
+++ b/media-sound/alsa-headers/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/alsa-headers
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-headers/ChangeLog,v 1.154 2008/06/05 07:39:49 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-headers/ChangeLog,v 1.155 2008/08/02 21:00:30 betelgeuse Exp $
+
+*alsa-headers-1.0.17 (02 Aug 2008)
+
+  02 Aug 2008; Petteri Räty <betelgeuse@gentoo.org>
+  +alsa-headers-1.0.17.ebuild:
+  Version bump. Fixes bug #227043. Thanks to chutzpah for the help.
 
   05 Jun 2008; Raúl Porcel <armin76@gentoo.org> alsa-headers-1.0.16.ebuild:
   ia64 stable
diff --git a/media-sound/alsa-headers/alsa-headers-1.0.17.ebuild b/media-sound/alsa-headers/alsa-headers-1.0.17.ebuild
new file mode 100644
index 000000000000..74cd1b7393d0
--- /dev/null
+++ b/media-sound/alsa-headers/alsa-headers-1.0.17.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-headers/alsa-headers-1.0.17.ebuild,v 1.1 2008/08/02 21:00:30 betelgeuse Exp $
+
+inherit eutils
+
+MY_PN=${PN/headers/driver}
+MY_P="${MY_PN}-${PV/_rc/rc}"
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="Header files for Advanced Linux Sound Architecture kernel modules"
+HOMEPAGE="http://www.alsa-project.org/"
+SRC_URI="mirror://alsaproject/driver/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
+IUSE=""
+
+DEPEND=""
+
+RESTRICT="binchecks strip"
+
+# Remove the sound symlink workaround...
+pkg_setup() {
+	if [[ -L "${ROOT}/usr/include/sound" ]]; then
+		rm	"${ROOT}/usr/include/sound"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+
+	cd "${S}"
+	epatch "${FILESDIR}/${PN}-1.0.6a-user.patch"
+}
+
+src_compile() { :; }
+
+src_install() {
+	cd "${S}/alsa-kernel/include"
+	insinto /usr/include/sound
+	doins *.h || die "include failed"
+}
diff --git a/media-sound/alsa-tools/ChangeLog b/media-sound/alsa-tools/ChangeLog
index 5b1c7baea608..038d7f9ada7f 100644
--- a/media-sound/alsa-tools/ChangeLog
+++ b/media-sound/alsa-tools/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/alsa-tools
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-tools/ChangeLog,v 1.160 2008/05/13 14:53:24 beandog Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-tools/ChangeLog,v 1.161 2008/08/02 21:00:24 betelgeuse Exp $
+
+*alsa-tools-1.0.17 (02 Aug 2008)
+
+  02 Aug 2008; Petteri Räty <betelgeuse@gentoo.org>
+  +alsa-tools-1.0.17.ebuild:
+  Version bump. Fixes bug #227043. Thanks to chutzpah for the help.
 
   13 May 2008; Steve Dibb <beandog@gentoo.org> alsa-tools-1.0.16.ebuild:
   amd64 stable, bug 217075
@@ -622,9 +628,9 @@
   Version update.
   Require virtual/alsa instead of media-sound/alsa-driver.
 
-*alsa-tools-0.9.4 (03 June 2003)
+*alsa-tools-0.9.4 (03 Jun 2003)
 
-  06 June 2003; Arcady Genkin <agenkin@gentoo.org> :
+  06 Jun 2003; Arcady Genkin <agenkin@gentoo.org> :
   Added patch by Jason Rhinelander <jason-gentoo@gossamer-threads.com>
   (bug #22324) to fix compilation with gcc 3.3.
 
diff --git a/media-sound/alsa-tools/alsa-tools-1.0.17.ebuild b/media-sound/alsa-tools/alsa-tools-1.0.17.ebuild
new file mode 100644
index 000000000000..8d5e63818015
--- /dev/null
+++ b/media-sound/alsa-tools/alsa-tools-1.0.17.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-tools/alsa-tools-1.0.17.ebuild,v 1.1 2008/08/02 21:00:24 betelgeuse Exp $
+
+WANT_AUTOMAKE="1.9"
+WANT_AUTOCONF="2.5"
+
+inherit eutils flag-o-matic autotools
+
+MY_P="${P/_rc/rc}"
+
+DESCRIPTION="Advanced Linux Sound Architecture tools"
+HOMEPAGE="http://www.alsa-project.org"
+SRC_URI="mirror://alsaproject/tools/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0.9"
+KEYWORDS="~amd64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+ECHOAUDIO_CARDS="alsa_cards_darla20 alsa_cards_gina20
+alsa_cards_layla20 alsa_cards_darla24 alsa_cards_gina24
+alsa_cards_layla24 alsa_cards_mona alsa_cards_mia alsa_cards_indigo
+alsa_cards_indigoio alsa_cards_echo3g"
+
+IUSE="fltk gtk midi alsa_cards_hdsp alsa_cards_hdspm alsa_cards_mixart
+alsa_cards_vx222 alsa_cards_usb-usx2y alsa_cards_sb16 alsa_cards_sbawe
+alsa_cards_emu10k1 alsa_cards_emu10k1x alsa_cards_ice1712
+alsa_cards_rme32 alsa_cards_rme96 alsa_cards_sscape alsa_cards_pcxhr
+${ECHOAUDIO_CARDS}"
+
+RDEPEND=">=media-libs/alsa-lib-${PV}
+	fltk? ( =x11-libs/fltk-1.1* )
+	gtk? ( =x11-libs/gtk+-2* )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if use midi && ! built_with_use --missing true media-libs/alsa-lib midi; then
+		eerror ""
+		eerror "To be able to build ${CATEGORY}/${PN} with midi support you"
+		eerror "need to have built media-libs/alsa-lib with midi USE flag."
+		die "Missing midi USE flag on media-libs/alsa-lib"
+	fi
+
+	ALSA_TOOLS="ac3dec"
+
+	use midi && ALSA_TOOLS="${ALSA_TOOLS} seq/sbiload us428control"
+
+	if use gtk; then
+		use midi && use alsa_cards_ice1712 && \
+			ALSA_TOOLS="${ALSA_TOOLS} envy24control"
+		use alsa_cards_rme32 && use alsa_cards_rme96 && \
+			ALSA_TOOLS="${ALSA_TOOLS} rmedigicontrol"
+	fi
+
+	if use alsa_cards_hdsp || use alsa_cards_hdspm; then
+		ALSA_TOOLS="${ALSA_TOOLS} hdsploader"
+		use fltk && ALSA_TOOLS="${ALSA_TOOLS} hdspconf hdspmixer"
+	fi
+
+	use alsa_cards_mixart && ALSA_TOOLS="${ALSA_TOOLS} mixartloader"
+	use alsa_cards_vx222 && ALSA_TOOLS="${ALSA_TOOLS} vxloader"
+	use alsa_cards_usb-usx2y && ALSA_TOOLS="${ALSA_TOOLS} usx2yloader"
+	use alsa_cards_pcxhr && ALSA_TOOLS="${ALSA_TOOLS} pcxhr"
+	use alsa_cards_sscape && ALSA_TOOLS="${ALSA_TOOLS} sscape_ctl"
+
+	{ use alsa_cards_sb16 || use alsa_cards_sbawe; } && \
+		ALSA_TOOLS="${ALSA_TOOLS} sb16_csp"
+
+	if use alsa_cards_emu10k1 || use alsa_cards_emu10k1x; then
+		ALSA_TOOLS="${ALSA_TOOLS} as10k1 ld10k1"
+	fi
+
+	if use gtk; then
+		for card in ${ECHOAUDIO_CARDS}; do
+			if use ${card}; then
+				ALSA_TOOLS="${ALSA_TOOLS} echomixer"
+			fi
+		done
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-1.0.11-asneeded.patch"
+	epatch "${FILESDIR}/${PN}-1.0.14-asneeded.patch"
+
+	for dir in echomixer envy24control rmedigicontrol; do
+		pushd "${dir}" &> /dev/null
+		sed -i -e '/AM_PATH_GTK/d' configure.in
+		eautomake
+		popd &> /dev/null
+	done
+
+	elibtoolize
+}
+
+src_compile() {
+	if use fltk; then
+		# hdspmixer requires fltk
+		append-ldflags "-L/usr/$(get_libdir)/fltk-1.1"
+		append-flags "-I/usr/include/fltk-1.1"
+	fi
+
+	# hdspmixer is missing depconf - copy from the hdsploader directory
+	cp "${S}/hdsploader/depcomp" "${S}/hdspmixer/"
+
+	local f
+	for f in ${ALSA_TOOLS}
+	do
+		cd "${S}/${f}"
+		econf --with-gtk2 || die "econf ${f} failed"
+		emake || die "emake ${f} failed"
+	done
+}
+
+src_install() {
+	local f
+	for f in ${ALSA_TOOLS}
+	do
+		# Install the main stuff
+		cd "${S}/${f}"
+		emake DESTDIR="${D}" install || die
+
+		# Install the text documentation
+		local doc
+		for doc in README TODO ChangeLog AUTHORS; do
+			if [[ -f "${doc}" ]]; then
+				mv "${doc}" "${doc}.$(basename ${f})" || die
+				dodoc "${doc}.$(basename ${f})" || die
+			fi
+		done
+	done
+}
diff --git a/media-sound/alsa-utils/ChangeLog b/media-sound/alsa-utils/ChangeLog
index 471761e559f2..c15b24b042d2 100644
--- a/media-sound/alsa-utils/ChangeLog
+++ b/media-sound/alsa-utils/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/alsa-utils
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.241 2008/06/05 07:43:04 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.242 2008/08/02 21:00:32 betelgeuse Exp $
+
+*alsa-utils-1.0.17 (02 Aug 2008)
+
+  02 Aug 2008; Petteri Räty <betelgeuse@gentoo.org>
+  +files/alsa-utils-1.0.17-seq.patch, +alsa-utils-1.0.17.ebuild:
+  Version bump. Fixes bug #227043. Thanks to chutzpah for the help.
 
   05 Jun 2008; Raúl Porcel <armin76@gentoo.org> alsa-utils-1.0.16.ebuild:
   ia64 stable
@@ -930,9 +936,9 @@
   11 Jul 2003; Arcady Genkin <agenkin@gentoo.org> :
   Version update.
 
-*alsa-utils-0.9.4 (03 June 2003)
+*alsa-utils-0.9.4 (03 Jun 2003)
 
-  03 June 2003; Arcady Genkin <agenkin@gentoo.org> :
+  03 Jun 2003; Arcady Genkin <agenkin@gentoo.org> :
   Version update.
 
 *alsa-utils-0.9.3 (04 May 2003)
diff --git a/media-sound/alsa-utils/alsa-utils-1.0.17.ebuild b/media-sound/alsa-utils/alsa-utils-1.0.17.ebuild
new file mode 100644
index 000000000000..0c8321b928ec
--- /dev/null
+++ b/media-sound/alsa-utils/alsa-utils-1.0.17.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.17.ebuild,v 1.1 2008/08/02 21:00:32 betelgeuse Exp $
+
+inherit eutils autotools
+
+MY_P="${P/_rc/rc}"
+
+DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
+HOMEPAGE="http://www.alsa-project.org/"
+SRC_URI="mirror://alsaproject/utils/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0.9"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
+IUSE="nls midi minimal"
+
+DEPEND=">=sys-libs/ncurses-5.1
+	dev-util/dialog
+	>=media-libs/alsa-lib-${PV}"
+RDEPEND="${DEPEND}
+	virtual/modutils
+	!minimal? ( sys-apps/pciutils )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if use midi && ! built_with_use --missing true media-libs/alsa-lib midi; then
+		eerror ""
+		eerror "To be able to build alsa-utils with midi support you need"
+		eerror "to have built media-libs/alsa-lib with midi USE flag."
+		die "Missing midi USE flag on media-libs/alsa-lib"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-1.0.11_rc2-nls.patch"
+	epatch "${FILESDIR}/${PN}-1.0.11_rc5-alsaconf-redirect.patch"
+	epatch "${FILESDIR}/${PN}-1.0.14-alsaconf-modules-update.patch"
+	epatch "${FILESDIR}/${PN}-1.0.17-seq.patch"
+
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_compile() {
+	econf $(use_enable nls) \
+		$(use_enable midi sequencer) \
+		|| die "configure failed"
+
+	emake || die "make failed"
+}
+
+pkg_preinst() {
+	if [[ -a /etc/modules.d/alsa ]] && [[ ! -a /etc/modprobe.d/alsa ]]; then
+		elog "Moving old alsa configuration in modules.d to new"
+		elog "location in modprobe.d in /etc/"
+		mv "${ROOT}/etc/modules.d/alsa" "${ROOT}/etc/modprobe.d/alsa"
+	fi
+}
+
+src_install() {
+	local ALSA_UTILS_DOCS="ChangeLog README TODO
+		seq/aconnect/README.aconnect
+		seq/aseqnet/README.aseqnet"
+
+	emake DESTDIR="${D}" install || die "Installation Failed"
+
+	dodoc ${ALSA_UTILS_DOCS} || die
+	newdoc alsamixer/README README.alsamixer || die
+
+	newinitd "${FILESDIR}/alsasound.initd" alsasound
+	newconfd "${FILESDIR}/alsasound.confd" alsasound
+	insinto /etc/modprobe.d
+	newins "${FILESDIR}/alsa-modules.conf-rc" alsa
+
+	keepdir /var/lib/alsa
+}
+
+pkg_postinst() {
+	echo
+	elog "To take advantage of the init script, and automate the process of"
+	elog "loading and unloading the ALSA sound drivers as well as"
+	elog "storing and restoring sound-card mixer levels you should"
+	elog "add alsasound to the boot runlevel. You can do this as"
+	elog "root like so:"
+	elog "	# rc-update add alsasound boot"
+	echo
+	if use minimal; then
+		ewarn "The minimal use flag disables the dependency on pciutils that"
+		ewarn "is needed by alsaconf at runtime."
+	fi
+}
diff --git a/media-sound/alsa-utils/files/alsa-utils-1.0.17-seq.patch b/media-sound/alsa-utils/files/alsa-utils-1.0.17-seq.patch
new file mode 100644
index 000000000000..3214a01b29ee
--- /dev/null
+++ b/media-sound/alsa-utils/files/alsa-utils-1.0.17-seq.patch
@@ -0,0 +1,40 @@
+diff -ur alsa-utils-1.0.17.orig/configure.in alsa-utils-1.0.17/configure.in
+--- alsa-utils-1.0.17.orig/configure.in	2008-07-30 21:44:32.000000000 -0400
++++ alsa-utils-1.0.17/configure.in	2008-07-30 21:45:45.000000000 -0400
+@@ -102,6 +102,18 @@
+   TESTSOUND="$dir/test.wav")
+ AC_SUBST(TESTSOUND)
+ 
++AC_ARG_ENABLE([sequencer],
++  [AC_HELP_STRING([--disable-sequencer], [Disable sequencer utilities (aconnect, aplaymidi, aseqdump, aseqnet)])] )
++
++if test "x$enable_sequencer" != "xno"; then
++   AC_CHECK_LIB([asound], [snd_seq_open], [has_seq=yes], [has_seq=no])
++fi
++if test "x$enable_sequencer" = "xyes" && test "x$has_seq" = "xno"; then
++   AC_MSG_FAILURE([cannot find snd_seq_open. ALSA was built without sequencer support])
++fi
++
++AM_CONDITIONAL([BUILD_SEQ], [test "x$has_seq" = "xyes"])
++
+ AM_CONFIG_HEADER(include/aconfig.h)
+ 
+ dnl Checks for typedefs, structures, and compiler characteristics.
+Only in alsa-utils-1.0.17: configure.in.orig
+diff -ur alsa-utils-1.0.17.orig/Makefile.am alsa-utils-1.0.17/Makefile.am
+--- alsa-utils-1.0.17.orig/Makefile.am	2008-07-30 21:44:32.000000000 -0400
++++ alsa-utils-1.0.17/Makefile.am	2008-07-30 21:47:04.000000000 -0400
+@@ -4,7 +4,12 @@
+ else
+ ALSAMIXER_DIR=
+ endif
+-SUBDIRS= include alsactl alsaconf $(ALSAMIXER_DIR) amidi amixer aplay iecset seq speaker-test utils m4 po
++
++if BUILD_SEQ
++SEQ_DIR=seq
++endif
++
++SUBDIRS= include alsactl alsaconf $(ALSAMIXER_DIR) amidi amixer aplay iecset $(SEQ_DIR) speaker-test utils m4 po
+ EXTRA_DIST= config.rpath  config.rpath mkinstalldirs ChangeLog INSTALL TODO README configure gitcompile depcomp
+ AUTOMAKE_OPTIONS=foreign
+ ACLOCAL_AMFLAGS = -I m4