As-needed conform linking and respecting LDFLAGS, #282733

Package-Manager: portage-2.2_rc62/cvs/Linux x86_64

1 files changed, 63 insertions, 0 deletions

diff --git a/media-video/mpeg-tools/mpeg-tools-1.5b-r4.ebuild b/media-video/mpeg-tools/mpeg-tools-1.5b-r4.ebuild
new file mode 100644
index 000000000000..aaaa75dfe7c4
--- /dev/null
+++ b/media-video/mpeg-tools/mpeg-tools-1.5b-r4.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mpeg-tools/mpeg-tools-1.5b-r4.ebuild,v 1.1 2010/02/04 23:43:33 jlec Exp $
+
+inherit eutils toolchain-funcs
+
+MY_PN=mpeg_encode
+DESCRIPTION="Tools for MPEG video"
+HOMEPAGE="http://bmrc.berkeley.edu/research/mpeg/mpeg_encode.html"
+SRC_URI="ftp://mm-ftp.cs.berkeley.edu/pub/multimedia/mpeg/encode/${MY_PN}-${PV}-src.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="x11-libs/libX11
+	>=media-libs/jpeg-7"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_PN}
+
+src_unpack () {
+	unpack ${A}
+	cd "${WORKDIR}"
+	epatch "${FILESDIR}"/${P}-build.patch
+	epatch "${FILESDIR}"/${P}-64bit_fixes.patch
+	epatch "${FILESDIR}"/${P}-tempfile-convert.patch
+	epatch "${FILESDIR}"/${P}-as-needed.patch
+	cd "${S}"
+	rm -r jpeg
+	epatch "${FILESDIR}"/${P}-system-jpeg.patch
+	epatch "${FILESDIR}"/${P}-system-jpeg-7.patch
+	epatch "${FILESDIR}"/${P}-tempfile-mpeg-encode.patch
+	epatch "${FILESDIR}"/${P}-tempfile-tests.patch
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" || die "emake failed"
+	emake -C convert CC="$(tc-getCC)" || die "emake convert failed"
+	emake -C convert/mtv CC="$(tc-getCC)" || die "emake convert/mtv failed"
+}
+
+src_install () {
+	dobin mpeg_encode || die "dobin mpeg_encode"
+	doman docs/*.1
+	dodoc BUGS CHANGES README TODO VERSION
+	dodoc docs/EXTENSIONS docs/INPUT.FORMAT docs/*.param docs/param-summary
+	docinto examples
+	dodoc examples/*
+
+	cd ../convert
+	dobin eyuvtojpeg jmovie2jpeg mpeg_demux mtv/movieToVid || die "dobin convert utils"
+	newdoc README README.convert
+	newdoc mtv/README README.mtv
+}
+
+pkg_postinst() {
+	if [[ -z $(best_version media-libs/netpbm) ]] ; then
+		elog "If you are looking for eyuvtoppm or ppmtoeyuv, please"
+		elog "emerge the netpbm package.  It has updated versions."
+	fi
+}