app-editors/retext: Update dependencies for PyQt5-5.12

For PyQt5-5.12 and later seperate dependency for
PyQtWebEngine is necessary instead of PyQt5[webengine].

Package-Manager: Portage-2.3.66 repoman-2.3.12
Signed-off-by: Nils Freydank <holgersson@posteo.de>
Closes: https://github.com/gentoo/gentoo/pull/11666
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 86 insertions, 7 deletions

diff --git a/app-editors/retext/retext-7.0.4-r1.ebuild b/app-editors/retext/retext-7.0.4-r1.ebuild
new file mode 100644
index 000000000000..21b6ece05bcf
--- /dev/null
+++ b/app-editors/retext/retext-7.0.4-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# no pypy{,3} support as PyQt5 does not support it at 2019-05-15
+# https://bitbucket.org/pypy/compatibility/wiki/Home#!gui-library-bindings
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+MY_PN="ReText"
+MY_P="${MY_PN}-${PV/_/~}"
+
+DESCRIPTION="Simple editor for Markdown and reStructuredText"
+HOMEPAGE="https://github.com/retext-project/retext https://github.com/retext-project/retext/wiki"
+
+if [[ ${PV} == *9999 ]]
+	then
+		inherit git-r3
+		EGIT_REPO_URI="https://github.com/retext-project/retext.git"
+	else
+		SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+		KEYWORDS="~amd64 ~x86"
+		S="${WORKDIR}"/${MY_P}
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="+spell"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/markups[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/python-markdown-math[${PYTHON_USEDEP}]
+	dev-python/PyQt5[gui,network,printsupport,widgets,${PYTHON_USEDEP}]
+	|| (
+		dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+		<dev-python/PyQt5-5.12[webengine]
+		)
+	spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	esetup.py test
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+
+	einfo "Starting with retext-7.0.4 the markdown-math plugin is installed."
+	einfo "Note that you can use different math delimiters, e.g. \(...\) for inline math."
+	einfo "For more details take a look at:"
+	einfo "https://github.com/mitya57/python-markdown-math#math-delimiters"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/app-editors/retext/retext-9999.ebuild b/app-editors/retext/retext-9999.ebuild
index 0e48d2b2a8cf..21b6ece05bcf 100644
--- a/app-editors/retext/retext-9999.ebuild
+++ b/app-editors/retext/retext-9999.ebuild
@@ -1,13 +1,13 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-# no pypy{,3} support as PyQt5 does not support it at 2018-11-18
+# no pypy{,3} support as PyQt5 does not support it at 2019-05-15
 # https://bitbucket.org/pypy/compatibility/wiki/Home#!gui-library-bindings
 PYTHON_COMPAT=( python3_{5,6,7} )
 
-inherit distutils-r1 gnome2-utils virtualx xdg-utils
+inherit distutils-r1 virtualx xdg-utils
 
 MY_PN="ReText"
 MY_P="${MY_PN}-${PV/_/~}"
@@ -36,13 +36,18 @@ RDEPEND="
 	dev-python/markups[${PYTHON_USEDEP}]
 	dev-python/pygments[${PYTHON_USEDEP}]
 	dev-python/python-markdown-math[${PYTHON_USEDEP}]
-	dev-python/PyQt5[gui,network,printsupport,webengine,widgets,${PYTHON_USEDEP}]
+	dev-python/PyQt5[gui,network,printsupport,widgets,${PYTHON_USEDEP}]
+	|| (
+		dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+		<dev-python/PyQt5-5.12[webengine]
+		)
 	spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )
 "
 DEPEND="
 	${RDEPEND}
+"
+BDEPEND="
 	dev-python/setuptools[${PYTHON_USEDEP}]
-	test? ( x11-base/xorg-server[xvfb] )
 "
 
 src_test() {
@@ -55,7 +60,7 @@ python_test() {
 
 pkg_postinst() {
 	xdg_desktop_database_update
-	gnome2_icon_cache_update
+	xdg_icon_cache_update
 
 	einfo "Starting with retext-7.0.4 the markdown-math plugin is installed."
 	einfo "Note that you can use different math delimiters, e.g. \(...\) for inline math."
@@ -64,6 +69,6 @@ pkg_postinst() {
 }
 
 pkg_postrm() {
-	gnome2_icon_cache_update
 	xdg_desktop_database_update
+	xdg_icon_cache_update
 }