media-sound/amarok/amarok-1.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-1.1.ebuild,v 1.2 2004/09/28 17:59:43 eradicator Exp $

IUSE="cjk gstreamer xmms opengl xine arts noamazon"

inherit kde eutils

MY_P="${P/_beta/-beta}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="amaroK is a media player for KDE"
HOMEPAGE="http://amarok.kde.org/"
SRC_URI="mirror://sourceforge/amarok/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"

# ppc: please test out libvisual!
KEYWORDS="~x86 ~ppc ~amd64"

DEPEND="!ppc? ( >=media-libs/libvisual-0.1.6 )
	arts? ( >=kde-base/kdemultimedia-3.2 )
	gstreamer? ( >=media-libs/gst-plugins-0.8.1 )
	opengl? ( virtual/opengl )
	xmms? ( >=media-sound/xmms-1.2 )
	xine? ( >=media-libs/xine-lib-1_rc4 )
	>=media-libs/tunepimp-0.3.0
	>=dev-util/pkgconfig-0.9.0
	>=media-libs/taglib-1.3
	>=kde-base/kdelibs-3.2
	>=x11-libs/qt-3.3"

need-kde 3.2

src_unpack() {
	if  ! use gstreamer && ! use xine && ! use arts
	then
		die "You must enable either Gstreamer, aRts or Xine"
	fi

	kde_src_unpack
	#CJK mp3 tag fix
	use cjk && epatch ${FILESDIR}/amarok-1.0-cjk-a.diff
}

src_compile() {
	PREFIX="`kde-config --prefix`"

	myconf="`use_with arts` `use_with gstreamer`"
	myconf="${myconf} `use_with opengl` `use_with xine` `use_enable !noamazon amazon`"

	einfo "${myconf}"

	kde_src_compile myconf configure make || die
}