Live ebuild thanks to Dan Weeks <dan@danweeks.net>. Bug #372443

Package-Manager: portage-2.1.9.49/cvs/Linux x86_64

2 files changed, 78 insertions, 1 deletions

diff --git a/net-misc/remmina/ChangeLog b/net-misc/remmina/ChangeLog
index 5b31ed6739a3..197a16ab30db 100644
--- a/net-misc/remmina/ChangeLog
+++ b/net-misc/remmina/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/remmina
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/remmina/ChangeLog,v 1.4 2011/03/21 22:15:12 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/remmina/ChangeLog,v 1.5 2011/06/24 14:41:36 hwoarang Exp $
+
+*remmina-9999 (24 Jun 2011)
+
+  24 Jun 2011; Markos Chandras <hwoarang@gentoo.org> +remmina-9999.ebuild:
+  Live ebuild thanks to Dan Weeks <dan@danweeks.net>. Bug #372443
 
   21 Mar 2011; Nirbheek Chauhan <nirbheek@gentoo.org> remmina-0.7.5.ebuild,
   remmina-0.9.3.ebuild:
diff --git a/net-misc/remmina/remmina-9999.ebuild b/net-misc/remmina/remmina-9999.ebuild
new file mode 100644
index 000000000000..e5949739c5a9
--- /dev/null
+++ b/net-misc/remmina/remmina-9999.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/remmina/remmina-9999.ebuild,v 1.1 2011/06/24 14:41:36 hwoarang Exp $
+
+EAPI=2
+EGIT_REPO_URI="git://remmina.git.sourceforge.net/gitroot/remmina/remmina"
+EGIT_PROJECT="remmina"
+EGIT_SOURCEDIR="${WORKDIR}"
+
+inherit autotools git-2 eutils gnome2-utils
+
+DESCRIPTION="A GTK+ RDP, VNC, XDMCP and SSH client"
+HOMEPAGE="http://remmina.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="avahi crypt debug nls ssh unique vte"
+
+RDEPEND="x11-libs/gtk+:2
+	avahi? ( net-dns/avahi )
+	crypt? ( dev-libs/libgcrypt )
+	nls? ( virtual/libintl )
+	ssh? ( net-libs/libssh[sftp] )
+	unique? ( dev-libs/libunique:1 )
+	vte? ( x11-libs/vte:0 )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	intltoolize --force --copy --automake
+	eautoreconf
+}
+
+src_configure() {
+	if use ssh && ! use vte; then
+		ewarn "Enabling ssh without vte only provides sftp support."
+	fi
+
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable avahi) \
+		$(use_enable crypt gcrypt) \
+		$(use_enable debug) \
+		$(use_enable nls) \
+		$(use_enable ssh) \
+		$(use_enable unique) \
+		$(use_enable vte)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog README || die "dodoc failed"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	elog "You need to install net-misc/remmina-plugins which"
+	elog "provide all the necessary network protocols required by ${PN}"
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}