1 files changed, 54 insertions, 0 deletions
diff --git a/sys-process/htop/htop-0.9.ebuild b/sys-process/htop/htop-0.9.ebuild
new file mode 100644
index 000000000000..a343bcc6f7b7
--- /dev/null
+++ b/sys-process/htop/htop-0.9.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-process/htop/htop-0.9.ebuild,v 1.1 2011/01/09 14:48:11 ssuominen Exp $
+
+EAPI=3
+inherit eutils flag-o-matic multilib
+
+DESCRIPTION="interactive process viewer"
+HOMEPAGE="http://htop.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
+IUSE="cgroup debug openvz unicode vserver"
+
+DEPEND="sys-libs/ncurses[unicode?]"
+
+pkg_setup() {
+	if use elibc_FreeBSD && ! [[ -f ${ROOT}/proc/stat && -f ${ROOT}/proc/meminfo ]]; then
+		eerror
+		eerror "htop needs /proc mounted to compile and work, to mount it type"
+		eerror "mount -t linprocfs none /proc"
+		eerror "or uncomment the example in /etc/fstab"
+		eerror
+		die "htop needs /proc mounted"
+	fi
+
+	if ! has_version sys-process/lsof; then
+		ewarn "To use lsof features in htop(what processes are accessing"
+		ewarn "what files), you must have sys-process/lsof installed."
+	fi
+}
+
+src_prepare() {
+	sed -i -e '1c\#!'"${EPREFIX}"'/usr/bin/python' \
+		scripts/MakeHeader.py || die
+}
+
+src_configure() {
+	useq debug && append-flags -DDEBUG
+
+	econf \
+		$(use_enable openvz) \
+		$(use_enable cgroup) \
+		$(use_enable vserver) \
+		$(use_enable unicode) \
+		--enable-taskstats
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc ChangeLog README TODO
+}