www-client/falkon: 23.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/www-client/falkon/Manifest b/www-client/falkon/Manifest
index d829d15683ca..a49f14069654 100644
--- a/www-client/falkon/Manifest
+++ b/www-client/falkon/Manifest
@@ -1 +1,2 @@
 DIST falkon-23.04.3.tar.xz 2553088 BLAKE2B e6dafe1f22f47c031b2c856aa5ba9a23eb74295c5cf891282ec51894c520383bca94ff42ef94c3396075b734da53adc5a289e4c8a94203b8daf6d6f8e847e527 SHA512 2d77e6f7383b3bf23aa979d57d2ba3a58516f18e3a72bf8a78695b36273ff00877e0109bba0dfa2b09215433457d12f919568cecacd9b96be888b585bf513f83
+DIST falkon-23.08.0.tar.xz 2571348 BLAKE2B 2673df672a17909661d488c425acf8fdb46112920707f038a0a84ff41b977006cccc509e00c1d0d1c4f8200a563b7aedbc2c0d70c9790c07094756932afe9af4 SHA512 f9f1e28a096c528bd5b1a01e9c5aacb89ad75fe2f28dedeb659f383f559142847e989b775d9619866cb41ea36efff1c6ceaa75f1d9adc37b6b04521e8b88b58d
diff --git a/www-client/falkon/falkon-23.08.0.ebuild b/www-client/falkon/falkon-23.08.0.ebuild
new file mode 100644
index 000000000000..3928b72439c9
--- /dev/null
+++ b/www-client/falkon/falkon-23.08.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.106.0
+QTMIN=5.15.9
+PYTHON_COMPAT=( python3_{10..11} )
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
+	>=dev-qt/qtwebchannel-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5=[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	virtual/libintl
+	dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+	kde? (
+		>=kde-frameworks/kcoreaddons-${KFMIN}:5
+		>=kde-frameworks/kcrash-${KFMIN}:5
+		>=kde-frameworks/kio-${KFMIN}:5
+		>=kde-frameworks/kjobwidgets-${KFMIN}:5
+		>=kde-frameworks/kwallet-${KFMIN}:5
+		>=kde-frameworks/purpose-${KFMIN}:5
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep "
+			>=dev-python/pyside2-${QTMIN}[designer,gui,webengine,widgets,\${PYTHON_USEDEP}] \
+			>=dev-python/shiboken2-${QTMIN}[\${PYTHON_USEDEP}]
+		")
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb:=
+		x11-libs/xcb-util
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:5"
+fi
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+PATCHES=( "${FILESDIR}/${PN}-23.07.80-python3.patch" )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_KEYRING=OFF
+		-DDISABLE_DBUS=$(usex !dbus)
+		$(cmake_use_find_package kde KF5Wallet)
+		$(cmake_use_find_package kde KF5KIO)
+		-DBUILD_PYTHON_SUPPORT=$(usex python)
+		-DNO_X11=$(usex !X)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	ecm_src_configure
+}