1 files changed, 45 insertions, 0 deletions
diff --git a/net-analyzer/goaccess/goaccess-0.6.1.ebuild b/net-analyzer/goaccess/goaccess-0.6.1.ebuild
new file mode 100644
index 000000000000..3a36b14b7104
--- /dev/null
+++ b/net-analyzer/goaccess/goaccess-0.6.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/goaccess/goaccess-0.6.1.ebuild,v 1.1 2013/11/24 15:01:18 hwoarang Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+inherit autotools-utils
+
+DESCRIPTION="A real-time Apache log analyzer and interactive viewer that runs in a terminal"
+HOMEPAGE="http://goaccess.prosoftcorp.com"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+IUSE="geoip unicode"
+
+RDEPEND="
+	dev-libs/glib:2
+	sys-libs/ncurses[unicode?]
+	geoip? ( dev-libs/geoip )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# respect CFLAGS, bug #451806
+	sed -i -e '/AM_CFLAGS/s/-g//' Makefile.am || die 'sed failed'
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	# configure does not properly recognise '--disable-something'
+	local myeconfargs=(
+		$(usex geoip '--enable-geoip' '' '' '')
+		$(usex unicode '--enable-utf8' '' '' '')
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile CFLAGS="${CFLAGS}"
+}