app-admin/keepassx/keepassx-0.3.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/keepassx/keepassx-0.3.4.ebuild,v 1.4 2009/02/01 19:20:51 nixnut Exp $

EAPI="2"

inherit eutils qt4

DESCRIPTION="Qt password manager compatible with its Win32 and Pocket PC versions."
HOMEPAGE="http://keepassx.sourceforge.net/"
SRC_URI="mirror://sourceforge/keepassx/KeePassX-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="debug"
DEPEND="|| ( ( x11-libs/qt-core:4[qt3support]
			x11-libs/qt-gui:4[qt3support]
			x11-libs/qt-xmlpatterns:4 )
		( =x11-libs/qt-4.3*:4[png,qt3support,zlib] ) )"
RDEPEND="${DEPEND}"

src_configure() {
	# generate translations
	cd "${S}/src"
	lrelease src.pro || die "lrelease failed"
	mv "${S}"/src/translations/*.qm "${S}"/share/keepassx/i18n

	cd "${S}"
	use debug && myconf="DEBUG=1"
	eqmake4 ${PN}.pro PREFIX="${D}/usr" ${myconf} || die "eqmake4 failed"
}

src_compile(){
	# workaround compile failure due to distcc, bug #214327
	PATH=${PATH/\/usr\/lib\/distcc\/bin:}
	emake || die "emake failed"
}

src_install(){
	# workaround pre-stripping the keepassx binary during install, bug #248711
	sed -i -e '/strip/d' "${S}"/src/Makefile || die "sed failed"

	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc changelog todo || die "dodoc failed"
}