x11-wm/aewm/aewm-1.3.12.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/aewm/aewm-1.3.12.ebuild,v 1.5 2014/11/01 17:48:38 ago Exp $

EAPI=5
inherit eutils toolchain-funcs

DESCRIPTION="A minimalistic X11 window manager"
HOMEPAGE="http://www.red-bean.com/~decklin/software/aewm/"
SRC_URI="${HOMEPAGE}${P}.tar.bz2"

LICENSE="MIT 9wm"
SLOT="0"
KEYWORDS="amd64 ppc x86 ~x86-fbsd"

RDEPEND="
	dev-libs/glib:2
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXft
"
DEPEND="
	${RDEPEND}
	virtual/pkgconfig
	x11-proto/xextproto
	x11-proto/xproto
"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	sed -i -e '/^font/s|".*"|"fixed"|g' doc/aewmrc.ex || die
	sed -i -e 's|skill|pkill|g' doc/clientsrc.ex || die
}

src_compile() {
	emake \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		PKG_CONFIG="$(tc-getPKG_CONFIG)"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		MANDIR="${D}/usr/share/man/man1" \
		XROOT="/usr" \
		install

	dodoc NEWS README
}