net-libs/gnome-online-accounts: bump to 3.36.0

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index 98b60206c190..b5a68a78bf3f 100644
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1 +1,2 @@
 DIST gnome-online-accounts-3.34.1.tar.xz 856288 BLAKE2B 99a6c242dd57acf009a2b4451287fff5bbc61b0aeb0396b13368b179d1b1604b413ff9dcb56bf4415c990cb4f2cb434a0fcf17b9381dcb5055a99985249af5d4 SHA512 233f1b15d4a7bdbee4ed85ba252ea0d9af2ac15a2edd3ce2b40d76434285fd093f07375313a599fa191f8df1551eb37f48c4784e389fcbaec0565bb3aba28426
+DIST gnome-online-accounts-3.36.0.tar.xz 860472 BLAKE2B 921f2f5ed9ac3db07046507723d814fc41579aee76cd2437673cdc3612db1077627ab47586e719b56a5bce25afe75b8028477f69745791eeb774c82bf854863d SHA512 2d04ea016c1bace9a2cb6ef7a6539c7f878cfa9b309394b18ed692ef1b9b73bf5f93a3f9edcb74170f1be4823a5c9ac6cde3b4e7245906e1b4e130d33eeb1c81
diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.36.0.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.36.0.ebuild
new file mode 100644
index 000000000000..c7585efa0244
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.36.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="debug gnome +introspection kerberos +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.52:2
+	>=app-crypt/libsecret-0.5
+	>=dev-libs/json-glib-0.16
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	net-libs/rest:0.7
+	>=net-libs/webkit-gtk-2.12.0:4
+	>=x11-libs/gtk+-3.19.12:3
+	x11-libs/pango
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	kerberos? (
+		app-crypt/gcr:0=[gtk]
+		app-crypt/mit-krb5 )
+"
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-libs/libxslt
+	>=dev-util/gdbus-codegen-2.30.0
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+	gnome2_src_configure \
+		--disable-static \
+		--enable-backend \
+		--enable-documentation \
+		--enable-exchange \
+		--enable-facebook \
+		--enable-flickr \
+		--enable-foursquare \
+		--enable-imap-smtp \
+		--enable-lastfm \
+		--enable-media-server \
+		--enable-owncloud \
+		--enable-windows-live \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable kerberos) \
+		$(use_enable kerberos fedora) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}