Version bump for Gnome 3.6.

Package-Manager: portage-2.2.0_alpha149/cvs/Linux x86_64
Manifest-Sign-Key: 0xC6085806

1 files changed, 64 insertions, 0 deletions

diff --git a/www-client/epiphany-extensions/epiphany-extensions-3.6.0.ebuild b/www-client/epiphany-extensions/epiphany-extensions-3.6.0.ebuild
new file mode 100644
index 000000000000..5c5ad12d683a
--- /dev/null
+++ b/www-client/epiphany-extensions/epiphany-extensions-3.6.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany-extensions/epiphany-extensions-3.6.0.ebuild,v 1.1 2012/12/25 23:57:49 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="Extensions for the Epiphany web browser"
+HOMEPAGE="http://www.gnome.org/projects/epiphany/extensions.html"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="dbus examples pcre"
+
+RDEPEND="
+	>=www-client/epiphany-3.6
+	app-text/opensp
+	>=dev-libs/glib-2.26.0:2
+	>=dev-libs/libxml2-2.6:2
+	>=x11-libs/gtk+-2.90.4:3
+	net-libs/webkit-gtk:3
+
+	dbus? (
+		>=dev-libs/dbus-glib-0.34
+		sys-apps/dbus )
+	pcre? ( >=dev-libs/libpcre-3.9-r2 )
+"
+DEPEND="${RDEPEND}
+	>=app-text/gnome-doc-utils-0.3.2
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	gnome-base/gnome-common
+"
+# eautoreconf dependencies:
+#	  gnome-base/gnome-common
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=664369; needs eautoreconf
+	epatch "${FILESDIR}/${PN}-3.2.0-dbus-libs.patch"
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local extensions=""
+	# XXX: Only enable default/useful extensions?
+	extensions="actions adblock auto-reload certificates \
+			   error-viewer extensions-manager-ui gestures html5tube \
+			   java-console livehttpheaders page-info \
+			   push-scroller select-stylesheet \
+			   smart-bookmarks soup-fly tab-states"
+	use dbus && extensions="${extensions} rss"
+	use pcre && extensions="${extensions} greasemonkey"
+	use examples && extensions="${extensions} sample"
+
+	G2CONF="${G2CONF}
+		--with-extensions=$(echo "${extensions}" | sed -e 's/[[:space:]]\+/,/g')"
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_configure
+}