1 files changed, 56 insertions, 0 deletions
diff --git a/net-analyzer/fail2ban/fail2ban-0.8.2.ebuild b/net-analyzer/fail2ban/fail2ban-0.8.2.ebuild
new file mode 100644
index 000000000000..e1013fa0aab3
--- /dev/null
+++ b/net-analyzer/fail2ban/fail2ban-0.8.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/fail2ban-0.8.2.ebuild,v 1.1 2008/03/17 19:00:57 jer Exp $
+
+inherit distutils
+
+DESCRIPTION="Bans IP that make too many password failures"
+HOMEPAGE="http://fail2ban.sourceforge.net/"
+SRC_URI="mirror://sourceforge/fail2ban/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE=""
+
+DEPEND=">=dev-lang/python-2.4"
+RDEPEND="${DEPEND}
+	virtual/mta"
+
+src_install() {
+	distutils_src_install
+
+	newconfd files/gentoo-confd fail2ban
+	newinitd files/gentoo-initd fail2ban
+	dodoc CHANGELOG README TODO || die "dodoc failed"
+	doman man/*.1 || die "doman failed"
+
+	# Use INSTALL_MASK  if you do not want to touch /etc/logrotate.d.
+	# See http://thread.gmane.org/gmane.linux.gentoo.devel/35675
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}-logrotate ${PN} || die
+}
+
+pkg_postinst() {
+	if has_version '<net-analyzer/fail2ban-0.7' ; then
+		elog
+		elog "Configuration files are now in /etc/fail2ban/"
+		elog "You probably have to manually update your configuration"
+		elog "files before restarting Fail2ban!"
+		elog
+		elog "Fail2ban is not installed under /usr/lib anymore. The"
+		elog "new location is under /usr/share."
+		elog
+		elog "You are upgrading from version 0.6.x, please see:"
+		elog "http://www.fail2ban.org/wiki/index.php/HOWTO_Upgrade_from_0.6_to_0.8"
+	fi
+}
+
+pkg_setup() {
+	if ! built_with_use dev-lang/python readline ; then
+		echo
+		eerror "dev-lang/python is missing readline support. Please add"
+		eerror "'readline' to your USE flags, and re-emerge dev-lang/python."
+		die "dev-lang/python needs readline support"
+	fi
+}