media-libs/libass: fix implicit dep on dev-libs/libunibreak

Since version 0.17.0, ```media-libs/libass``` searches for ```dev-libs/libunibreak```
to optionally use the Unicode line breaking algorithm instead of ASS' much stricter rules.

Signed-off-by: Cristian Othón Martínez Vera <cfuga@cfuga.mx>
Signed-off-by: David Roman <davidroman96@gmail.com>
Closes: https://bugs.gentoo.org/911414
Closes: https://github.com/gentoo/gentoo/pull/38871
Signed-off-by: Sam James <sam@gentoo.org>

9 files changed, 82 insertions, 0 deletions

diff --git a/media-libs/libass/libass-0.17.1-r1.ebuild b/media-libs/libass/libass-0.17.1-r1.ebuild
new file mode 100644
index 000000000000..ea718aecd975
--- /dev/null
+++ b/media-libs/libass/libass-0.17.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/libass.asc
+inherit multilib-minimal verify-sig
+
+DESCRIPTION="Library for SSA/ASS subtitles rendering"
+HOMEPAGE="https://github.com/libass/libass"
+SRC_URI="https://github.com/libass/libass/releases/download/${PV}/${P}.tar.xz"
+SRC_URI+=" verify-sig? ( https://github.com/libass/libass/releases/download/${PV}/${P}.tar.xz.asc )"
+
+LICENSE="ISC"
+SLOT="0/9" # subslot = libass soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="+fontconfig libunibreak test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/fribidi-0.19.5-r1[${MULTILIB_USEDEP}]
+	>=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}]
+	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
+	>=media-libs/harfbuzz-1.2.3:=[truetype,${MULTILIB_USEDEP}]
+	fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
+	libunibreak? ( dev-libs/libunibreak:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	amd64? ( dev-lang/nasm )
+	x86? ( dev-lang/nasm )
+	test? ( media-libs/libpng[${MULTILIB_USEDEP}] )
+	verify-sig? ( sec-keys/openpgp-keys-libass )
+"
+
+DOCS=( Changelog )
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable fontconfig) \
+		$(use_enable libunibreak) \
+		$(use_enable test) \
+		--disable-require-system-font-provider
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	find "${ED}" -name '*.la' -type f -delete || die
+}
diff --git a/media-libs/libass/metadata.xml b/media-libs/libass/metadata.xml
index 589ec7043bf8..62a5b8661a6a 100644
--- a/media-libs/libass/metadata.xml
+++ b/media-libs/libass/metadata.xml
@@ -4,6 +4,9 @@
   <maintainer type="project">
     <email>media-video@gentoo.org</email>
   </maintainer>
+  <use>
+    <flag name="libunibreak">Use <pkg>dev-libs/libunibreak</pkg> for Unicode line breaking algorithm</flag>
+  </use>
   <upstream>
     <remote-id type="github">libass/libass</remote-id>
   </upstream>
diff --git a/profiles/arch/alpha/package.use.mask b/profiles/arch/alpha/package.use.mask
index a9a88e0bb322..386fc2d40836 100644
--- a/profiles/arch/alpha/package.use.mask
+++ b/profiles/arch/alpha/package.use.mask
@@ -1,6 +1,10 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
+# David Roman <davidroman96@gmail.com> (2024-10-04)
+# dev-libs/libunibreak is not keyworded
+media-libs/libass libunibreak
+
 # Sam James <sam@gentoo.org> (2024-08-23)
 # dev-util/bpftool and/or sys-devel/bpf-toolchain not keyworded here
 sys-apps/systemd bpf
diff --git a/profiles/arch/hppa/package.use.mask b/profiles/arch/hppa/package.use.mask
index dc92c7939f40..f0a070bc7539 100644
--- a/profiles/arch/hppa/package.use.mask
+++ b/profiles/arch/hppa/package.use.mask
@@ -4,6 +4,10 @@
 # NOTE: When masking a USE flag due to missing keywords, please file a keyword
 # request bug for the hppa arch.
 
+# David Roman <davidroman96@gmail.com> (2024-10-04)
+# dev-libs/libunibreak is not keyworded
+media-libs/libass libunibreak
+
 # Sam James <sam@gentoo.org> (2024-08-23)
 # dev-util/bpftool and/or sys-devel/bpf-toolchain not keyworded here
 sys-apps/systemd bpf
diff --git a/profiles/arch/loong/package.use.mask b/profiles/arch/loong/package.use.mask
index 0438cea893d3..a10a477151eb 100644
--- a/profiles/arch/loong/package.use.mask
+++ b/profiles/arch/loong/package.use.mask
@@ -1,6 +1,10 @@
 # Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
+# David Roman <davidroman96@gmail.com> (2024-10-04)
+# dev-libs/libunibreak is not keyworded
+media-libs/libass libunibreak
+
 # WANG Xuerui <xen0n@gentoo.org> (2024-09-27)
 # media-libs/libilbc needs porting
 media-video/ffmpeg libilbc
diff --git a/profiles/arch/mips/package.use.mask b/profiles/arch/mips/package.use.mask
index d7cac0a393f7..113fd19129af 100644
--- a/profiles/arch/mips/package.use.mask
+++ b/profiles/arch/mips/package.use.mask
@@ -1,6 +1,10 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
+# David Roman <davidroman96@gmail.com> (2024-10-04)
+# dev-libs/libunibreak is not keyworded
+media-libs/libass libunibreak
+
 # Arthur Zamarin <arthurzam@gentoo.org> (2024-09-08)
 # Packages needing dev-python/selenium.
 dev-python/aiohttp-cors test
diff --git a/profiles/arch/powerpc/ppc64/package.use.mask b/profiles/arch/powerpc/ppc64/package.use.mask
index 1818fc6de33f..015539e06ae0 100644
--- a/profiles/arch/powerpc/ppc64/package.use.mask
+++ b/profiles/arch/powerpc/ppc64/package.use.mask
@@ -1,6 +1,10 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
+# David Roman <davidroman96@gmail.com> (2024-10-04)
+# dev-libs/libunibreak is not keyworded
+media-libs/libass libunibreak
+
 # Matt Jolly <kangie@gentoo.org> (2024-08-14)
 # QUIC dependencies are not keyworded
 net-misc/curl http3 quic curl_quic_openssl curl_quic_ngtcp2
diff --git a/profiles/arch/riscv/package.use.mask b/profiles/arch/riscv/package.use.mask
index 40d756b4ac58..55abb27079cd 100644
--- a/profiles/arch/riscv/package.use.mask
+++ b/profiles/arch/riscv/package.use.mask
@@ -1,6 +1,10 @@
 # Copyright 2019-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
+# David Roman <davidroman96@gmail.com> (2024-10-04)
+# dev-libs/libunibreak not keyworded here
+media-libs/libass libunibreak
+
 # Paul Zander <negril.nx+gentoo@gmail.com> (2024-09-08)
 # needs re-keywording and clean-up of media-libs/opencollada
 media-libs/assimp collada
diff --git a/profiles/arch/sparc/package.use.mask b/profiles/arch/sparc/package.use.mask
index 55d49431d68f..be94807c3f69 100644
--- a/profiles/arch/sparc/package.use.mask
+++ b/profiles/arch/sparc/package.use.mask
@@ -1,6 +1,10 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
+# David Roman <davidroman96@gmail.com> (2024-10-04)
+# dev-libs/libunibreak not keyworded here
+media-libs/libass libunibreak
+
 # Sam James <sam@gentoo.org> (2024-08-23)
 # dev-util/bpftool and/or sys-devel/bpf-toolchain not keyworded here
 sys-apps/systemd bpf