sys-kernel/gentoo-kernel-bin: add 5.14.16-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index e9c83e6ae069..5196f8ca9734 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -46,6 +46,7 @@ DIST gentoo-kernel-5.14.15-1.amd64.xpak 68135693 BLAKE2B 4d1b3c8f095bcbedc67c33e
 DIST gentoo-kernel-5.14.15-1.arm64.xpak 63053059 BLAKE2B adbc13a8b046cd40da16d9902bfcef68347c81ed695af14445d526fdfed641d44635cc108c761a6056c4d485d9f0beaf80a1256474d427b6954318ca0b211287 SHA512 ed6bc279e81e80287cd5da69ae7d633b540ccb3ba219deb104fa04e0809734125d658ba995c39004a895bc6ab093c6d28d8eee6ab0d28e78d1669af5e4b8d189
 DIST gentoo-kernel-5.14.15-1.x86.xpak 59181387 BLAKE2B 635576604adee2b32c107ca50fb74a106fb1e88a8f4640d8e9660d1493b4f86870e429acb1a3b42286b1d0781b4cc2421b10f1cecd778c4505f6edc1bf05b728 SHA512 6bf1300d5b3bc7512184e5d99d7e7b69d354e8b1fba41e609ed0288bdf134a1951c57b75d0255633c70ec250d05e4a403c09be56aa16d5ead38bee2f1b1bbb88
 DIST gentoo-kernel-5.14.16-1.amd64.xpak 68131257 BLAKE2B 8dc482d683f804b840b9a78f36bb344a6dffb35678ea543467cbfd2bb174d4fa0700f891c4e4935e326d29a24603932b83824506e552c52c90dde426f1db10a7 SHA512 07ec41de81bc6fd725aefe3d5209d38e81bf1c883eda59eaceb82c618b872c7075794966add8dc86696cf26fdd9cc61847c694474361a6785ac3d8b426058d37
+DIST gentoo-kernel-5.14.16-1.arm64.xpak 63034327 BLAKE2B 27c1fdcd3b6df55aafcfb744a87215ab5643e07f8a1246868036257449e79d8eb18a67f2fa264526a5c0880a65ebaa9e1fcfd7bc9508211848c8331287937736 SHA512 274ef82725a6f6b6e5dddc2bdb6a05439f4cb4a69e16af5d52897de55cff8817fa2137eb0ad12186d21932a87d15c05a74968205684f1ab798428025938fbf7c
 DIST gentoo-kernel-5.14.16-1.x86.xpak 59189394 BLAKE2B 9ed0a856eeaa5a715dc0161d338f5d6fd009985068f7f5dc440c219eeae5bb7fb0e8248d15543adfc2aa0009417a6f9c5a96ed60485c1f0a30138f01b35c3856 SHA512 bc15228884dd481f01b53c67758191a01d1bdad9b566f7c818b1fceb5b38567490557817b09086c7075be252e1804ad05cd4d860dbca981ca51e8be0327bcb4d
 DIST gentoo-kernel-5.4.148-1.amd64.xpak 61364378 BLAKE2B 2d5a665f5ccee0de5abc78d593b8bc6f1da0fa6fa9573ee9c0a65efaae9629ac3ea0b26a4b83e6abb23eee5fcb842fd67a395af35fb5476529b30dc0739d7944 SHA512 277064e06bdf25fc67f0894ab1d8116f23c71488b92a1751833c6aff684c7f2d28e2116e31d40878caa3f741fe9fe61f1f0c3cfaca4677298d2851b22afdf1ff
 DIST gentoo-kernel-5.4.148-1.arm64-r1.xpak 57998682 BLAKE2B a27bee25e2e6b2c0fea38cb5bee1ce433c6dbf10468b374ffb237a15403a4acb7feb0729526d337c5c9b1a85c4afc63716fa3c4b5fbe32c03ddb6966765f8946 SHA512 c72a4d8bc4bca7cf9ad5b594d7cadff11f9a4ec7181c0dbdce14919a1af50c1a901dd69b1a5d3f35abe51f9ca82f729f352ac8873d0b0f225e4bdd45a213b350
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.16-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.16-r1.ebuild
new file mode 100644
index 000000000000..acaaf28e30cb
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.16-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}