http://my.opera.com/desktopteam/blog/2011/06/23/swordfish-rc1

Package-Manager: portage-2.2.0_alpha41/cvs/Linux x86_64

3 files changed, 245 insertions, 5 deletions

diff --git a/www-client/opera-next/ChangeLog b/www-client/opera-next/ChangeLog
index 122536a3e7a7..d1d7f69eb56d 100644
--- a/www-client/opera-next/ChangeLog
+++ b/www-client/opera-next/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/opera-next
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.22 2011/06/23 04:30:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/ChangeLog,v 1.23 2011/06/23 18:39:24 jer Exp $
+
+*opera-next-11.50.1067 (23 Jun 2011)
+
+  23 Jun 2011; Jeroen Roovers <jer@gentoo.org> +opera-next-11.50.1067.ebuild:
+  http://my.opera.com/desktopteam/blog/2011/06/23/swordfish-rc1
 
 *opera-next-11.50.1065 (23 Jun 2011)
 
diff --git a/www-client/opera-next/Manifest b/www-client/opera-next/Manifest
index e5cb827ba52f..c5e33fd7b3a5 100644
--- a/www-client/opera-next/Manifest
+++ b/www-client/opera-next/Manifest
@@ -49,6 +49,9 @@ DIST opera-next-11.50-1054.x86_64.linux.tar.xz 11651236 RMD160 a406c96ad3e593a13
 DIST opera-next-11.50-1065.i386.freebsd.tar.xz 10978624 RMD160 fb7ab2e71db3f4ba31484bf31b0ff77e66de5efa SHA1 4f07fb3e9ee231f46262160255478d1d2162fc8f SHA256 cbf6814c604a648510b178e9dc4619c673fdcbe7327cf8d8f02409a611d270a9
 DIST opera-next-11.50-1065.i386.linux.tar.xz 10917056 RMD160 2496976f75a233363473876428c132b0338da3c8 SHA1 3403b0a83c106e960b662be54792bd7c069dd556 SHA256 c006e032dba7d432eeffe1f89b53c0931f460bf338e9e157316f7c612a5716f5
 DIST opera-next-11.50-1065.x86_64.linux.tar.xz 11658736 RMD160 9f3abbba4eb72716fb22c518b9126f620fc5adb5 SHA1 37a102c7edddc07eee73f7a397bb06394cf27de9 SHA256 d06ffff5f9cebdff5d1eb53facbc4ae2e946cce08acb969bd2cdb1578af56f20
+DIST opera-next-11.50-1067.i386.freebsd.tar.xz 11203548 RMD160 4fb0fa649cec6eef678418395620617f2f76fe05 SHA1 69335cbe2ba65402b39fe1afd355e24e0b40dc9e SHA256 48728c8322f5fa3eb00a44fe5332ba99959afac60eb73b09700ee5bcb1ff299c
+DIST opera-next-11.50-1067.i386.linux.tar.xz 11143228 RMD160 f27832f88ba9018b9fedfec47b647ba79bd4fae1 SHA1 88c05afd92e495c4422c644db423465266cb53d9 SHA256 0f1d948c778bfd36ff264cfbea9ba37fb7e935f9d11937c67e1baa2b0e02b482
+DIST opera-next-11.50-1067.x86_64.linux.tar.xz 11890564 RMD160 11f8b280ba92939e75ef98796eeed46a214f2097 SHA1 b9d22105132677319c784f4eb1dd8a9d0739d360 SHA256 82f8d551b24b62096d58f10153fc610cd2fc325d1f6f9d896ba528076bb71c68
 EBUILD opera-next-11.50.1009.ebuild 5938 RMD160 88b7c94fb996540e5a211fcf2ce278ac2dff6cc8 SHA1 e8b73ada5b8ce747ef697229b6cca2b3d67052d8 SHA256 68106e4e0a47620e1ca868822efcc9ae717cc6663fb30a9e830662fa1ebee498
 EBUILD opera-next-11.50.1015.ebuild 5946 RMD160 8da970b0a9d46985bb7ec456b3f327d2bef98f77 SHA1 1c7c770600862cd83f8b80837b857314c4f5390c SHA256 97cddad9846cf6e75202a619c0072df215f46d4d5b403c7af0ad8ff4c66d5964
 EBUILD opera-next-11.50.1016.ebuild 5947 RMD160 fa066a659b2b0d2fdbb9afb8dda8742f3717ce44 SHA1 6fee78bed4ca2a75d12fa9c3386fa8fadc083d7e SHA256 22708e79fa8c6b392b7919253a6f2a31a8a468c6a9277dd81672c668bede3035
@@ -65,12 +68,13 @@ EBUILD opera-next-11.50.1049.ebuild 6193 RMD160 e21f1813e3fb8491d7094ca0bc5998be
 EBUILD opera-next-11.50.1052.ebuild 6193 RMD160 0e2146af453cf3d9c8c8424a34a1b6dab94d0069 SHA1 28815360ccc241a1d5204aa4fab895b2e8d5f1c8 SHA256 0cee78ce2ad9cdcc6932a52509fd7421128696b55e066110ae8473e89751c33e
 EBUILD opera-next-11.50.1054.ebuild 6197 RMD160 3725b3b17ed5311e6fbc3baf2a393d16027edd62 SHA1 b2d643cc0530620ce0c3f2d324cc613615d14feb SHA256 c880dc63ad76994b71bd72d92faebb2ab0a4a42f2912c9be8780a11ddf8233ac
 EBUILD opera-next-11.50.1065.ebuild 6192 RMD160 23777ba5d4fda29438bebf88491b53271afb203c SHA1 8506496067953ab46899341615e8a42e07aa72a8 SHA256 479a8d9ee671ad83e8c882d2ed067cc4558828159a5b21618c78923a41b1acd9
-MISC ChangeLog 4069 RMD160 1b4a38feb9f7dd112e7a94b0a881f9f08bdeaab9 SHA1 6c67753906ef664895573b37a78f131ad522e8f2 SHA256 6a24878098a26fb0f4b6cdd7608c7b65c1a1639463c7f37a0902aea4c7882b83
+EBUILD opera-next-11.50.1067.ebuild 6199 RMD160 5c521be3da70631d81b8fd48b5611c6689b0fbae SHA1 14f10dd57b1836eca1cc7c4ee32da9991975d0d9 SHA256 c2725bb20e95e2254955476f9fbd935efb99ac59721079b6a6a82ab4a62c4feb
+MISC ChangeLog 4250 RMD160 99b3ffa3af5e54c6ada8233eb476fa70bf1765a5 SHA1 bd569c68912a70800446b56b7e8425a323710cc3 SHA256 9c31b0c1eb87e075e0f0a81c855462c1d7836f949974f07b0510aeb74d372ae6
 MISC metadata.xml 1547 RMD160 465d146bcfdb6553f7f0ab2dddd68c4dcb2e7731 SHA1 1afb7e0ccc0833ba0eb73be38b282b66ad629ff6 SHA256 5cfc6e7cbf3c454d563eb407b4569f0f5a9b3ce7770026d6055f27211d481915
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iEYEARECAAYFAk4CwYEACgkQVWmRsqeSphOdIQCeJMMozhGbdhG9jHDIpLMLUlxv
-IuQAn19jRAimKVfF/4aBwHEWvGv9qYWz
-=QR8Z
+iEYEARECAAYFAk4DiGYACgkQVWmRsqeSphPGMwCbBYBCYsk/s6Gnuq1m4JU8igzc
+11UAnR9tmLqXvZJCCAqi7XIlk8YiP5Go
+=7Bkl
 -----END PGP SIGNATURE-----
diff --git a/www-client/opera-next/opera-next-11.50.1067.ebuild b/www-client/opera-next/opera-next-11.50.1067.ebuild
new file mode 100644
index 000000000000..b9dbc3029c3f
--- /dev/null
+++ b/www-client/opera-next/opera-next-11.50.1067.ebuild
@@ -0,0 +1,231 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera-next/opera-next-11.50.1067.ebuild,v 1.1 2011/06/23 18:39:24 jer Exp $
+
+EAPI="3"
+
+inherit eutils fdo-mime gnome2-utils multilib pax-utils versionator
+
+DESCRIPTION="A fast and secure web browser and Internet suite"
+HOMEPAGE="http://www.opera.com/"
+
+SLOT="0"
+LICENSE="OPERA-11 LGPL-2 LGPL-3"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="elibc_FreeBSD gtk kde +gstreamer"
+
+O_V="$(get_version_component_range 1-2)" # Major version, i.e. 11.00
+O_B="$(get_version_component_range 3)"   # Build version, i.e. 1156
+
+O_D="rc1_${O_V}-${O_B}"
+O_P="${PN}-${O_V}-${O_B}"
+O_U="http://snapshot.opera.com/unix/"
+
+SRC_URI="
+	amd64? ( ${O_U}${O_D}/${O_P}.x86_64.linux.tar.xz )
+	x86? ( ${O_U}${O_D}/${O_P}.i386.linux.tar.xz )
+	x86-fbsd? ( ${O_U}${O_D}/${O_P}.i386.freebsd.tar.xz )
+"
+
+OPREFIX="/usr/$(get_libdir)"
+
+QA_DT_HASH="${OPREFIX}/${PN}/.*"
+QA_PRESTRIPPED="${OPREFIX}/${PN}/.*"
+
+O_LINGUAS="af az be bg bn cs da de el en-GB es-ES es-LA et fi fr fr-CA fy gd hi
+hr hu id it ja ka ko lt me mk ms nb nl nn pa pl pt pt-BR ro ru sk sr sv sw ta te
+th tl tr uk uz vi zh-CN zh-TW zu"
+
+for O_LINGUA in ${O_LINGUAS}; do
+	IUSE="${IUSE} linguas_${O_LINGUA/-/_}"
+done
+
+DEPEND="
+	>=sys-apps/sed-4
+	app-arch/xz-utils
+"
+GTKRDEPEND="
+	dev-libs/atk
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/pango
+	x11-libs/pixman
+"
+KDERDEPEND="
+	kde-base/kdelibs
+	x11-libs/qt-core
+	x11-libs/qt-gui
+"
+GSTRDEPEND="
+	dev-libs/glib
+	dev-libs/libxml2
+	media-plugins/gst-plugins-meta
+	media-libs/gstreamer
+"
+RDEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXft
+	x11-libs/libXrender
+	gtk? ( ${GTKRDEPEND} )
+	kde? ( ${KDERDEPEND} )
+	gstreamer? ( ${GSTRDEPEND} )
+"
+
+pkg_setup() {
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+	elog "If you seek support, please file a bug report at"
+	elog "https://bugs.gentoo.org and post the output of"
+	elog " \`emerge --info =${CATEGORY}/${P}'"
+	echo -e \
+		" ${GOOD}****************************************************${NORMAL}"
+}
+
+src_unpack() {
+	unpack ${A}
+	mv -v ${PN}* "${S}" || die
+}
+
+src_prepare() {
+	local LNGDIR="share/${PN}/locale"
+
+	# Count linguas
+	count() { echo ${#}; }
+	local lingua_count=$(count ${O_LINGUAS} en)
+	local locale_count=$(count ${LNGDIR}/*)
+	[[ ${lingua_count} = ${locale_count} ]] \
+		|| die "Number of LINGUAS does not match number of locales"
+	unset count
+
+	# Remove unwanted linguas
+	einfo "Keeping these locales (linguas): ${LINGUAS}."
+	for LINGUA in ${O_LINGUAS}; do
+		if ! use linguas_${LINGUA/-/_}; then
+			LINGUA=$(find "${LNGDIR}" -maxdepth 1 -type d -iname ${LINGUA/_/-})
+			rm -r "${LINGUA}" || die "The list of linguas needs to be fixed"
+		fi
+	done
+
+	# Remove doc directory but keep the LICENSE under another name (bug #315473)
+	mv share/doc/${PN}/LICENSE share/${PN}/defaults/license.txt
+	rm -rf share/doc
+	for locale in share/${PN}/locale/*; do
+		rm -f "${locale}/license.txt"
+		ln -sn /usr/share/${PN}/defaults/license.txt "${locale}/license.txt" \
+			|| die "ln -sn license.txt"
+	done
+
+	# Remove package directory
+	rm -rf share/${PN}/package
+
+	# Leave libopera*.so only if the user chooses
+	if ! use gtk; then
+		rm lib/${PN}/liboperagtk.so || die "rm liboperagtk.so failed"
+	fi
+	if ! use kde; then
+		rm lib/${PN}/liboperakde4.so || die "rm liboperakde4.so failed"
+	fi
+
+	# Unzip the man pages before sedding
+	gunzip share/man/man1/* || die "gunzip failed"
+
+	# Replace PREFIX, SUFFIX and PN in various files
+	sed -i \
+		-e "s:@@{PREFIX}:/usr:g" \
+		-e "s:@@{SUFFIX}::g" \
+		-e "s:@@{_SUFFIX}::g" \
+		-e "s:@@{USUFFIX}::g" \
+		-e "s:opera:${PN}:g" \
+		share/man/man1/* \
+		share/applications/${PN}-browser.desktop \
+		|| die "sed failed"
+
+	# Create /usr/bin/opera wrapper
+	echo '#!/bin/sh' > ${PN}
+	echo 'export OPERA_DIR=/usr/share/'"${PN}" >> ${PN}
+	echo 'export OPERA_PERSONALDIR=${OPERA_PERSONALDIR:-"${HOME}/.'${PN}'"}' \
+		>> ${PN}
+	echo 'exec '"${OPREFIX}/${PN}/${PN}"' "$@"' >> ${PN}
+
+	# Fix libdir in defaults/pluginpath.ini
+	sed -i \
+		share/${PN}/defaults/pluginpath.ini \
+		-e "s|/usr/lib32|${OPREFIX}|g" \
+		-e '/netscape/{s|[0-1]|2|g}' \
+		|| die "sed pluginpath.ini failed"
+
+	# Change libz.so.3 to libz.so.1 for gentoo/freebsd
+	if use elibc_FreeBSD; then
+		scanelf -qR -N libz.so.3 -F "#N" lib/${PN}/ | \
+		while read i; do
+			if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
+			then
+				export SANITY_CHECK_LIBZ_FAILED=1
+				break
+			fi
+			sed -i \
+				"$i" \
+				-e 's/libz\.so\.3/libz.so.1/g'
+		done
+		[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] \
+			&& die "failed to change libz.so.3 to libz.so.1"
+	fi
+}
+
+src_install() {
+	# We install into usr instead of opt as Opera does not support the latter
+	dodir /usr
+	mv lib/ "${D}/${OPREFIX}" || die "mv lib/ failed"
+	mv share/ "${D}/usr/" || die "mv share/ failed"
+
+	# Install startup scripts
+	dobin ${PN} || die "dobin failed"
+
+	# Stop revdep-rebuild from checking opera binaries
+	dodir /etc/revdep-rebuild
+	echo "SEARCH_DIRS_MASK=\"${OPREFIX}/${PN}\"" \
+		> "${D}"/etc/revdep-rebuild/90${PN}
+
+	# Set PaX markings for hardened/PaX (bug #344267)
+	pax-mark m \
+		"${D}/${OPREFIX}/${PN}/${PN}" \
+		"${D}/${OPREFIX}/${PN}/operaplugincleaner" \
+		"${D}/${OPREFIX}/${PN}/operapluginwrapper"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	elog "To change the UI language, choose [Tools] -> [Preferences], open the"
+	elog "[General] tab, click on [Details...] then [Choose...] and point the"
+	elog "file chooser at /usr/share/${PN}/locale/, then enter the"
+	elog "directory for the language you want and [Open] the .lng file."
+
+	if use elibc_FreeBSD; then
+		elog
+		elog "To improve shared memory usage please set:"
+		elog "$ sysctl kern.ipc.shm_allow_removed=1"
+	fi
+
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	# Update desktop file database and gtk icon cache (bug #334993)
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}