www-apps/dragonflycms/dragonflycms-9.2.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/dragonflycms/dragonflycms-9.2.1.ebuild,v 1.1 2008/02/28 07:06:41 wrobel Exp $

inherit webapp depend.php

MY_P=Dragonfly${PV}

DESCRIPTION="A feature-rich open source content management system based off of PHP-Nuke 6.5"
HOMEPAGE="http://dragonflycms.org"
SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"

RESTRICT="fetch"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~x86"
IUSE=""

need_httpd_cgi
need_php_httpd

S="${WORKDIR}"

pkg_nofetch() {
	einfo "Please download ${MY_P}.tar.bz2 from:"
	einfo "http://dragonflycms.org/Downloads/get=28.html"
	einfo "and move it to ${DISTDIR}"
}

src_install() {
	webapp_src_preinst

	dodoc documentation/{BACKUP,IMPORTANT_NOTES,INSTALL,README,UPGRADE}.txt

	insinto "${MY_HTDOCSDIR}"
	doins -r public_html/*

	webapp_configfile "${MY_HTDOCSDIR}"/install/config.php

	for x in cpg_error.log includes cache modules/coppermine/albums \
			modules/coppermine/albums/userpics uploads/avatars \
			uploads/forums; do
		webapp_serverowned "${MY_HTDOCSDIR}"/${x}
	done

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_src_install
}