dev-python/ipykernel: Bump to 6.9.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index bccd4984844e..ed7218e3531e 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1 +1,2 @@
 DIST ipykernel-6.6.1.tar.gz 123915 BLAKE2B 136a3acdea6790d4666c3f5b0d040a91be405ff35e510456d920d0d2d2fb4f4076eb8e74089d08c42f0eba50caa48da929c1a684ad414919a67748f13d6fdf78 SHA512 bfe37f3d69c9b05f9bbbdec7f2103c353433b402474507a9d17c02f224e3a80eaea010b5a8bcebfd4410fbba661feae74107a4904c0af7835c6c1aa6bd0c1159
+DIST ipykernel-6.9.1.tar.gz 127244 BLAKE2B 13f3860f4d565bb4b362841bdcdd81ed5e3284ca6b4750c491cf5895d09fa1a1671acc8529066355cf2f549f89099dfaf8024281ab445b5db0e5ae52062c36d4 SHA512 5c977b01068153762817a372a20e8f3c7055f1cca16d4a4a03f73f4d9c5ce78597a106a4d153fd04dc601129fd8e1993d686e8ff6e299c2169a9d6f1272de58a
diff --git a/dev-python/ipykernel/ipykernel-6.9.1.ebuild b/dev-python/ipykernel/ipykernel-6.9.1.ebuild
new file mode 100644
index 000000000000..8c593a257ad4
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.9.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="https://github.com/ipython/ipykernel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/debugpy-1.0.0[${PYTHON_USEDEP}]
+	<dev-python/debugpy-2.0[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.0[${PYTHON_USEDEP}]
+	<dev-python/traitlets-6.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter_client-8.0[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.2[${PYTHON_USEDEP}]
+	<www-servers/tornado-7.0[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1.0[${PYTHON_USEDEP}]
+	<dev-python/matplotlib-inline-0.2.0[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/nose_warnings_filters[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.5.0-drop-pytest-cov.patch
+)
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	ipykernel/tests/test_debugger.py::test_attach_debug
+	ipykernel/tests/test_debugger.py::test_set_breakpoints
+	ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+	ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+	ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+)
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}