games-puzzle/lmarbles/lmarbles-1.0.6.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/lmarbles/lmarbles-1.0.6.ebuild,v 1.3 2004/06/24 23:06:59 agriffis Exp $

inherit games

DESCRIPTION="puzzle game inspired by Atomix and written in SDL"
HOMEPAGE="http://lgames.sourceforge.net/index.php?project=LMarbles"
SRC_URI="mirror://sourceforge/lgames/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ppc amd64"
IUSE=""

RDEPEND=">=media-libs/libsdl-1.2.4
	>=media-libs/sdl-mixer-1.2.3"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}
	cd ${S}
	sed -i \
		-e '/^inst_dir/s:/games::' \
		-e "/^prf_dir/s:/var/lib/games:${GAMES_STATEDIR}:" configure \
		|| die "sed configure failed"
	sed -i \
		-e '/c_pth, strlen/s:strlen:sizeof:' src/cfg.c \
		|| die "sed src/cfg.c failed"
	sed -i \
		-e 's:/marbles.prfs:/lmarbles.prfs:' \
		src/Makefile.in src/lmarbles.6 \
		|| die "sed marbles/lmarbles failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog README TODO
	prepgamesdirs
}