1 files changed, 47 insertions, 0 deletions
diff --git a/sys-kernel/linux-headers/linux-headers-2.6.32.ebuild b/sys-kernel/linux-headers/linux-headers-2.6.32.ebuild
new file mode 100644
index 000000000000..ec6eea2787c0
--- /dev/null
+++ b/sys-kernel/linux-headers/linux-headers-2.6.32.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-headers/linux-headers-2.6.32.ebuild,v 1.1 2010/02/13 08:51:49 vapier Exp $
+
+ETYPE="headers"
+H_SUPPORTEDARCH="alpha amd64 arm bfin cris hppa m68k mips ia64 ppc ppc64 s390 sh sparc x86"
+inherit kernel-2
+detect_version
+
+PATCH_VER="1"
+SRC_URI="mirror://gentoo/gentoo-headers-base-${PV}.tar.lzma"
+[[ -n ${PATCH_VER} ]] && SRC_URI="${SRC_URI} mirror://gentoo/gentoo-headers-${PV}-${PATCH_VER}.tar.lzma"
+
+KEYWORDS="-* ~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+
+DEPEND="|| ( app-arch/xz-utils app-arch/lzma-utils )"
+RDEPEND=""
+
+S=${WORKDIR}/gentoo-headers-base-${PV}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	[[ -n ${PATCH_VER} ]] && EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/${PV}
+}
+
+src_install() {
+	kernel-2_src_install
+	cd "${D}"
+	egrep -r \
+		-e '(^|[[:space:](])(asm|volatile|inline)[[:space:](]' \
+		-e '\<([us](8|16|32|64))\>' \
+		.
+	headers___fix $(find -type f)
+
+	egrep -l -r -e '__[us](8|16|32|64)' "${D}" | xargs grep -L linux/types.h
+
+	# hrm, build system sucks
+	find "${D}" '(' -name '.install' -o -name '*.cmd' ')' -print0 | xargs -0 rm -f
+
+	# provided by libdrm (for now?)
+	rm -rf "${D}"/$(kernel_header_destdir)/drm
+}
+
+src_test() {
+	emake ARCH=$(tc-arch-kernel) headers_check || die
+}