dev-ruby/nio4r/nio4r-1.0.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/nio4r/nio4r-1.0.0.ebuild,v 1.3 2014/08/12 22:46:53 blueness Exp $

EAPI=5

USE_RUBY="ruby19 ruby20 ruby21"

RUBY_FAKEGEM_RECIPE_TEST="rspec"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"

inherit ruby-fakegem

DESCRIPTION="A high performance selector API for monitoring IO objects"
HOMEPAGE="https://github.com/celluloid/nio4r"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64"
IUSE=""

RDEPEND+=" dev-libs/libev"

ruby_add_bdepend "test? ( dev-ruby/rake-compiler )"

RUBY_PATCHES=( "${FILESDIR}"/${P}-extconf.patch )

all_ruby_prepare() {
	rm -rf ext/libev
	sed -i -e 's#"../libev/ev.h"#<ev.h>#' ext/${PN}/libev.h || die
	sed -i -e '/ev.c/d' ext/${PN}/nio4r_ext.c || die
	sed -i -e '/[Cc]overalls/d' -e '/[Bb]undler/d' spec/spec_helper.rb || die
}

each_ruby_configure() {
	${RUBY} -Cext/${PN} extconf.rb || die
}

each_ruby_compile() {
	emake V=1 -Cext/${PN}
	cp ext/${PN}/*$(get_modname) lib/ || die
}