blob: 09851094fb978b259dcdfb2b1eecd5725240e87e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/gxine/gxine-0.5.906-r1.ebuild,v 1.4 2012/01/28 04:20:54 ssuominen Exp $
EAPI=4
inherit autotools eutils fdo-mime gnome2-utils multilib nsplugins
DESCRIPTION="GTK+ Front-End for libxine"
HOMEPAGE="http://xine.sourceforge.net/"
SRC_URI="mirror://sourceforge/xine/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 x86"
IUSE="gnome lirc nls nsplugin udev xcb xinerama"
RDEPEND=">=media-libs/xine-lib-1.1.17
>=x11-libs/gtk+-2.8:2
>=dev-libs/glib-2.10:2
>=x11-libs/pango-1.12
>=dev-lang/spidermonkey-1.8.2.15
x11-libs/libX11
x11-libs/libXext
x11-libs/libXrender
gnome? ( >=dev-libs/dbus-glib-0.88 )
lirc? ( app-misc/lirc )
nls? ( virtual/libintl )
nsplugin? ( dev-libs/nspr
x11-libs/libXaw
x11-libs/libXt )
udev? ( || ( >=sys-fs/udev-171-r1[gudev] <sys-fs/udev-171-r1[extras] ) )
xcb? ( x11-libs/libxcb )
xinerama? ( x11-libs/libXinerama )"
DEPEND="${RDEPEND}
dev-util/pkgconfig
nls? ( sys-devel/gettext )"
src_prepare() {
# ld: cannot find -ljs
sed -i -e '/JS_LIBS="`spidermonkey_locate_lib/s:js:mozjs:' m4/_js.m4 || die
epatch \
"${FILESDIR}"/${PN}-0.5.905-desktop.patch \
"${FILESDIR}"/${PN}-0.5.905-fix-nspr-useage.patch \
"${FILESDIR}"/${P}-endif.patch \
"${FILESDIR}"/${P}-playlist_segfault.patch
# need to disable calling of xine-list when running without
# userpriv, otherwise we get sandbox violations (bug #233847)
if [[ ${EUID} == "0" ]]; then
sed -i -e 's:^XINE_LIST=.*$:XINE_LIST=:' configure.ac || die
fi
eautoreconf
}
src_configure() {
econf \
$(use_enable nls) \
$(use_enable lirc) \
--enable-watchdog \
$(use_with xcb) \
$(has_version '<dev-lang/spidermonkey-1.8.5' && echo --with-spidermonkey=/usr/include/js) \
$(use_with nsplugin browser-plugin) \
$(use_with udev gudev) \
--without-hal \
$(use_with gnome dbus) \
$(use_with xinerama)
}
src_install() {
emake DESTDIR="${D}" \
docdir=/usr/share/doc/${PF} \
docsdir=/usr/share/doc/${PF} \
install
dodoc AUTHORS BUGS ChangeLog NEWS README{,.{cs,de},_l10n} TODO
use nsplugin && inst_plugin /usr/$(get_libdir)/gxine/gxineplugin.so
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
gnome2_icon_cache_update
}
pkg_postrm() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
gnome2_icon_cache_update
}
|
GitWeb