1 files changed, 69 insertions, 0 deletions
diff --git a/app-arch/bsdtar/bsdtar-1.2.51-r1.ebuild b/app-arch/bsdtar/bsdtar-1.2.51-r1.ebuild
new file mode 100644
index 000000000000..f6767e00f956
--- /dev/null
+++ b/app-arch/bsdtar/bsdtar-1.2.51-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/bsdtar/bsdtar-1.2.51-r1.ebuild,v 1.1 2006/03/21 20:05:45 flameeyes Exp $
+
+inherit eutils autotools
+
+MY_P="libarchive-${PV}"
+
+DESCRIPTION="BSD tar command"
+HOMEPAGE="http://people.freebsd.org/~kientzle/libarchive/"
+SRC_URI="http://people.freebsd.org/~kientzle/libarchive/src/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc-macos ~x86"
+IUSE="build static acl xattr"
+
+RDEPEND="!dev-libs/libarchive
+	kernel_linux? (
+		acl? ( sys-apps/acl )
+		xattr? ( sys-apps/attr )
+		)"
+DEPEND="kernel_linux? ( sys-fs/e2fsprogs
+	virtual/os-headers )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	epatch "${FILESDIR}/${MY_P}-linking.patch"
+	epatch "${FILESDIR}/${MY_P}-acl.patch"
+
+	eautoreconf
+	epunt_cxx
+}
+
+src_compile() {
+	local myconf
+
+	if ! use userland_Darwin && ( use static || use build ); then
+		myconf="${myconf} --enable-static-bsdtar"
+	else
+		myconf="${myconf} --disable-static-bsdtar"
+	fi
+
+	econf --bindir=/bin \
+		$(use_enable acl) \
+		$(use_enable xattr) \
+		${myconf} || die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install
+
+	# Create tar symlink for FreeBSD
+	if [[ ${CHOST} == *-freebsd* ]]; then
+		dosym bsdtar /bin/tar
+		dosym bsdtar.1.gz /usr/share/man/man1/tar.1.gz
+	fi
+
+	if [[ ${CHOST} != *-darwin* ]]; then
+		dodir /$(get_libdir)
+		mv ${D}/usr/$(get_libdir)/*.so* ${D}/$(get_libdir)
+		gen_usr_ldscript libarchive.so
+	fi
+}