1 files changed, 70 insertions, 0 deletions
diff --git a/dev-lisp/ecls/ecls-10.2.1.ebuild b/dev-lisp/ecls/ecls-10.2.1.ebuild
new file mode 100644
index 000000000000..ba30ac9521d6
--- /dev/null
+++ b/dev-lisp/ecls/ecls-10.2.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lisp/ecls/ecls-10.2.1.ebuild,v 1.1 2010/02/19 16:36:18 grozin Exp $
+
+EAPI=3
+inherit eutils multilib
+
+MY_P=ecl-${PV}
+
+DESCRIPTION="ECL is an embeddable Common Lisp implementation."
+HOMEPAGE="http://common-lisp.net/project/ecl/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tgz"
+
+LICENSE="BSD LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="debug doc precisegc +threads +unicode X"
+
+RDEPEND="dev-libs/gmp
+		virtual/libffi
+		>=dev-libs/boehm-gc-7.1[threads?]"
+DEPEND="${RDEPEND}"
+PDEPEND="dev-lisp/gentoo-init"
+
+PROVIDE="virtual/commonlisp"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PV}-headers-gentoo.patch
+}
+
+src_configure() {
+	econf \
+		--with-system-gmp \
+		--enable-boehm=system \
+		--enable-longdouble \
+		--enable-gengc \
+		$(use_enable precisegc) \
+		$(use_with debug debug-cflags) \
+		$(use_enable threads) \
+		$(use_with threads __thread) \
+		$(use_enable unicode) \
+		$(use_with X x) \
+		$(use_with X clx)
+}
+
+src_compile() {
+	#parallel fails
+	emake -j1 || die "Compilation failed"
+	if use doc; then
+		pushd build/doc
+		emake || die "Building docs failed"
+		popd
+	fi
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "Installation failed"
+
+	dodoc ANNOUNCEMENT Copyright
+	dodoc "${FILESDIR}"/README.Gentoo
+	pushd build/doc
+	newman ecl.man ecl.1
+	newman ecl-config.man ecl-config.1
+	if use doc; then
+		doinfo ecl{,dev}.info || die "Installing info docs failed"
+	fi
+	popd
+}