net-misc/asterisk: version bump to 13.29.1 + maintainership

Converted to GLEP 81 for user+group.
Consolidated a few DEPEND issues.
Dropped pkg_config phase function.
Took maintainership.
Fixed a bunch of other issues from pkgcheck (${D} and ${ROOT} not having
    a / following it directly).
Bumped to EAPI=7
Use $ED over $D where applicable.
Fix statsd integration.
Update depend on virtual/mysql to db/mysql-connector-c
Enable NOISY_BUILD as requested (instructed) by slyfox.
Fix /usr/share/doc/${PV} being asterisk: owned.
Make SSL optional.

This commit enables progress on the GLSA bug: https://bugs.gentoo.org/689796

Might close: https://bugs.gentoo.org/594160 (SIGILL, may be GRSEC, or #667498)

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Closes: https://bugs.gentoo.org/631464
Closes: https://bugs.gentoo.org/654710
Closes: https://bugs.gentoo.org/656472
Closes: https://bugs.gentoo.org/666004
Closes: https://bugs.gentoo.org/667498
Closes: https://bugs.gentoo.org/670522
Closes: https://bugs.gentoo.org/679804
Closes: https://bugs.gentoo.org/686906
Closes: https://bugs.gentoo.org/692696
Signed-off-by: Jaco Kroon <jaco@uls.co.za>
Closes: https://github.com/gentoo/gentoo/pull/13649
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 342 insertions, 8 deletions

diff --git a/net-misc/asterisk/Manifest b/net-misc/asterisk/Manifest
index 01ba4b2e0a9f..613d2ddb039f 100644
--- a/net-misc/asterisk/Manifest
+++ b/net-misc/asterisk/Manifest
@@ -1,4 +1,6 @@
 DIST asterisk-11.25.3.tar.gz 35134682 BLAKE2B 9da24d5d6a674ab660edb103e5fc56ddfbcc58cd86166cc08cceb0598a63b51eae36133565e09a30ad11ff6623ba8945437dfb561d2916f68341d398540dabce SHA512 9c0521d55e5b69663ea40066d52e397ba6c165a4b20cd0a1e5e375b9c0e5a6e4f37908e50b0b580e288dec9be252af9a8bce7bceb03ba029f902fb757e6311ed
 DIST asterisk-13.23.1.tar.gz 33064056 BLAKE2B 7f531766df5f2db29b562e7c7d4e265d5cf610f192188691279c0294195b835bb62beef19d7e9554862e6b44764064b21d50a3e307bbf85dd12b67a2df8be459 SHA512 227bfc80b2e6382019d608296c4e1c8e992ba867636fa2c8ee578d0aa406b8828bf7962b24035d9b581c433afd18be7cbe98eb954112661b9759b6296ee686dd
+DIST asterisk-13.29.1.tar.gz 33061969 BLAKE2B b581a3b706438fd0f685cab9c6148f9803d09f878d2ec824cd7b3edb299d5514e7c473622f135caa8a7905ab70dff915b83ff9dcbcf80cb04955ba8dea03c968 SHA512 3c32324f67413abdf73a3146b8e280fd23d65854df23b87b01e7f20c635c304606f6216c49c6dcd44c3a09b945d15124a5d70182c4b69e5ed8e542a13589d2df
 DIST gentoo-asterisk-patchset-3.17.tar.bz2 5074 BLAKE2B 3c945e77b54b2449253acb9fcea8d289a7a3184729190622c14aff5557d36c93556efa83320fe4e7ae84021960c09f35ae9f997e8015706eef933aae2948309e SHA512 37f86f3c699b2643afd8080391e817a282571694bb56e00efd0734918dbc33d6c12a2463dbc24667597420863b4f506870140fbb8ef3f1700124ef790ae7252d
 DIST gentoo-asterisk-patchset-4.07.tar.bz2 2471 BLAKE2B d9026e7e8c12431496c24f204d117ed715741623195af10c838ec3ac5ce6a26fbb2d76d4c45c538881b532084e2ce74d2de83a27a0abaa5f65791be91416ef6d SHA512 73a9f92e6a737687c311941100c45bbc573f54fa79d0284318996c0d70274a4d2218693406d71b371496d27123d4d99bbc159974388e6547a682c06084d3b4c5
+DIST gentoo-asterisk-patchset-4.08.tar.bz2 2176 BLAKE2B 7f8c9b5fda855091e66b2534d2be23fb1616f565480459f71f766826e5deeeecb24899e2ee9eefe74323e892624d32ab954ec7e9be6a002431ff029fc13493ed SHA512 365c1b8628882c48c279e1fd77d982e6d0820ba7d7122e97bb4988f875d7010caa956798c833c3b01d389004fa08a63a9de2c1b452c9e5701c6106e29fd8e9e1
diff --git a/net-misc/asterisk/asterisk-13.29.1.ebuild b/net-misc/asterisk/asterisk-13.29.1.ebuild
new file mode 100644
index 000000000000..94ab40d59c9c
--- /dev/null
+++ b/net-misc/asterisk/asterisk-13.29.1.ebuild
@@ -0,0 +1,327 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools linux-info systemd
+
+MY_P="${PN}-${PV/_/-}"
+
+DESCRIPTION="Asterisk: A Modular Open Source PBX System"
+HOMEPAGE="https://www.asterisk.org/"
+SRC_URI="https://downloads.asterisk.org/pub/telephony/asterisk/releases/${MY_P}.tar.gz
+	https://downloads.uls.co.za/gentoo/asterisk/gentoo-asterisk-patchset-4.08.tar.bz2"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+IUSE_VOICEMAIL_STORAGE="
+	+voicemail_storage_file
+	voicemail_storage_odbc
+	voicemail_storage_imap
+"
+IUSE="${IUSE_VOICEMAIL_STORAGE} alsa bluetooth calendar +caps cluster curl dahdi debug doc freetds gtalk http iconv ilbc ldap libedit libressl lua mysql newt +samples odbc osplookup oss pjproject portaudio postgres radius selinux snmp span speex srtp +ssl static statsd syslog vorbis xmpp"
+IUSE_EXPAND="VOICEMAIL_STORAGE"
+REQUIRED_USE="gtalk? ( xmpp )
+	^^ ( ${IUSE_VOICEMAIL_STORAGE/+/} )
+	voicemail_storage_odbc? ( odbc )
+"
+
+PATCHES=( "${WORKDIR}/asterisk-patchset" )
+
+DEPEND="acct-user/asterisk
+	acct-group/asterisk
+	dev-db/sqlite:3
+	dev-libs/popt
+	dev-libs/jansson
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	sys-libs/ncurses:0=
+	sys-libs/zlib:=
+
+	alsa? ( media-libs/alsa-lib )
+	bluetooth? ( net-wireless/bluez:= )
+	calendar? (
+		net-libs/neon:=
+		dev-libs/libical:=
+		dev-libs/iksemel
+	)
+	caps? ( sys-libs/libcap )
+	cluster? ( sys-cluster/corosync )
+	curl? ( net-misc/curl )
+	dahdi? (
+		net-libs/libpri
+		net-misc/dahdi-tools
+	)
+	freetds? ( dev-db/freetds )
+	gtalk? ( dev-libs/iksemel )
+	http? ( dev-libs/gmime:2.6 )
+	iconv? ( virtual/libiconv )
+	ilbc? ( dev-libs/ilbc-rfc3951 )
+	ldap? ( net-nds/openldap )
+	libedit? ( dev-libs/libedit )
+	lua? ( dev-lang/lua:* )
+	mysql? ( dev-db/mysql-connector-c:= )
+	newt? ( dev-libs/newt )
+	odbc? ( dev-db/unixODBC )
+	osplookup? ( net-libs/osptoolkit )
+	pjproject? ( net-libs/pjproject )
+	portaudio? ( media-libs/portaudio )
+	postgres? ( dev-db/postgresql:* )
+	radius? ( net-dialup/freeradius-client )
+	snmp? ( net-analyzer/net-snmp:= )
+	span? ( media-libs/spandsp )
+	speex? (
+		media-libs/speex
+		media-libs/speexdsp
+	)
+	srtp? ( net-libs/libsrtp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	vorbis? ( media-libs/libvorbis )
+	voicemail_storage_imap? ( virtual/imap-c-client )
+	xmpp? ( dev-libs/iksemel )
+"
+
+RDEPEND="${DEPEND}
+	net-misc/asterisk-core-sounds
+	net-misc/asterisk-extra-sounds
+	net-misc/asterisk-moh-opsound
+
+	selinux? ( sec-policy/selinux-asterisk )
+	syslog? ( virtual/logger )"
+
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+QA_DT_NEEDED="/usr/lib.*/libasteriskssl[.]so[.][0-9]\+"
+
+pkg_setup() {
+	CONFIG_CHECK="~!NF_CONNTRACK_SIP"
+	local WARNING_NF_CONNTRACK_SIP="SIP (NAT) connection tracking is enabled. Some users
+	have reported that this module dropped critical SIP packets in their deployments. You
+	may want to disable it if you see such problems."
+	check_extra_config
+}
+
+src_prepare() {
+	default
+	AT_M4DIR="autoconf third-party third-party/pjproject third-party/jansson" eautoreconf
+}
+
+function menuselect()
+{
+	menuselect/menuselect "$@" || die "menuselect $* failed."
+}
+
+src_configure() {
+	local vmst
+
+	econf \
+		--libdir="/usr/$(get_libdir)" \
+		--localstatedir="/var" \
+		--with-crypto \
+		--with-gsm=internal \
+		--with-popt \
+		--with-z \
+		--without-libedit \
+		$(use_with caps cap) \
+		$(use_with http gmime) \
+		$(use_with newt) \
+		$(use_with pjproject) \
+		$(use_with portaudio) \
+		$(use_with ssl)
+
+	# Blank out sounds/sounds.xml file to prevent
+	# asterisk from installing sounds files (we pull them in via
+	# asterisk-{core,extra}-sounds and asterisk-moh-opsound.
+	>"${S}"/sounds/sounds.xml
+
+	# That NATIVE_ARCH chatter really is quite bothersome
+	sed -i 's/NATIVE_ARCH=/NATIVE_ARCH=0/' build_tools/menuselect-deps || die "Unable to squelch noisy build system"
+
+	# Compile menuselect binary for optional components
+	emake NOISE_BUILD=yes menuselect.makeopts
+
+	# Disable BUILD_NATIVE (bug #667498)
+	menuselect --disable build_native menuselect.makeopts
+
+	# Broken functionality is forcibly disabled (bug #360143)
+	menuselect --disable chan_misdn menuselect.makeopts
+	menuselect --disable chan_ooh323 menuselect.makeopts
+
+	# Utility set is forcibly enabled (bug #358001)
+	menuselect --enable smsq menuselect.makeopts
+	menuselect --enable streamplayer menuselect.makeopts
+	menuselect --enable aelparse menuselect.makeopts
+	menuselect --enable astman menuselect.makeopts
+
+	# this is connected, otherwise it would not find
+	# ast_pktccops_gate_alloc symbol
+	menuselect --enable chan_mgcp menuselect.makeopts
+	menuselect --enable res_pktccops menuselect.makeopts
+
+	# SSL is forcibly enabled, IAX2 & DUNDI are expected to be available
+	menuselect --enable pbx_dundi menuselect.makeopts
+	menuselect --enable func_aes menuselect.makeopts
+	menuselect --enable chan_iax2 menuselect.makeopts
+
+	# SQlite3 is now the main database backend, enable related features
+	menuselect --enable cdr_sqlite3_custom menuselect.makeopts
+	menuselect --enable cel_sqlite3_custom menuselect.makeopts
+
+	# The others are based on USE-flag settings
+	use_select() {
+		local state=$(use "$1" && echo enable || echo disable)
+		shift # remove use from parameters
+
+		while [[ -n $1 ]]; do
+			menuselect --${state} "$1" menuselect.makeopts
+			shift
+		done
+	}
+
+	use_select alsa         chan_alsa
+	use_select bluetooth    chan_mobile
+	use_select calendar     res_calendar res_calendar_{caldav,ews,exchange,icalendar}
+	use_select cluster      res_corosync
+	use_select curl         func_curl res_config_curl res_curl
+	use_select dahdi        app_dahdiras app_meetme chan_dahdi codec_dahdi res_timing_dahdi
+	use_select freetds      {cdr,cel}_tds
+	use_select gtalk        chan_motif
+	use_select http         res_http_post
+	use_select iconv        func_iconv
+	use_select ilbc         codec_ilbc format_ilbc
+	use_select ldap         res_config_ldap
+	use_select lua          pbx_lua
+	use_select mysql        app_mysql cdr_mysql res_config_mysql
+	use_select odbc         cdr_adaptive_odbc res_config_odbc {cdr,cel,res,func}_odbc
+	use_select osplookup    app_osplookup
+	use_select oss          chan_oss
+	use_select postgres     {cdr,cel}_pgsql res_config_pgsql
+	use_select radius       {cdr,cel}_radius
+	use_select snmp         res_snmp
+	use_select span         res_fax_spandsp
+	use_select speex        {codec,func}_speex
+	use_select srtp         res_srtp
+	use_select statsd       res_statsd res_{endpoint,chan}_stats
+	use_select syslog       cdr_syslog
+	use_select vorbis       format_ogg_vorbis
+	use_select xmpp         res_xmpp
+
+	# Voicemail storage ...
+	for vmst in ${IUSE_VOICEMAIL_STORAGE/+/}; do
+		if use ${vmst}; then
+			menuselect --enable $(echo ${vmst##*_} | tr '[:lower:]' '[:upper:]')_STORAGE menuselect.makeopts
+		fi
+	done
+
+	if use debug; then
+		for o in DONT_OPTIMIZE DEBUG_THREADS BETTER_BACKTRACES; do
+			menuselect --enable $o menuselect.makeopts
+		done
+	fi
+}
+
+src_compile() {
+	emake ASTCFLAGS="${CFLAGS}" ASTLDFLAGS="${LDFLAGS}" NOISY_BUILD=yes
+}
+
+src_install() {
+	local d
+
+	mkdir -p "${ED}/usr/$(get_libdir)/pkgconfig" || die
+	emake DESTDIR="${D}" NOISY_BUILD=yes installdirs
+	emake DESTDIR="${D}" NOISY_BUILD=yes install
+
+	if use radius; then
+		insinto /etc/radiusclient/
+		doins contrib/dictionary.digium
+	fi
+	diropts -m 0750 -o root -g asterisk
+	keepdir	/etc/asterisk
+	if use samples; then
+		emake NOISY_BUILD=yes DESTDIR="${ED}" samples
+		for conffile in "${ED}/etc/asterisk/"*
+		do
+			fowners root:root "${conffile#${ED}}"
+			fperms 0644 "${conffile#${ED}}"
+		done
+		einfo "Sample files have been installed"
+	else
+		einfo "Skipping installation of sample files..."
+		rm "${ED}"/var/lib/asterisk/mohmp3/* || die
+		rm "${ED}"/var/lib/asterisk/sounds/demo-* || die
+		rm "${ED}"/var/lib/asterisk/agi-bin/* || die
+		rm "${ED}"/etc/asterisk/* || die
+	fi
+	rm -r "${ED}"/var/spool/asterisk/voicemail/default || die
+
+	# keep directories
+	diropts -m 0770 -o asterisk asterisk
+	keepdir /var/lib/asterisk
+	keepdir /var/spool/asterisk
+	keepdir /var/spool/asterisk/{system,tmp,meetme,monitor,dictate,voicemail}
+	diropts -m 0750 -o asterisk -g asterisk
+	keepdir /var/log/asterisk/{cdr-csv,cdr-custom}
+
+	newinitd "${FILESDIR}"/1.8.0/asterisk.initd8 asterisk
+	newconfd "${FILESDIR}"/1.8.0/asterisk.confd asterisk
+
+	systemd_dounit "${FILESDIR}"/asterisk.service
+	systemd_newtmpfilesd "${FILESDIR}"/asterisk.tmpfiles.conf asterisk.conf
+	systemd_install_serviced "${FILESDIR}"/asterisk.service.conf
+
+	# Reset diropts else dodoc uses it for doc installations.
+	diropts -m0755
+
+	# install the upgrade documentation
+	dodoc UPGRADE* BUGS CREDITS
+
+	# install extra documentation
+	if use doc; then
+		dodoc doc/*.txt
+		dodoc doc/*.pdf
+	fi
+
+	# install SIP scripts; bug #300832
+	#
+	dodoc "${FILESDIR}/1.6.2/sip_calc_auth"
+	dodoc "${FILESDIR}/1.8.0/find_call_sip_trace.sh"
+	dodoc "${FILESDIR}/1.8.0/find_call_ids.sh"
+	dodoc "${FILESDIR}/1.6.2/call_data.txt"
+
+	# install logrotate snippet; bug #329281
+	#
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/1.6.2/asterisk.logrotate4" asterisk
+
+	# Asterisk installs a few folders that's empty by design,
+	# but still required.  This finds them, and marks them for
+	# portage.
+	for d in $(find "${ED}"/var -type d -empty || die "Find failed."); do
+		keepdir "${d#${ED}}"
+	done
+}
+
+pkg_postinst() {
+	#
+	# Announcements, warnings, reminders...
+	#
+	einfo "Asterisk has been installed"
+	echo
+	elog "If you want to know more about asterisk, visit these sites:"
+	elog "http://www.asteriskdocs.org/"
+	elog "http://www.voip-info.org/wiki-Asterisk"
+	echo
+	elog "http://www.automated.it/guidetoasterisk.htm"
+	echo
+	elog "Gentoo VoIP IRC Channel:"
+	elog "#gentoo-voip @ irc.freenode.net"
+	echo
+	echo
+	elog "Please read the Asterisk 13 upgrade document:"
+	elog "https://wiki.asterisk.org/wiki/display/AST/Upgrading+to+Asterisk+13"
+}
diff --git a/net-misc/asterisk/metadata.xml b/net-misc/asterisk/metadata.xml
index 7790ac2d905f..c47b77295147 100644
--- a/net-misc/asterisk/metadata.xml
+++ b/net-misc/asterisk/metadata.xml
@@ -2,20 +2,25 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<maintainer type="person">
-		<email>chainsaw@gentoo.org</email>
-		<name>Tony Vroon</name>
+		<email>jaco@uls.co.za</email>
+		<name>Jaco Kroon</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
 	</maintainer>
 	<use>
-		<flag name="newt">Include additional tools that require redhats windowing toolkit</flag>
+		<flag name="cluster">Enable high-availability support through the Corosync Cluster Engine</flag>
 		<flag name="dahdi">Support Digium compatible hardware (formerly known as Zaptel).</flag>
-		<flag name="span">Enable support for the spandsp codec</flag>
-		<flag name="samples">Install sample sound and configuration files (default: on)</flag>
-		<flag name="srtp">Enable support for encrypted voice transmission (secure RTP)</flag>
 		<flag name="gtalk">Enable support for Google Talk services</flag>
-		<flag name="osplookup">Support secure peering using the Open Settlement Protocol</flag>
 		<flag name="http">Enable embedded web server</flag>
-		<flag name="cluster">Enable high-availability support through the Corosync Cluster Engine</flag>
 		<flag name="ilbc">Enable the Internet Low Bitrate Codec (iLBC)</flag>
+		<flag name="newt">Include additional tools that require redhats windowing toolkit</flag>
+		<flag name="osplookup">Support secure peering using the Open Settlement Protocol</flag>
 		<flag name="pjproject">Enable support for pjproject (pjsip)</flag>
+		<flag name="samples">Install sample sound and configuration files (default: on)</flag>
+		<flag name="span">Enable support for the spandsp codec</flag>
+		<flag name="srtp">Enable support for encrypted voice transmission (secure RTP)</flag>
+		<flag name="statsd">Enable statsd integration</flag>
 	</use>
 </pkgmetadata>