Add optional support for www-plugins/gecko-mediaplayer, as suggested by sandrain in Gentoo Forums.

Package-Manager: portage-2.1.8.3/cvs/Linux i686

6 files changed, 281 insertions, 7 deletions

diff --git a/www-client/chromium/ChangeLog b/www-client/chromium/ChangeLog
index 58f2a41e9dbf..9668e74cd222 100644
--- a/www-client/chromium/ChangeLog
+++ b/www-client/chromium/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.198 2010/10/08 12:11:06 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.199 2010/10/09 14:00:16 phajdan.jr Exp $
+
+*chromium-7.0.544.0-r1 (09 Oct 2010)
+
+  09 Oct 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+  +files/chromium-gecko-mediaplayer-r0.patch, +chromium-7.0.544.0-r1.ebuild,
+  chromium-9999.ebuild, metadata.xml:
+  Add optional support for www-plugins/gecko-mediaplayer, as suggested by
+  sandrain in Gentoo Forums.
 
 *chromium-7.0.517.36 (08 Oct 2010)
 
diff --git a/www-client/chromium/Manifest b/www-client/chromium/Manifest
index c86b9236abf5..9f00fcd5641b 100644
--- a/www-client/chromium/Manifest
+++ b/www-client/chromium/Manifest
@@ -1,3 +1,4 @@
+AUX chromium-gecko-mediaplayer-r0.patch 590 RMD160 8b01e801ef4a8d3aaa842ab217929e71ebb70a87 SHA1 916ecd1c7a405fc12de579538c07c42cd9e84ecc SHA256 491cfaa353ad965a0cbfe2fc6370e4df5d1cd55398698b838996053f9e46f12c
 AUX chromium-gnome-keyring-r0.patch 2842 RMD160 1ac9a6e2785954a7a4f7f60988c8d7c101ad6db8 SHA1 44ee90f3c6632bcad9843cce22865c9c39fd6c8a SHA256 237d85599270b7cc1f83e58e27712f3d65609c325318b0b28ac277d630574c96
 AUX chromium-launcher.sh 1143 RMD160 3bc84b886104acdf993e27e1e05218b730bbead1 SHA1 505850d82b0aed48612c32ff36172c924d2debd0 SHA256 bdec73f460377a20c870cc2e8586cdc48183d2f2f6011b7a2573cb294dd08e28
 AUX chromium-make-3.82-compatibility-r0.patch 867 RMD160 d6fd01bcd32460678e1503ca9fbeb78ed16e8213 SHA1 9964cbe8063140312dd1217327f3648dfaf71284 SHA256 339f8022d0a2ff733d779ba8c4a3cf09a28633afccc0106d86289ef497f2f401
@@ -17,7 +18,8 @@ EBUILD chromium-6.0.472.63.ebuild 6875 RMD160 868088280a7e82a3016c6feee15c61ea8e
 EBUILD chromium-7.0.517.24.ebuild 6611 RMD160 6a276a416a19c3a78a33112c25c87aed7bdd4a0b SHA1 508ad38752f50ce75efafea8e18fef052a8ba978 SHA256 7f941e6775455807469bf28cb1a3069a270e098c2f1ed248c084f47521d6a2c2
 EBUILD chromium-7.0.517.36.ebuild 6611 RMD160 11af550adfeb2e2dab6fb5ee2247bf52458ed43c SHA1 72a8bb8d6dd74de4290c3d08d4f0908969694f04 SHA256 dd32a37a19a669afcb5a669405aa004e92a20d5db8b09cd0aac0efac090adbe5
 EBUILD chromium-7.0.536.2-r1.ebuild 6666 RMD160 07963523f25ad06aaddbe2088d717ddf2f52c699 SHA1 2909b16cc555ef5f17ff0d368f9fac2aa56dcdd9 SHA256 176f8ee3145f6664668954f20d7b84bb3047a17a21718c0077504e53ec73fc87
+EBUILD chromium-7.0.544.0-r1.ebuild 7187 RMD160 31e2975f7276e8587d100f0ad9b780f646816f6a SHA1 e9468d2b3cd7c232867f2d82d2788b4007bb1859 SHA256 f723752ea03dd91b90f7ce1fd140dfd7770900a3a5f66c0fef1c33e568c02a33
 EBUILD chromium-7.0.544.0.ebuild 6645 RMD160 fc43f37fe3191ed57082a398341faf5f7db075b8 SHA1 5c72edc8be4ba5f9534a1a0f18fba3e162f23703 SHA256 580bdbf4409cf3f51f61c435692abd5740da011a17d3d418d776077a868125da
-EBUILD chromium-9999.ebuild 8226 RMD160 b7609019b298dcd713974ad98347ad344249f34d SHA1 2c1485522882f67309a1b6d88b0b99f7f769e83d SHA256 3d1dd0e8eb2a40015b0c12a3028b42f0bbfffc8e4c94e0446bca4f99e5066329
-MISC ChangeLog 43617 RMD160 86642c42ee5685aeee9f41ec9cb448df1519e17f SHA1 f1648cb1c97080201e27b4ea30c5b64f8a209973 SHA256 54ac2d7783262fd8bc7217925648fad534a8f6c07e7958a3238912b9f595700a
-MISC metadata.xml 406 RMD160 d09b00979942b334a50d93a97fc0c871d9c12533 SHA1 6109fea03404526e0b794b2d3ab7a86cd2db0798 SHA256 1b13e11f0612543177e8def6184c785553183b77b6724d249a7557c64b6ead2a
+EBUILD chromium-9999.ebuild 8765 RMD160 0722aca7fa38311d589aba0fa0b8348a8a9d49a8 SHA1 851bdb1bf7594c138dfd0dcc2f04c1b1d89c9343 SHA256 8e41c9564f5dd5e5758e3cd2e9a619d38f350f5435dfdd0a99dcc07ca16d18ac
+MISC ChangeLog 43929 RMD160 29e314d6358e2f9ed7301a5e9d4edc23a074e7c4 SHA1 3f2f76ba719b4e57c3e7d3f5a1edd105daeae956 SHA256 191db859e5af55f2f71fda78531a39d712345b2759399cb6a39e358504ca3e35
+MISC metadata.xml 516 RMD160 55abec043e516fad54cc6c9f5aff0d1ac6aba738 SHA1 9cb50bcd2f1e7f0dc6e257fcab3b24f0f0f90f0c SHA256 b2f497aa9d3ab3deb4cbd25eedc3037df449349a3506f1af7e3de9730c522b8b
diff --git a/www-client/chromium/chromium-7.0.544.0-r1.ebuild b/www-client/chromium/chromium-7.0.544.0-r1.ebuild
new file mode 100644
index 000000000000..fc983226cc50
--- /dev/null
+++ b/www-client/chromium/chromium-7.0.544.0-r1.ebuild
@@ -0,0 +1,238 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.544.0-r1.ebuild,v 1.1 2010/10/09 14:00:27 phajdan.jr Exp $
+
+EAPI="2"
+
+inherit eutils flag-o-matic multilib pax-utils toolchain-funcs
+
+DESCRIPTION="Open-source version of Google Chrome web browser"
+HOMEPAGE="http://chromium.org/"
+SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="cups +gecko-mediaplayer gnome gnome-keyring system-sqlite"
+
+RDEPEND="app-arch/bzip2
+	system-sqlite? (
+		>=dev-db/sqlite-3.6.23.1[fts3,icu,secure-delete,threadsafe]
+	)
+	>=dev-libs/icu-4.4.1
+	>=dev-libs/libevent-1.4.13
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-libs/nss-3.12.3
+	>=gnome-base/gconf-2.24.0
+	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
+	>=media-libs/alsa-lib-1.0.19
+	media-libs/jpeg:0
+	media-libs/libpng
+	cups? ( >=net-print/cups-1.4.4 )
+	sys-libs/zlib
+	>=x11-libs/gtk+-2.14.7
+	x11-libs/libXScrnSaver"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	>=dev-util/gperf-3.0.3
+	>=dev-util/pkgconfig-0.23
+	sys-devel/flex"
+RDEPEND+="
+	|| (
+		x11-themes/gnome-icon-theme
+		x11-themes/oxygen-molecule
+		x11-themes/tango-icon-theme
+		x11-themes/xfce4-icon-theme
+	)
+	x11-apps/xmessage
+	x11-misc/xdg-utils
+	virtual/ttf-fonts
+	gecko-mediaplayer? ( !www-plugins/gecko-mediaplayer[gnome] )"
+
+remove_bundled_lib() {
+	einfo "Removing bundled library $1 ..."
+	local out
+	out="$(find $1 -mindepth 1 \! -iname '*.gyp' -print -delete)" \
+		|| die "failed to remove bundled library $1"
+	if [[ -z $out ]]; then
+		die "no files matched when removing bundled library $1"
+	fi
+}
+
+pkg_setup() {
+	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
+}
+
+src_prepare() {
+	# Small fixes to the system-provided sqlite support,
+	# to be upstreamed.
+	epatch "${FILESDIR}"/${PN}-system-sqlite-r0.patch
+
+	# Small fix to the system-provided icu support,
+	# to be upstreamed.
+	epatch "${FILESDIR}"/${PN}-system-icu-r0.patch
+
+	# Enable optional support for gecko-mediaplayer.
+	epatch "${FILESDIR}"/${PN}-gecko-mediaplayer-r0.patch
+
+	remove_bundled_lib "third_party/bzip2"
+	remove_bundled_lib "third_party/codesighs"
+	remove_bundled_lib "third_party/cros"
+	remove_bundled_lib "third_party/icu"
+	remove_bundled_lib "third_party/jemalloc"
+	remove_bundled_lib "third_party/lcov"
+	remove_bundled_lib "third_party/libevent"
+	remove_bundled_lib "third_party/libjpeg"
+	remove_bundled_lib "third_party/libpng"
+	remove_bundled_lib "third_party/libxml"
+	remove_bundled_lib "third_party/libxslt"
+	remove_bundled_lib "third_party/lzma_sdk"
+	remove_bundled_lib "third_party/molokocacao"
+	remove_bundled_lib "third_party/ocmock"
+	remove_bundled_lib "third_party/pyftpdlib"
+	remove_bundled_lib "third_party/simplejson"
+	remove_bundled_lib "third_party/tlslite"
+	# TODO: also remove third_party/zlib. For now the compilation fails if we
+	# remove it (minizip-related).
+
+	if use system-sqlite; then
+		remove_bundled_lib "third_party/sqlite/src"
+		remove_bundled_lib "third_party/sqlite/preprocessed"
+	fi
+}
+
+src_configure() {
+	local myconf=""
+
+	# Never tell the build system to "enable" SSE2, it has a few unexpected
+	# additions, bug #336871.
+	myconf+=" -Ddisable_sse2=1"
+
+	# Use system-provided libraries.
+	# TODO: use_system_ffmpeg (http://crbug.com/50678).
+	# TODO: use_system_hunspell (upstream changes needed).
+	# TODO: use_system_ssl (need to consult upstream).
+	myconf+="
+		-Duse_system_bzip2=1
+		-Duse_system_icu=1
+		-Duse_system_libevent=1
+		-Duse_system_libjpeg=1
+		-Duse_system_libpng=1
+		-Duse_system_libxml=1
+		-Duse_system_zlib=1"
+
+	if use system-sqlite; then
+		myconf+=" -Duse_system_sqlite=1"
+	fi
+
+	# The dependency on cups is optional, see bug #324105.
+	if use cups; then
+		myconf+=" -Duse_cups=1"
+	else
+		myconf+=" -Duse_cups=0"
+	fi
+
+	if use "gnome-keyring"; then
+		myconf+=" -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
+	else
+		# TODO: we should also disable code trying to dlopen
+		# gnome-keyring in that case.
+		myconf+=" -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
+	fi
+
+	# Enable sandbox.
+	myconf+="
+		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
+		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
+
+	if host-is-pax; then
+		# Prevent the build from failing (bug #301880). The performance
+		# difference is very small.
+		myconf+=" -Dv8_use_snapshot=0"
+	fi
+
+	if use gecko-mediaplayer; then
+		# Disable hardcoded blacklist for gecko-mediaplayer.
+		# When www-plugins/gecko-mediaplayer is compiled with USE=gnome, it causes
+		# the browser to hang. We can handle the situation via dependencies,
+		# thus making it possible to use gecko-mediaplayer.
+		append-flags -DGENTOO_CHROMIUM_ENABLE_GECKO_MEDIAPLAYER
+	fi
+
+	# Use target arch detection logic from bug #296917.
+	local myarch="$ABI"
+	[[ $myarch = "" ]] && myarch="$ARCH"
+
+	if [[ $myarch = amd64 ]] ; then
+		myconf+=" -Dtarget_arch=x64"
+	elif [[ $myarch = x86 ]] ; then
+		myconf+=" -Dtarget_arch=ia32"
+	elif [[ $myarch = arm ]] ; then
+		# TODO: check this again after
+		# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
+		append-flags -fno-tree-sink
+
+		myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
+	else
+		die "Failed to determine target arch, got '$myarch'."
+	fi
+
+	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
+		myconf+=" -Dno_strict_aliasing=1 -Dgcc_version=44"
+	fi
+
+	# Work around a likely GCC bug, see bug #331945.
+	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "45" ]]; then
+		append-flags -fno-ipa-cp
+	fi
+
+	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
+	# Depending on GCC version the warnings are different and we don't want
+	# the build to fail because of that.
+	myconf+=" -Dwerror="
+
+	build/gyp_chromium --depth=. ${myconf} || die
+}
+
+src_compile() {
+	emake chrome chrome_sandbox BUILDTYPE=Release V=1 || die
+}
+
+src_install() {
+	exeinto "${CHROMIUM_HOME}"
+	pax-mark m out/Release/chrome
+	doexe out/Release/chrome
+	doexe out/Release/chrome_sandbox || die
+	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
+	doexe out/Release/xdg-settings || die
+	doexe "${FILESDIR}"/chromium-launcher.sh || die
+
+	insinto "${CHROMIUM_HOME}"
+	doins out/Release/chrome.pak || die
+	doins out/Release/resources.pak || die
+
+	doins -r out/Release/locales || die
+	doins -r out/Release/resources || die
+
+	# chrome.1 is for chromium --help
+	newman out/Release/chrome.1 chrome.1 || die
+	newman out/Release/chrome.1 chromium.1 || die
+
+	doexe out/Release/ffmpegsumo_nolink || die
+	doexe out/Release/libffmpegsumo.so || die
+
+	# Install icon and desktop entry.
+	newicon out/Release/product_logo_48.png ${PN}-browser.png || die
+	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
+	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
+		"MimeType=text/html;text/xml;application/xhtml+xml;"
+	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die
+
+	# Install GNOME default application entry (bug #303100).
+	if use gnome; then
+		dodir /usr/share/gnome-control-center/default-apps || die
+		insinto /usr/share/gnome-control-center/default-apps
+		doins "${FILESDIR}"/chromium.xml || die
+	fi
+}
diff --git a/www-client/chromium/chromium-9999.ebuild b/www-client/chromium/chromium-9999.ebuild
index 589bc88a2b36..402cbabb805e 100644
--- a/www-client/chromium/chromium-9999.ebuild
+++ b/www-client/chromium/chromium-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.92 2010/10/07 15:20:09 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.93 2010/10/09 14:00:31 phajdan.jr Exp $
 
 EAPI="2"
 
@@ -15,7 +15,7 @@ EGCLIENT_REPO_URI="http://src.chromium.org/svn/trunk/src/"
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS=""
-IUSE="cups gnome gnome-keyring system-sqlite"
+IUSE="cups +gecko-mediaplayer gnome gnome-keyring system-sqlite"
 
 RDEPEND="app-arch/bzip2
 	system-sqlite? (
@@ -49,7 +49,8 @@ RDEPEND+="
 	)
 	x11-apps/xmessage
 	x11-misc/xdg-utils
-	virtual/ttf-fonts"
+	virtual/ttf-fonts
+	gecko-mediaplayer? ( !www-plugins/gecko-mediaplayer[gnome] )"
 
 src_unpack() {
 	subversion_src_unpack
@@ -113,6 +114,9 @@ src_prepare() {
 	# to be upstreamed.
 	epatch "${FILESDIR}"/${PN}-system-icu-r0.patch
 
+	# Enable optional support for gecko-mediaplayer.
+	epatch "${FILESDIR}"/${PN}-gecko-mediaplayer-r0.patch
+
 	remove_bundled_lib "third_party/bzip2"
 	remove_bundled_lib "third_party/codesighs"
 	remove_bundled_lib "third_party/cros"
@@ -189,6 +193,14 @@ src_configure() {
 		myconf+=" -Dv8_use_snapshot=0"
 	fi
 
+	if use gecko-mediaplayer; then
+		# Disable hardcoded blacklist for gecko-mediaplayer.
+		# When www-plugins/gecko-mediaplayer is compiled with USE=gnome, it causes
+		# the browser to hang. We can handle the situation via dependencies,
+		# thus making it possible to use gecko-mediaplayer.
+		append-flags -DGENTOO_CHROMIUM_ENABLE_GECKO_MEDIAPLAYER
+	fi
+
 	# Use target arch detection logic from bug #296917.
 	local myarch="$ABI"
 	[[ $myarch = "" ]] && myarch="$ARCH"
diff --git a/www-client/chromium/files/chromium-gecko-mediaplayer-r0.patch b/www-client/chromium/files/chromium-gecko-mediaplayer-r0.patch
new file mode 100644
index 000000000000..fb5376b82137
--- /dev/null
+++ b/www-client/chromium/files/chromium-gecko-mediaplayer-r0.patch
@@ -0,0 +1,12 @@
+--- webkit/glue/plugins/plugin_list.cc_posix.orig	2010-10-09 11:05:44.000000000 +0200
++++ webkit/glue/plugins/plugin_list_posix.cc	2010-10-09 11:06:35.000000000 +0200
+@@ -89,7 +89,9 @@
+ bool IsBlacklistedPlugin(const FilePath& path) {
+   const char* kBlackListedPlugins[] = {
+     "nppdf.so",           // Adobe PDF
++#ifndef GENTOO_CHROMIUM_ENABLE_GECKO_MEDIAPLAYER
+     "gecko-mediaplayer",  // Gecko Media Player
++#endif  // GENTOO_CHROMIUM_ENABLE_GECKO_MEDIAPLAYER
+   };
+   std::string filename = path.BaseName().value();
+   for (size_t i = 0; i < arraysize(kBlackListedPlugins); i++) {
diff --git a/www-client/chromium/metadata.xml b/www-client/chromium/metadata.xml
index 593fb01b9ed4..b9e26d125530 100644
--- a/www-client/chromium/metadata.xml
+++ b/www-client/chromium/metadata.xml
@@ -4,6 +4,8 @@
 	<herd>chromium</herd>
 	<longdescription>Chromium is the open-source web browser project behind Google Chrome</longdescription>
 	<use>
+		<flag name="gecko-mediaplayer">Allow the browser to load
+			<pkg>www-plugins/gecko-mediaplayer</pkg></flag>
 		<flag name="system-sqlite">Use the system-wide <pkg>dev-db/sqlite</pkg>
 			installation with secure-delete enabled</flag>
 	</use>