1 files changed, 73 insertions, 0 deletions
diff --git a/net-libs/rb_libtorrent/rb_libtorrent-0.14.8-r1.ebuild b/net-libs/rb_libtorrent/rb_libtorrent-0.14.8-r1.ebuild
new file mode 100644
index 000000000000..76136a9aeabe
--- /dev/null
+++ b/net-libs/rb_libtorrent/rb_libtorrent-0.14.8-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.14.8-r1.ebuild,v 1.1 2010/01/14 12:27:02 yngwin Exp $
+
+EAPI="2"
+inherit autotools eutils flag-o-matic versionator
+
+MY_P=${P/rb_/}
+MY_P=${MY_P/torrent/torrent-rasterbar}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
+HOMEPAGE="http://www.rasterbar.com/products/libtorrent/"
+SRC_URI="http://libtorrent.googlecode.com/files/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="debug doc examples python test"
+RESTRICT="test"
+
+DEPEND="|| ( >=dev-libs/boost-1.35
+		( ~dev-libs/boost-1.34.1 dev-cpp/asio ) )
+	python? ( >=dev-libs/boost-1.35.0-r5[python] dev-lang/python:2.6[threads] )
+	sys-libs/zlib"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/0.14.6-configure-ldflags-fix.patch  #290756
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -pthread
+
+	# use multi-threading versions of boost libs
+	local BOOST_LIBS="--with-boost-system=boost_system-mt \
+		--with-boost-asio=boost_system-mt \
+		--with-boost-filesystem=boost_filesystem-mt \
+		--with-boost-thread=boost_thread-mt \
+		--with-boost-regex=boost_regex-mt \
+		--with-boost-python=boost_python-mt \
+		--with-boost-program_options=boost_program_options-mt"
+
+	# detect boost version and location, bug 295474
+	BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
+	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
+	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
+	BOOST_INC="/usr/include/boost-${BOOST_VER}"
+	BOOST_LIB="/usr/$(get_libdir)/boost-${BOOST_VER}"
+
+	local LOGGING
+	use debug && LOGGING="--with-logging=verbose"
+
+	econf $(use_enable debug) \
+		$(use_enable test tests) \
+		$(use_enable examples) \
+		$(use_enable python python-binding) \
+		--with-zlib=system \
+		--with-asio=system \
+		${LOGGING} \
+		--with-boost=${BOOST_INC} \
+		--with-boost-libdir=${BOOST_LIB} \
+		${BOOST_LIBS}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die 'emake install failed'
+	dodoc ChangeLog AUTHORS NEWS README || die 'dodoc failed'
+	if use doc ; then
+		dohtml docs/* || die "Could not install HTML documentation"
+	fi
+}