New snapshot

Package-Manager: portage-2.1.10.34/cvs/Linux x86_64

3 files changed, 318 insertions, 2 deletions

diff --git a/media-video/libav/ChangeLog b/media-video/libav/ChangeLog
index 9d2c1a3a4215..113cecebb224 100644
--- a/media-video/libav/ChangeLog
+++ b/media-video/libav/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/libav
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/libav/ChangeLog,v 1.36 2011/11/15 13:01:17 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/libav/ChangeLog,v 1.37 2011/11/16 03:59:51 lu_zero Exp $
+
+*libav-0.8_pre20111116 (16 Nov 2011)
+
+  16 Nov 2011; Luca Barbato <lu_zero@gentoo.org> +libav-0.8_pre20111116.ebuild:
+  New snapshot
 
   15 Nov 2011; Luca Barbato <lu_zero@gentoo.org> libav-9999.ebuild:
   Make neon sure we enable and build neon code on use neon
diff --git a/media-video/libav/Manifest b/media-video/libav/Manifest
index df1b9e1bb0b3..80ec7b3c4eb0 100644
--- a/media-video/libav/Manifest
+++ b/media-video/libav/Manifest
@@ -3,11 +3,13 @@ AUX 0.6.2-float_arrays.patch 1611 RMD160 960188d97261729526187c53a281a03c31a6a95
 DIST libav-0.6.2.tar.bz2 3639862 RMD160 fbdee25614940253e018e42a633da579704146fd SHA1 b79dc56a08f4ef07b41d1a78b2251f21fde8b81d SHA256 eb13f20bfa09664559e81ff9691cebcb77a763320ddf63c47a402351409697af
 DIST libav-0.7.2.tar.xz 3573280 RMD160 5f41d42375e66e681ac99b0183825ddc4f09b70d SHA1 938c52f122030a797e9c9ba5cab6a7cb812cd9d7 SHA256 450999ed097b0814247f44be1321c4997aee49d56cab6636b0a7257e13ba2729
 DIST libav-0.8_pre20110818.tar.xz 3588912 RMD160 ad289ef01a762fe1141a4a6db647006f98b82e98 SHA1 8d669f211edb11ca9504dc56fff3f2292b5da692 SHA256 00612c08a723cfa9885335e45db6c0083efd17229cbffeb67c5849443617f68d
+DIST libav-0.8_pre20111116.tar.xz 3672592 RMD160 dd5301bdd32e3d28472da7a4d260816bccfed312 SHA1 e1ad9963a36a602adb6dbfc3f7089a1de421da3e SHA256 fc172f67a4ba2ebacac0d57fa98e3e960be3e99262326721f3e55f3210d8c77b
 EBUILD libav-0.6.2.ebuild 7602 RMD160 69343b32c466f2ab343e7c6df95b8828a9bbc487 SHA1 c4bec403c0ddc2c7aabcf4a74b69a8a51cac5d12 SHA256 89ae504daa8e22b6d1685f0636738c57619bb382cb8932e6deed83e1d3fd23bd
 EBUILD libav-0.6.9999.ebuild 7551 RMD160 b939f2a68e9bd9a7da4811c56432fba92c8e415a SHA1 7e1262552041497a468b688b0671eb6dafb49ebb SHA256 66c39427dd364636ae0137db31dd256d5a18dc2d1455086c8c8115664051bea7
 EBUILD libav-0.7.2.ebuild 7997 RMD160 ffe4f995d2effccc27489b94589429684dab461f SHA1 a10ee4c1597be2f21715bda28718adf7bfa58118 SHA256 6f55a7e9e5e49767ff25740b29a5f61ced41f0eb518096e5dae9644bf02250db
 EBUILD libav-0.7.9999.ebuild 7947 RMD160 a67ea8d26ccffe866e4a3edc11076da4ad53d5e6 SHA1 d297581ec2cbb9e1a71199164f6107582d765686 SHA256 cb3fe767d8a836d758355daab4a20865d21cde3f8efd7480025d3b638ee5c9bd
 EBUILD libav-0.8_pre20110818.ebuild 8363 RMD160 819a6683c1a974e05423e90bc7b673c0efe69300 SHA1 d9d54bcf788aff84b612346d8061b729031cad1d SHA256 6592548fd9b633acfcae1686da5377743730c200b414fbb95574c6dd5ca5cd97
+EBUILD libav-0.8_pre20111116.ebuild 8974 RMD160 ee4f081fa46097ba7d150777cd05297c1581ed8d SHA1 a281de17e7e7490836c6bb013b8813de9b7bd665 SHA256 3aec354067e6852696b25208d7b3bad36a5deaab7b85f4d2efb91efda1636c25
 EBUILD libav-9999.ebuild 8964 RMD160 617cd940ca9293226336f8f2e601b405512b45e5 SHA1 a5cb73bfa75f2c82417d0cf05d320c184665969f SHA256 2c46eb086aba34dfc9741780895436da54f613a4bfa27e5c6e80b7dbbf58ac01
-MISC ChangeLog 5690 RMD160 c8f00d394a287efa916f6266acdb5d3e930cd488 SHA1 72698599b4f5553ddef8255da7d17ec7b58861cc SHA256 88538f435c55e96048d38edc446c19f4dabe364f141ad6aec7f7d87a9e8984f5
+MISC ChangeLog 5824 RMD160 cf504315fa914c2828f9cb33a386fcf52103e80b SHA1 a129961b4e9f2b356d06dd8f9fac7e855f4e4dc4 SHA256 69d6115c79936206345738d531e7041e731d2bc40f4761f67e26c6d672728a5f
 MISC metadata.xml 2980 RMD160 683fbf9c4aa2498dba7bd011423967eeff4448a7 SHA1 d15e5b733ee26eb4a31494546f0e602275b0d5d3 SHA256 9c246d686175ea1cb7fc11668298c374408f6f5ef16d0a858e3fa3f8989c7630
diff --git a/media-video/libav/libav-0.8_pre20111116.ebuild b/media-video/libav/libav-0.8_pre20111116.ebuild
new file mode 100644
index 000000000000..a5bcf7e3d2b1
--- /dev/null
+++ b/media-video/libav/libav-0.8_pre20111116.ebuild
@@ -0,0 +1,309 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/libav/libav-0.8_pre20111116.ebuild,v 1.1 2011/11/16 03:59:51 lu_zero Exp $
+
+EAPI=4
+
+if [[ ${PV} == *9999 ]] ; then
+	SCM="git-2"
+	EGIT_REPO_URI="git://git.libav.org/libav.git"
+	[[ ${PV%9999} != "" ]] && EGIT_BRANCH="release/${PV%.9999}"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video."
+HOMEPAGE="http://libav.org/"
+if [[ ${PV} == *9999 ]] ; then
+	SRC_URI=""
+elif [[ ${PV%_p*} != ${PV} ]] ; then # Gentoo snapshot
+	SRC_URI="http://dev.gentoo.org/~lu_zero/libav/${P}.tar.xz"
+else # Official release
+	SRC_URI="http://${PN}.org/releases/${P}.tar.xz"
+fi
+
+LICENSE="LGPL-2 gpl? ( GPL-3 )"
+SLOT="0"
+[[ ${PV} == *9999 ]] || KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64
+~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos
+~x64-solaris ~x86-solaris"
+IUSE="+3dnow +3dnowext aac alsa altivec amr bindist +bzip2 cdio cpudetection
+	  custom-cflags debug dirac doc +encode faac truetype frei0r +gpl gsm
+      +hardcoded-tables ieee1394 jack jpeg2k +mmx +mmxext mp3 network openssl
+	  oss pic pulseaudio qt-faststart rtmp schroedinger sdl speex ssl +ssse3
+	  static-libs test theora threads v4l vaapi vdpau vorbis vpx X x264 xvid
+	  +zlib"
+
+VIDEO_CARDS="nvidia"
+for x in ${VIDEO_CARDS}; do
+	IUSE="${IUSE} video_cards_${x}"
+done
+
+CPU_FEATURES="3dnow:amd3dnow 3dnowext:amd3dnowext altivec avx mmx mmxext:mmx2 ssse3 vis neon iwmmxt"
+
+for i in ${CPU_FEATURES}; do
+	IUSE="${IUSE} ${i%:*}"
+done
+
+RDEPEND="
+	!media-video/ffmpeg
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio )
+	dirac? ( media-video/dirac )
+	encode? (
+		aac? ( media-libs/vo-aacenc )
+		amr? ( media-libs/vo-amrwbenc )
+		faac? ( media-libs/faac )
+		mp3? ( >=media-sound/lame-3.98.3 )
+		theora? ( >=media-libs/libtheora-1.1.1[encode] media-libs/libogg )
+		vorbis? ( media-libs/libvorbis media-libs/libogg )
+		x264? ( >=media-libs/x264-0.0.20110426 )
+		xvid? ( >=media-libs/xvid-1.1.0 )
+	)
+	truetype? ( media-libs/freetype )
+	frei0r? ( media-plugins/frei0r-plugins )
+	gsm? ( >=media-sound/gsm-1.0.12-r1 )
+	ieee1394? ( media-libs/libdc1394 sys-libs/libraw1394 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
+	rtmp? ( >=media-video/rtmpdump-2.2f )
+	ssl? ( openssl? ( dev-libs/openssl )
+		   !openssl? ( net-libs/gnutls ) )
+	sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video] )
+	schroedinger? ( media-libs/schroedinger )
+	speex? ( >=media-libs/speex-1.2_beta3 )
+	vaapi? ( x11-libs/libva )
+	video_cards_nvidia? ( vdpau? ( x11-libs/libvdpau ) )
+	vpx? ( >=media-libs/libvpx-0.9.6 )
+	X? ( x11-libs/libX11 x11-libs/libXext )
+	zlib? ( sys-libs/zlib )
+"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	dirac? ( dev-util/pkgconfig )
+	doc? ( app-text/texi2html )
+	mmx? ( dev-lang/yasm )
+	rtmp? ( dev-util/pkgconfig )
+	schroedinger? ( dev-util/pkgconfig )
+	test? ( net-misc/wget )
+	v4l? ( sys-kernel/linux-headers )
+"
+
+# faac can't be binary distributed
+# openssl support marked as nonfree
+# faac and aac are concurent implementations
+# amr and aac require at least lgpl3
+REQUIRED_USE="bindist? ( !faac !openssl )
+	amr? ( gpl ) aac? ( gpl )"
+
+RESTRICT="test"
+
+src_prepare() {
+	# if we have snapshot then we need to hardcode the version
+	if [[ ${PV%_p*} != ${PV} ]]; then
+		sed -i -e "s/UNKNOWN/DATE-${PV#*_pre}/" "${S}/version.sh" || die
+	fi
+}
+
+src_configure() {
+	local myconf="${EXTRA_FFMPEG_CONF}"
+	local uses i
+
+	myconf="
+		$(use_enable gpl)
+		$(use_enable gpl version3)
+		--enable-postproc
+		--enable-avfilter
+	"
+
+	# enabled by default
+	uses="debug doc network zlib"
+	for i in ${uses}; do
+		use ${i} || myconf+=" --disable-${i}"
+	done
+	use bzip2 || myconf+=" --disable-bzlib"
+	use sdl || myconf+=" --disable-avplay"
+
+	if use ssl; then
+		use openssl && myconf+=" --enable-openssl --enable-nonfree" \
+					|| myconf+=" --enable-gnutls"
+	fi
+
+	use custom-cflags && myconf+=" --disable-optimizations"
+	use cpudetection && myconf+=" --enable-runtime-cpudetect"
+
+	#for i in h264_vdpau mpeg1_vdpau mpeg_vdpau vc1_vdpau wmv3_vdpau; do
+	#	use video_cards_nvidia || myconf="${myconf} --disable-decoder=${i}"
+	#	use vdpau || myconf="${myconf} --disable-decoder=${i}"
+	#done
+	use video_cards_nvidia && use vdpau || myconf+=" --disable-vdpau"
+
+	use vaapi && myconf+=" --enable-vaapi"
+
+	# Encoders
+	if use encode; then
+		use mp3 && myconf+=" --enable-libmp3lame"
+		use amr && myconf+=" --enable-libvo-amrwbenc"
+		use faac && myconf+=" --enable-libfaac --enable-nonfree"
+		use aac && myconf+=" --enable-libvo-aacenc"
+		uses="theora vorbis x264 xvid"
+		for i in ${uses}; do
+			use ${i} && myconf+=" --enable-lib${i}"
+		done
+	else
+		myconf+=" --disable-encoders"
+	fi
+
+	# libavdevice options
+	use cdio && myconf+=" --enable-libcdio"
+	use ieee1394 && myconf+=" --enable-libdc1394"
+	use pulseaudio && myconf+=" --enable-libpulse"
+	# Indevs
+	# v4l1 is gone since linux-headers-2.6.38
+	myconf+=" --disable-indev=v4l"
+	use v4l || myconf+=" --disable-indev=v4l2"
+	for i in alsa oss jack; do
+		use ${i} || myconf+=" --disable-indev=${i}"
+	done
+	use X && myconf+=" --enable-x11grab"
+	# Outdevs
+	for i in alsa oss ; do
+		use ${i} || myconf+=" --disable-outdev=${i}"
+	done
+	# libavfilter options
+	use frei0r && myconf+=" --enable-frei0r"
+	use truetype &&  myconf+=" --enable-libfreetype"
+
+	# Threads; we only support pthread for now but ffmpeg supports more
+	use threads && myconf+=" --enable-pthreads"
+
+	# Decoders
+	use amr && myconf+=" --enable-libopencore-amrwb --enable-libopencore-amrnb"
+	uses="gsm dirac rtmp schroedinger speex vpx"
+	for i in ${uses}; do
+		use ${i} && myconf+=" --enable-lib${i}"
+	done
+	use jpeg2k && myconf+=" --enable-libopenjpeg"
+
+	# CPU features
+	for i in ${CPU_FEATURES}; do
+		use ${i%:*} || myconf+=" --disable-${i#*:}"
+	done
+
+	# pass the right -mfpu as extra
+	use neon && myconf+=" --extra-cflags=-mfpu=neon"
+
+	# disable mmx accelerated code if PIC is required
+	# as the provided asm decidedly is not PIC for x86.
+	if use pic && use x86 ; then
+		myconf+=" --disable-mmx --disable-mmx2"
+	fi
+
+	# Option to force building pic
+	use pic && myconf+=" --enable-pic"
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host" # bug #273421
+		[[ ${i} = *-sse3 ]] && i="${i%-sse3}" # bug 283968
+		myconf+=" --cpu=${i}"
+		break
+	done
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf+=" --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		case ${CHOST} in
+			*freebsd*)
+				myconf+=" --target-os=freebsd"
+				;;
+			mingw32*)
+				myconf+=" --target-os=mingw32"
+				;;
+			*linux*)
+				myconf+=" --target-os=linux"
+				;;
+		esac
+	fi
+
+	# Misc stuff
+	use hardcoded-tables && myconf+=" --enable-hardcoded-tables"
+
+	# Specific workarounds for too-few-registers arch...
+	if [[ $(tc-arch) == "x86" ]]; then
+		filter-flags -fforce-addr -momit-leaf-frame-pointer
+		append-flags -fomit-frame-pointer
+		is-flag -O? || append-flags -O2
+		if use debug; then
+			# no need to warn about debug if not using debug flag
+			ewarn ""
+			ewarn "Debug information will be almost useless as the frame pointer is omitted."
+			ewarn "This makes debugging harder, so crashes that has no fixed behavior are"
+			ewarn "difficult to fix. Please have that in mind."
+			ewarn ""
+		fi
+	fi
+
+	cd "${S}"
+	./configure \
+		--prefix="$EPREFIX"/usr \
+		--libdir="$EPREFIX"/usr/$(get_libdir) \
+		--shlibdir="$EPREFIX"/usr/$(get_libdir) \
+		--mandir="$EPREFIX"/usr/share/man \
+		--enable-shared \
+		--cc="$(tc-getCC)" \
+		$(use_enable static-libs static) \
+		${myconf} || die
+}
+
+src_compile() {
+	emake
+
+	if use qt-faststart; then
+		tc-export CC
+		emake tools/qt-faststart
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-man
+
+	dodoc Changelog README INSTALL
+	dodoc doc/*
+
+	if use qt-faststart; then
+		dobin tools/qt-faststart
+	fi
+
+	for i in avplay avserver avprobe; do
+		dosym  ${i} /usr/bin/${i/av/ff}
+	done
+}
+
+pkg_postinst() {
+	elog "Please note that the programs formerly known as ffplay, ffserver"
+	elog "and ffprobe are now called avplay, avserver and avprobe."
+	elog
+	elog "ffmpeg had been replaced by the feature incompatible avconv thus"
+	elog "the legacy ffmpeg is provided for compatibility with older scripts"
+}
+
+src_test() {
+	local i tests
+	if use encode; then
+		tests="codectest lavftest seektest"
+		for i in ${tests}; do
+			LD_LIBRARY_PATH="${S}/libavcore:${S}/libpostproc:${S}/libswscale:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
+				emake ${i}
+		done
+	else
+		ewarn "Tests fail without USE=encode, skipping"
+	fi
+}