1 files changed, 55 insertions, 0 deletions
diff --git a/sys-fs/ntfs3g/ntfs3g-1.1120.ebuild b/sys-fs/ntfs3g/ntfs3g-1.1120.ebuild
new file mode 100644
index 000000000000..131d7c7cd231
--- /dev/null
+++ b/sys-fs/ntfs3g/ntfs3g-1.1120.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ntfs3g-1.1120.ebuild,v 1.1 2007/11/26 17:17:42 chutzpah Exp $
+
+inherit multilib toolchain-funcs
+
+MY_PN="${PN/3g/-3g}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Open source read-write NTFS driver that runs under FUSE"
+HOMEPAGE="http://www.ntfs-3g.org"
+SRC_URI="http://www.ntfs-3g.org/${MY_P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug suid"
+
+RDEPEND=">=sys-fs/fuse-2.6.3"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_compile() {
+	econf \
+		--disable-ldconfig \
+		--libdir=/$(get_libdir) \
+		$(use_enable debug)
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+
+	dodir /usr/$(get_libdir)/
+	mv "${D}"/$(get_libdir)/*.{,l}a "${D}"/usr/$(get_libdir)/
+
+	dodoc AUTHORS ChangeLog CREDITS NEWS README
+
+	gen_usr_ldscript libntfs-3g.so
+
+	use suid && fperms u+s /bin/${MY_PN}
+}
+
+pkg_postinst() {
+	if use suid; then
+		ewarn
+		ewarn "You have chosen to install ${PN} with the binary setuid root. This"
+		ewarn "means that if there any undetected vulnerabilities in the binary,"
+		ewarn "then local users may be able to gain root access on your machine."
+		ewarn
+	fi
+}