1 files changed, 54 insertions, 0 deletions
diff --git a/kde-base/konqueror/konqueror-4.3.2.ebuild b/kde-base/konqueror/konqueror-4.3.2.ebuild
new file mode 100644
index 000000000000..edb02ecf48e6
--- /dev/null
+++ b/kde-base/konqueror/konqueror-4.3.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/konqueror/konqueror-4.3.2.ebuild,v 1.1 2009/10/06 19:50:50 alexxy Exp $
+
+EAPI="2"
+
+KMNAME="kdebase-apps"
+inherit kde4-meta
+
+DESCRIPTION="KDE: Web browser, file manager, ..."
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="+auth +bookmarks debug +handbook thumbnail"
+# 4 of 4 tests fail. Last checked for 4.0.3
+RESTRICT="test"
+
+DEPEND="
+	>=kde-base/libkonq-${PV}:${SLOT}[kdeprefix=]
+"
+RDEPEND="${DEPEND}
+	>=kde-base/kdebase-kioslaves-${PV}:${SLOT}[kdeprefix=]
+	>=kde-base/keditfiletype-${PV}:${SLOT}[kdeprefix=]
+	>=kde-base/kfind-${PV}:${SLOT}[kdeprefix=]
+	>=kde-base/kfmclient-${PV}:${SLOT}[kdeprefix=]
+	>=kde-base/kurifilter-plugins-${PV}:${SLOT}[kdeprefix=]
+	auth? ( >=kde-base/kpasswdserver-${PV}:${SLOT}[kdeprefix=] )
+	bookmarks? ( >=kde-base/keditbookmarks-${PV}:${SLOT}[kdeprefix=] )
+"
+PDEPEND="
+	thumbnail? ( >=kde-base/mplayerthumbs-${PV}:${SLOT}[kdeprefix=] )
+"
+
+KMEXTRACTONLY="
+	konqueror/client/
+	lib/konq/
+"
+
+src_prepare() {
+	kde4-meta_src_prepare
+
+	# Do not install *.desktop files for kfmclient
+	sed -e "/kfmclient\.desktop/d" -i konqueror/CMakeLists.txt \
+		|| die "Failed to omit .desktop files"
+}
+
+pkg_postinst() {
+	kde4-meta_pkg_postinst
+
+	echo
+	elog "If you want to use konqueror as a filemanager, install the dolphin kpart:"
+	elog "emerge -1 kde-base/dolphin:${SLOT}"
+	elog
+	elog "To use Java on webpages: emerge jre"
+	echo
+}