1 files changed, 55 insertions, 0 deletions
diff --git a/dev-libs/libtar/libtar-1.2.20-r1.ebuild b/dev-libs/libtar/libtar-1.2.20-r1.ebuild
new file mode 100644
index 000000000000..ebbd177b23e0
--- /dev/null
+++ b/dev-libs/libtar/libtar-1.2.20-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libtar/libtar-1.2.20-r1.ebuild,v 1.1 2013/10/13 08:09:16 ago Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+inherit autotools-utils
+
+DESCRIPTION="C library for manipulating tar archives"
+HOMEPAGE="http://www.feep.net/libtar/ http://repo.or.cz/w/libtar.git/"
+SRC_URI="http://repo.or.cz/w/libtar.git/snapshot/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="static-libs zlib"
+
+RDEPEND="zlib? ( sys-libs/zlib )
+	!zlib? ( app-arch/gzip )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.2.11-free.patch"
+	"${FILESDIR}/${PN}-1.2.11-impl-dec.patch"
+)
+
+src_prepare() {
+	sed -i \
+		-e '/INSTALL_PROGRAM/s:-s::' \
+		{doc,lib{,tar}}/Makefile.in || die
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-encap
+		--disable-epkg-install
+		$(use_with zlib)
+	)
+
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	dodoc ChangeLog* README TODO
+	newdoc compat/README README.compat
+	newdoc compat/TODO TODO.compat
+	newdoc listhash/TODO TODO.listhash
+}