Version bump.

Package-Manager: portage-2.2_rc60/cvs/Linux x86_64

1 files changed, 52 insertions, 0 deletions

diff --git a/net-libs/libsoup-gnome/libsoup-gnome-2.28.2.ebuild b/net-libs/libsoup-gnome/libsoup-gnome-2.28.2.ebuild
new file mode 100644
index 000000000000..ed29e1e010f1
--- /dev/null
+++ b/net-libs/libsoup-gnome/libsoup-gnome-2.28.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup-gnome/libsoup-gnome-2.28.2.ebuild,v 1.1 2009/12/17 22:55:30 eva Exp $
+
+EAPI="2"
+
+inherit autotools eutils gnome2
+
+MY_PN=${PN/-gnome}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="GNOME plugin for libsoup"
+HOMEPAGE="http://www.gnome.org/"
+SRC_URI="${SRC_URI//-gnome}"
+
+LICENSE="LGPL-2"
+SLOT="2.4"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+# Do NOT build with --disable-debug/--enable-debug=no - gnome2.eclass takes care of that
+IUSE="debug doc"
+
+RDEPEND="~net-libs/libsoup-${PV}
+	gnome-base/gnome-keyring
+	net-libs/libproxy
+	>=gnome-base/gconf-2
+	dev-db/sqlite:3"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9
+	dev-util/gtk-doc-am
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS="AUTHORS NEWS README"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-static
+		--with-libsoup-system
+		--with-gnome"
+}
+src_prepare() {
+	gnome2_src_prepare
+
+	# Fix test to follow POSIX (for x86-fbsd)
+	# No patch to prevent having to eautoreconf
+	sed -e 's/\(test.*\)==/\1=/g' -i configure.in configure || die "sed failed"
+
+	# Use lib present on the system
+	epatch "${FILESDIR}"/${PN}-2.28.1-system-lib.patch
+	eautoreconf
+}