Version bump for the 0.9.4 series.

Package-Manager: portage-2.2.0_alpha95/cvs/Linux x86_64

2 files changed, 70 insertions, 2 deletions

diff --git a/net-misc/networkmanager-openvpn/ChangeLog b/net-misc/networkmanager-openvpn/ChangeLog
index 4b439456fbce..49030f118121 100644
--- a/net-misc/networkmanager-openvpn/ChangeLog
+++ b/net-misc/networkmanager-openvpn/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/networkmanager-openvpn
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/ChangeLog,v 1.27 2011/12/18 20:15:51 phajdan.jr Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/ChangeLog,v 1.28 2012/03/27 09:17:12 tetromino Exp $
+
+*networkmanager-openvpn-0.9.4.0 (27 Mar 2012)
+
+  27 Mar 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +networkmanager-openvpn-0.9.4.0.ebuild:
+  Version bump for the 0.9.4 series.
 
   18 Dec 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org>
   networkmanager-openvpn-0.8.2-r1.ebuild:
diff --git a/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.4.0.ebuild b/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.4.0.ebuild
new file mode 100644
index 000000000000..bf26a441bb0f
--- /dev/null
+++ b/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.4.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.4.0.ebuild,v 1.1 2012/03/27 09:17:12 tetromino Exp $
+
+EAPI="4"
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome.org
+
+DESCRIPTION="NetworkManager OpenVPN plugin"
+HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome test"
+
+RDEPEND="
+	>=dev-libs/dbus-glib-0.74
+	>=net-misc/networkmanager-${PV}
+	>=net-misc/openvpn-2.1_rc9
+	gnome? (
+		>=x11-libs/gtk+-2.91.4:3
+		gnome-base/gnome-keyring
+	)"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/intltool-0.35
+	dev-util/pkgconfig"
+
+src_prepare() {
+	# Test will fail if the machine doesn't have a particular locale installed
+	# FAIL: (tls-import-data) unexpected 'ca' secret value
+	sed '/test_non_utf8_import (plugin, test_dir)/ d' \
+		-i properties/tests/test-import-export.c || die "sed failed"
+
+	# Drop DEPRECATED flags, bug #385597
+	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
+		auth-dialog/Makefile.am auth-dialog/Makefile.in \
+		common/Makefile.am common/Makefile.in \
+		properties/Makefile.am properties/Makefile.in \
+		src/Makefile.am src/Makefile.in \
+		configure.ac configure || die
+}
+
+src_configure() {
+	ECONF="--disable-more-warnings
+		--disable-static
+		--with-dist-version=Gentoo
+		--with-gtkver=3
+		$(use_with gnome)
+		$(use_with test tests)"
+
+	econf ${ECONF}
+}
+
+src_install() {
+	default
+	# Remove useless .la files
+	find "${D}" -name '*.la' -exec rm -f {} +
+}