speex support is not optional so remove the speex use flag. Fixes bug #233774.

Package-Manager: portage-2.2_rc4/cvs/Linux 2.6.26-gentoo i686

3 files changed, 203 insertions, 5 deletions

diff --git a/media-sound/pulseaudio/ChangeLog b/media-sound/pulseaudio/ChangeLog
index 56e4fe05e05e..a94e2594d093 100644
--- a/media-sound/pulseaudio/ChangeLog
+++ b/media-sound/pulseaudio/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/pulseaudio
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.106 2008/08/03 02:03:17 chutzpah Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.107 2008/08/03 08:15:57 betelgeuse Exp $
+
+*pulseaudio-0.9.11-r1 (03 Aug 2008)
+
+  03 Aug 2008; Petteri Räty <betelgeuse@gentoo.org>
+  +pulseaudio-0.9.11-r1.ebuild:
+  speex support is not optional so remove the speex use flag. Fixes bug
+  #233774.
 
 *pulseaudio-0.9.11 (03 Aug 2008)
 
diff --git a/media-sound/pulseaudio/Manifest b/media-sound/pulseaudio/Manifest
index 1462c6465b4d..55b845ca5cb7 100644
--- a/media-sound/pulseaudio/Manifest
+++ b/media-sound/pulseaudio/Manifest
@@ -18,15 +18,16 @@ DIST pulseaudio-0.9.9.tar.gz 1063448 RMD160 beb9cb645ce69978ba095e73376ae8ae4b92
 EBUILD pulseaudio-0.9.10-r1.ebuild 5865 RMD160 c65dd19a6461fea44172af31884751a52763fdfc SHA1 850115327755d941ae2b058df8c307898add0387 SHA256 83d2b79632a96a169f20219d36eb2ee78f951156ebde7607012a8dca5cb75111
 EBUILD pulseaudio-0.9.10-r51.ebuild 5828 RMD160 c3f442403bece77a50678428816bc4be791a76f8 SHA1 2f33c3a8318b55546102a90bbb995f6527153785 SHA256 5328068fb5bb78203721af9b41654363ef9d8ace9801f39daf4f74a478dc8188
 EBUILD pulseaudio-0.9.10.ebuild 5668 RMD160 bbda20bb4340ef60044c9d376c70ff9dc49df6bc SHA1 cba18c72faf7b5c5fd2b9ba7ac9cdef2a5da8387 SHA256 ce1b37a01d4541b40ac0d178ddb91e756a7324ce5dbd433c7e7dbc45adfbd95c
+EBUILD pulseaudio-0.9.11-r1.ebuild 5924 RMD160 8b48f6c5f33822d1fcd62863c2be08b879d85bdf SHA1 a62454820cf70f0b0ded71d108d2617018dd36e4 SHA256 f61b20dee80bdf13ed08eea469d03e07ef049c93033e63278c5461ee5d02530c
 EBUILD pulseaudio-0.9.11.ebuild 5861 RMD160 6fa50de291158e56812058778f9097a3e1479c57 SHA1 fadeb02b6c249ff401b43ec1d5a5161c58f5f7b7 SHA256 50c8b51ad2fb666089d56ba684ecf154998ebcc4c6407d1f7643420ceea88ade
 EBUILD pulseaudio-0.9.7.ebuild 4752 RMD160 0217d3ccee281219df3a6817935f762b9a03f286 SHA1 2fca6bbfd4b2c209ca59e5313a1b45cec19c5fb2 SHA256 65803bb77985bc3bb82e0e0d01e82a7293fc61ad951a35a1672e25941725437c
 EBUILD pulseaudio-0.9.9.ebuild 5810 RMD160 db6a3d4da34ea78d6cf5901c57bc74b48082fd66 SHA1 7a659611de1b5ad7acb8e4e5ebac8ac6ec2c06f7 SHA256 90128fff4ccca7e019cd772e0faab2dc68ec8c2149aa476ddc77e1b63201279b
-MISC ChangeLog 19679 RMD160 627d9c47a65a6e6412b58944c5b23ff2992410a9 SHA1 683560db643b0fa226d2bb9a97f9fd23bc9084ed SHA256 8c99588efa30e6cf09e97532ca29c0a008497f66b3ee7c492ecb222044061f2c
+MISC ChangeLog 19887 RMD160 0cecedff586aa8b0b72886334ec4605db8af635a SHA1 8dfe77f640403bfe7625e6e2150f201b80e4026c SHA256 3b182139ff14fb087179a01dbc848d3e925f5f2f7ac5aae87d5dc1d25dec8017
 MISC metadata.xml 1106 RMD160 451b24728e90377bc829a999a76fca5b4bc91078 SHA1 6b242be79913c9ffa2aafdd95149a7fa93b3c764 SHA256 995d3c7013901cd84098a1b40975c54863751e8668874f763ec70b81e23e9a9f
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.9 (GNU/Linux)
 
-iEYEARECAAYFAkiVEgEACgkQWt/XSf2CZdkH9QCdF4AIfWhz2VqYgzOr7ox2GTR+
-Em0Anjp9CwJ1cVZsGnDp1X1n6Rq/vR0S
-=VUg/
+iEYEARECAAYFAkiVaUMACgkQcxLzpIGCsLQOxwCeNG0U65xtyjlx5dh8BbuzltLI
+y5wAniGtBxykImffmfpbMfNvEPUcDfvO
+=pESV
 -----END PGP SIGNATURE-----
diff --git a/media-sound/pulseaudio/pulseaudio-0.9.11-r1.ebuild b/media-sound/pulseaudio/pulseaudio-0.9.11-r1.ebuild
new file mode 100644
index 000000000000..73ec89a8760b
--- /dev/null
+++ b/media-sound/pulseaudio/pulseaudio-0.9.11-r1.ebuild
@@ -0,0 +1,190 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.11-r1.ebuild,v 1.1 2008/08/03 08:15:57 betelgeuse Exp $
+
+EAPI=1
+
+inherit eutils libtool autotools flag-o-matic
+
+DESCRIPTION="A networked sound server with an advanced plugin system"
+HOMEPAGE="http://0pointer.de/lennart/projects/pulseaudio/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2 GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc64 ~sparc ~x86"
+IUSE="alsa avahi caps jack lirc oss tcpd X hal dbus libsamplerate gnome bluetooth policykit asyncns +glib"
+
+RDEPEND="X? ( x11-libs/libX11 x11-libs/libSM x11-libs/libXau x11-libs/libXdmcp )
+	caps? ( sys-libs/libcap )
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
+	alsa? ( >=media-libs/alsa-lib-1.0.17 )
+	glib? ( >=dev-libs/glib-2.4.0 )
+	avahi? ( >=net-dns/avahi-0.6.12 )
+	>=dev-libs/liboil-0.3.0
+	jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	lirc? ( app-misc/lirc )
+	dbus? ( >=sys-apps/dbus-1.0.0 )
+	gnome? ( >=gnome-base/gconf-2.4.0 )
+	hal? (
+		>=sys-apps/hal-0.5.7
+		>=sys-apps/dbus-1.0.0
+	)
+	app-admin/eselect-esd
+	bluetooth? (
+		>=net-wireless/bluez-libs-3
+		>=sys-apps/dbus-1.0.0
+	)
+	policykit? ( sys-auth/policykit )
+	asyncns? ( net-libs/libasyncns )
+	>=media-libs/audiofile-0.2.6-r1
+	>=media-libs/speex-1.2_beta
+	>=media-libs/libsndfile-1.0.10
+	>=dev-libs/liboil-0.3.6
+	sys-libs/gdbm
+	sys-apps/openrc
+	>=sys-apps/baselayout-2.0_rc5
+	>=sys-devel/libtool-1.5.24" # it's a valid RDEPEND, libltdl.so is used
+DEPEND="${RDEPEND}
+	X? ( x11-proto/xproto )
+	dev-libs/libatomic_ops
+	dev-util/pkgconfig
+	dev-util/unifdef"
+
+# alsa-utils dep is for the alsasound init.d script (see bug #155707)
+# bluez-utils dep is for the bluetooth init.d script
+RDEPEND="${RDEPEND}
+	gnome-extra/gnome-audio
+	alsa? ( media-sound/alsa-utils )
+	bluetooth? ( >=net-wireless/bluez-utils-3 )"
+
+pkg_setup() {
+	if use avahi && ! built_with_use net-dns/avahi dbus ; then
+		echo
+		eerror "In order to compile pulseaudio with avahi support, you need to have"
+		eerror "net-dns/avahi emerged with 'dbus' in your USE flag. Please add that"
+		eerror "flag, re-emerge avahi, and then emerge pulseaudio again."
+		die "net-dns/avahi is missing the D-Bus bindings."
+	fi
+
+	enewgroup audio 18 # Just make sure it exists
+	enewgroup realtime
+	enewgroup pulse-access
+	enewgroup pulse
+	enewuser pulse -1 -1 /var/run/pulse pulse,audio
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Avoid building - and especially linking - test programs
+	# outside of make check
+	sed -i -e 's:noinst_PROGRAMS:check_PROGRAMS:' \
+		"${S}/src/Makefile.am"
+
+	eautoreconf
+	elibtoolize
+}
+
+src_compile() {
+	# To properly fix CVE-2008-0008
+	append-flags -UNDEBUG
+
+	econf \
+		--enable-largefile \
+		$(use_enable glib) \
+		--disable-solaris \
+		$(use_enable asyncns) \
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable lirc) \
+		$(use_enable tcpd tcpwrap) \
+		$(use_enable jack) \
+		$(use_enable lirc) \
+		$(use_enable avahi) \
+		$(use_enable hal) \
+		$(use_enable dbus) \
+		$(use_enable gnome gconf) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable bluetooth bluez) \
+		$(use_enable policykit polkit) \
+		$(use_with caps) \
+		$(use_with X x) \
+		--disable-ltdl-install \
+		--localstatedir=/var \
+		--with-realtime-group=realtime \
+		--disable-per-user-esound-socket \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install || die "make install failed"
+
+	newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio
+
+	use_define() {
+		local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}
+
+		use "$1" && echo "-D$define" || echo "-U$define"
+	}
+
+	unifdef "${FILESDIR}/pulseaudio.init.d-3" \
+		$(use_define hal) \
+		$(use_define avahi) \
+		$(use_define alsa) \
+		$(use_define bluetooth) \
+		> "${T}/pulseaudio"
+	doinitd "${T}/pulseaudio"
+
+	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"
+
+	dohtml -r doc
+	dodoc README
+
+	# Create the state directory
+	diropts -o pulse -g pulse -m0755
+	keepdir /var/run/pulse
+
+	find "${D}" -name '*.la' -delete
+}
+
+pkg_postinst() {
+	elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
+	elog "This support is enabled by starting the pulseaudio init.d ."
+	elog "To be able to access that you need to be in the group pulse-access."
+	elog "For more information about system-wide support, please refer to"
+	elog "	 http://pulseaudio.org/wiki/SystemWideInstance"
+	if use gnome; then
+		elog
+		elog "By enabling gnome USE flag, you enabled gconf support. Pleaes note"
+		elog "that you might need to remove the gnome USE flag or disable the"
+		elog "gconf module on /etc/pulse/default.pa to be able to use PulseAudio"
+		elog "with a system-wide instance."
+	fi
+	elog
+	elog "To use the ESounD wrapper while using a system-wide daemon, you also"
+	elog "need to enable auth-anonymous for the esound-unix module, or to copy"
+	elog "/var/run/pulse/.esd_auth into each home directory."
+	elog
+	elog "If you want to make use of realtime capabilities of PulseAudio"
+	elog "you should follow the realtime guide to create and set up a realtime"
+	elog "user group: http://www.gentoo.org/proj/en/desktop/sound/realtime.xml"
+	elog "Make sure you also have baselayout installed with pam USE flag"
+	elog "enabled, if you're using the rlimit method."
+	if use bluetooth; then
+		elog
+		elog "The BlueTooth proximity module is not enabled in the default"
+		elog "configuration file. If you do enable it, you'll have to have"
+		elog "your BlueTooth controller enabled and inserted at bootup or"
+		elog "PulseAudio will refuse to start."
+		elog
+		elog "Please note that the BlueTooth proximity module seems itself"
+		elog "still experimental, so please report to upstream if you have"
+		elog "problems with it."
+	fi
+
+	eselect esd update --if-unset
+}