1 files changed, 69 insertions, 0 deletions
diff --git a/media-sound/audacity/audacity-1.2.4b-r1.ebuild b/media-sound/audacity/audacity-1.2.4b-r1.ebuild
new file mode 100644
index 000000000000..b78721de920b
--- /dev/null
+++ b/media-sound/audacity/audacity-1.2.4b-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/audacity-1.2.4b-r1.ebuild,v 1.1 2006/01/03 03:11:48 matsuu Exp $
+
+inherit wxwidgets eutils flag-o-matic
+
+IUSE="encode mad vorbis"
+
+MY_P="${PN}-src-${PV}"
+DESCRIPTION="Free crossplatform audio editor"
+HOMEPAGE="http://audacity.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+
+DEPEND="=x11-libs/wxGTK-2.4*
+	>=app-arch/zip-2.3
+	media-libs/libid3tag
+	>=media-libs/libsndfile-1.0.0
+	vorbis? ( >=media-libs/libvorbis-1.0 )
+	encode? ( >=media-sound/lame-3.92 )
+	mad? ( >=media-libs/libmad-0.14.2b )"
+
+WX_GTK_VER="2.4"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+
+	cd "${S}"
+	epatch "${FILESDIR}"/${PN}-1.2.3-gcc41.patch # bug 113754
+}
+
+src_compile() {
+	if built_with_use '=x11-libs/wxGTK-2.4*' gtk2 ; then
+		need-wxwidgets gtk2
+	else
+		need-wxwidgets gtk
+	fi
+
+	filter-flags -fPIC
+
+	econf \
+		$(use_with mad libmad system) \
+		$(use_with vorbis vorbis system) \
+		--with-id3tag=system \
+		--with-libsndfile=system || die
+
+	# parallel borks
+	emake -j1 || die
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+
+	# Remove bad doc install
+	rm -rf ${D}/usr/share/doc
+
+	# Install our docs
+	dodoc README.txt audacity-1.2-help.htb
+
+	insinto /usr/share/icons/hicolor/48x48/apps
+	newins images/AudacityLogo48x48.xpm audacity.xpm
+
+	make_desktop_entry audacity Audacity audacity
+}