Version bump.

Package-Manager: portage-2.2.7/cvs/Linux x86_64
Manifest-Sign-Key: 0xFB7C4156

1 files changed, 50 insertions, 0 deletions

diff --git a/net-libs/libtirpc/libtirpc-0.2.4.ebuild b/net-libs/libtirpc/libtirpc-0.2.4.ebuild
new file mode 100644
index 000000000000..d58f9a86bf60
--- /dev/null
+++ b/net-libs/libtirpc/libtirpc-0.2.4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libtirpc/libtirpc-0.2.4.ebuild,v 1.1 2013/12/10 06:40:12 vapier Exp $
+
+EAPI="4"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Transport Independent RPC library (SunRPC replacement)"
+HOMEPAGE="http://libtirpc.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	mirror://gentoo/${PN}-glibc-nfs.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="ipv6 kerberos static-libs"
+
+RDEPEND="kerberos? ( net-libs/libgssglue )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+src_unpack() {
+	unpack ${A}
+	cp -r tirpc "${S}"/ || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable ipv6) \
+		$(use_enable kerberos gssapi) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	insinto /etc
+	doins doc/netconfig
+
+	insinto /usr/include/tirpc
+	doins -r "${WORKDIR}"/tirpc/*
+
+	# libtirpc replaces rpc support in glibc, so we need it in /
+	gen_usr_ldscript -a tirpc
+
+	# makes sure that the linking order for nfs-utils is proper, as
+	# libtool would inject a libgssglue dependency in the list.
+	use static-libs || find "${ED}" -name '*.la' -delete
+}